การสร้างมาโคร

ลองจินตนาการว่าคุณต้องเรียกใช้เครื่องมือเป็นส่วนหนึ่งของบิลด์ เช่น คุณอาจต้องการสร้างหรือประมวลผลไฟล์ต้นฉบับล่วงหน้า หรือบีบอัดไบนารี ในบทแนะนำนี้ คุณจะได้สร้างมาโครที่ปรับขนาดรูปภาพ

มาโครเหมาะสำหรับงานง่ายๆ หากต้องการทำสิ่งต่างๆ ที่ซับซ้อนมากขึ้น เช่น เพิ่มการรองรับภาษาโปรแกรมใหม่ ให้พิจารณา สร้างกฎ กฎช่วยให้คุณควบคุมและมีความยืดหยุ่นมากขึ้น

วิธีที่ง่ายที่สุดในการสร้างมาโครที่ปรับขนาดรูปภาพคือการใช้ genrule ดังนี้

genrule(
    name = "logo_miniature",
    srcs = ["logo.png"],
    outs = ["small_logo.png"],
    cmd = "convert $< -resize 100x100 $@",
)

cc_binary(
    name = "my_app",
    srcs = ["my_app.cc"],
    data = [":logo_miniature"],
)

หากต้องการปรับขนาดรูปภาพเพิ่มเติม คุณอาจต้องการนำโค้ดกลับมาใช้ซ้ำ หากต้องการทำเช่นนั้น ให้กำหนดฟังก์ชันในไฟล์ .bzl แยกต่างหาก และเรียกไฟล์ว่า miniature.bzl

def miniature(name, src, size="100x100", **kwargs):
  """Create a miniature of the src image.

  The generated file is prefixed with 'small_'.
  """
  native.genrule(
    name = name,
    srcs = [src],
    outs = ["small_" + src],
    cmd = "convert $< -resize " + size + " $@",
    **kwargs
  )

ข้อควรทราบบางประการมีดังนี้

• โดยทั่วไปแล้ว มาโครจะมีอาร์กิวเมนต์ name เหมือนกับกฎ

• หากต้องการบันทึกพฤติกรรมของมาโคร ให้ใช้ docstring เหมือนใน Python

• หากต้องการเรียก genrule หรือกฎดั้งเดิมอื่นๆ ให้ใช้ native.

• ใช้ **kwargs เพื่อส่งต่ออาร์กิวเมนต์เพิ่มเติมไปยัง genrule ที่อยู่เบื้องหลัง (ทำงานเหมือนใน Python) ซึ่งจะเป็นประโยชน์เพื่อให้ผู้ใช้สามารถใช้แอตทริบิวต์มาตรฐาน เช่น visibility หรือ tags

ตอนนี้ให้ใช้มาโครจากไฟล์ BUILD

load("//path/to:miniature.bzl", "miniature")

miniature(
    name = "logo_miniature",
    src = "image.png",
)

cc_binary(
    name = "my_app",
    srcs = ["my_app.cc"],
    data = [":logo_miniature"],
)