Aturan

Laporkan masalahopen_in_new Lihat sumberopen_in_new

Aturan menentukan serangkaian tindakan yang dijalankan oleh Bazel pada input untuk menghasilkan sekumpulan output, yang dirujuk dalam penyedia yang ditampilkan oleh fungsi implementasi aturan. Misalnya, aturan biner C++ mungkin:

1. Ambil sekumpulan file sumber .cpp (input).
2. Menjalankan g++ pada file sumber (tindakan).
3. Tampilkan penyedia DefaultInfo dengan output yang dapat dieksekusi dan file lainnya agar tersedia saat runtime.
4. Menampilkan penyedia CcInfo dengan informasi khusus C++ yang dikumpulkan dari target dan dependensinya.

Dari perspektif Bazel, g++ dan library C++ standar juga merupakan input untuk aturan ini. Sebagai penulis aturan, Anda tidak hanya harus mempertimbangkan input yang diberikan pengguna pada aturan, tetapi juga semua alat dan library yang diperlukan untuk menjalankan tindakan.

Sebelum membuat atau mengubah aturan apa pun, pastikan Anda memahami fase build Bazel. Penting untuk memahami tiga fase build (pemuatan, analisis, dan eksekusi). Anda juga dapat mempelajari makro untuk memahami perbedaan antara aturan dan makro. Untuk memulai, tinjau Tutorial Aturan terlebih dahulu. Kemudian, gunakan halaman ini sebagai referensi.

Beberapa aturan diintegrasikan ke dalam Bazel itu sendiri. Aturan native ini, seperti cc_library dan java_binary, memberikan beberapa dukungan inti untuk bahasa tertentu. Dengan menentukan aturan sendiri, Anda dapat menambahkan dukungan yang serupa untuk bahasa dan alat yang tidak didukung oleh Bazel secara native.

Bazel menyediakan model ekstensibilitas untuk menulis aturan menggunakan bahasa Starlark. Aturan ini ditulis dalam file .bzl, yang dapat dimuat langsung dari file BUILD.

Saat menentukan aturan sendiri, Anda harus memutuskan atribut apa yang didukungnya dan cara aturan tersebut menghasilkan outputnya.

Fungsi implementation aturan menentukan perilaku persisnya selama fase analisis. Fungsi ini tidak menjalankan perintah eksternal apa pun. Sebaliknya, peristiwa tersebut mendaftarkan tindakan yang akan digunakan nanti selama fase eksekusi untuk mem-build output aturan, jika diperlukan.

Pembuatan aturan

Dalam file .bzl, gunakan fungsi aturan untuk menentukan aturan baru, dan simpan hasilnya di variabel global. Panggilan ke rule menentukan atribut dan fungsi implementasi:

example_library = rule(
    implementation = _example_library_impl,
    attrs = {
        "deps": attr.label_list(),
        ...
    },
)

Ini menentukan jenis aturan bernama example_library.

Panggilan ke rule juga harus menentukan apakah aturan akan membuat output yang dapat dieksekusi (dengan executable=True), atau secara khusus pengujian yang dapat dieksekusi (dengan test=True). Jika yang terakhir, aturan tersebut adalah aturan pengujian, dan nama aturan harus diakhiri dengan _test.

Pembuatan instance target

Aturan dapat dimuat dan dipanggil di file BUILD:

load('//some/pkg:rules.bzl', 'example_library')

example_library(
    name = "example_target",
    deps = [":another_target"],
    ...
)

Setiap panggilan ke aturan build tidak menampilkan nilai apa pun, tetapi memiliki efek samping dari penentuan target. Ini disebut membuat instance aturan. Ini menentukan nama untuk target dan nilai baru untuk atribut target.

Aturan juga dapat dipanggil dari fungsi Starlark dan dimuat dalam file .bzl. Fungsi Starlark yang memanggil aturan disebut makro Starlark. Makro Starlark pada akhirnya harus dipanggil dari file BUILD, dan hanya dapat dipanggil selama fase pemuatan, saat file BUILD dievaluasi untuk membuat instance target.

Atribut

Atribut adalah argumen aturan. Atribut dapat memberikan nilai tertentu ke implementasi target, atau dapat merujuk ke target lain, sehingga membuat grafik dependensi.

Atribut khusus aturan, seperti srcs atau deps, ditentukan dengan meneruskan peta dari nama atribut ke skema (yang dibuat menggunakan modul attr) ke parameter attrs rule. Atribut umum, seperti name dan visibility, secara implisit ditambahkan ke semua aturan. Atribut tambahan ditambahkan secara implisit ke aturan yang dapat dieksekusi dan pengujian secara khusus. Atribut yang ditambahkan secara implisit ke aturan tidak dapat disertakan dalam kamus yang diteruskan ke attrs.

Atribut dependensi

Aturan yang memproses kode sumber biasanya menentukan atribut berikut untuk menangani berbagai jenis dependensi:

• srcs menentukan file sumber yang diproses oleh tindakan target. Sering kali, skema atribut menentukan ekstensi file mana yang diharapkan untuk jenis file sumber yang diproses oleh aturan. Aturan untuk bahasa dengan file header umumnya menentukan atribut hdrs terpisah untuk header yang diproses oleh target dan konsumennya.
• deps menentukan dependensi kode untuk target. Skema atribut harus menentukan penyedia yang harus disediakan oleh dependensi tersebut. (Misalnya, cc_library menyediakan CcInfo.)
• data menentukan file yang akan tersedia pada runtime ke file yang dapat dieksekusi yang bergantung pada target. Hal tersebut memungkinkan file arbitrer ditentukan.

example_library = rule(
    implementation = _example_library_impl,
    attrs = {
        "srcs": attr.label_list(allow_files = [".example"]),
        "hdrs": attr.label_list(allow_files = [".header"]),
        "deps": attr.label_list(providers = [ExampleInfo]),
        "data": attr.label_list(allow_files = True),
        ...
    },
)

Ini adalah contoh atribut dependensi. Setiap atribut yang menentukan label input (yang ditentukan dengan attr.label_list, attr.label, atau attr.label_keyed_string_dict) menentukan dependensi jenis tertentu antara target dan target yang labelnya (atau objek Label yang sesuai) dicantumkan dalam atribut tersebut saat target ditentukan. Repositori, dan mungkin jalur, untuk label ini diselesaikan relatif terhadap target yang ditentukan.

example_library(
    name = "my_target",
    deps = [":other_target"],
)

example_library(
    name = "other_target",
    ...
)

Dalam contoh ini, other_target adalah dependensi dari my_target, sehingga other_target dianalisis terlebih dahulu. Akan terjadi error jika ada siklus dalam grafik dependensi target.

Atribut pribadi dan dependensi implisit

Atribut dependensi dengan nilai default membuat dependensi implisit. Ini implisit karena merupakan bagian dari grafik target yang tidak ditentukan pengguna dalam file BUILD. Dependensi implisit berguna untuk melakukan hard code hubungan antara aturan dan alat (dependensi waktu build, seperti compiler), karena sering kali pengguna tidak tertarik untuk menentukan alat yang digunakan aturan. Di dalam fungsi implementasi aturan, ini diperlakukan sama seperti dependensi lainnya.

Jika ingin memberikan dependensi implisit tanpa mengizinkan pengguna mengganti nilai tersebut, Anda dapat membuat atribut tersebut menjadi pribadi dengan memberinya nama yang diawali dengan garis bawah (_). Atribut pribadi harus memiliki nilai default. Secara umum, sebaiknya gunakan atribut pribadi untuk dependensi implisit.

example_library = rule(
    implementation = _example_library_impl,
    attrs = {
        ...
        "_compiler": attr.label(
            default = Label("//tools:example_compiler"),
            allow_single_file = True,
            executable = True,
            cfg = "exec",
        ),
    },
)

Dalam contoh ini, setiap target jenis example_library memiliki dependensi implisit pada compiler //tools:example_compiler. Hal ini memungkinkan fungsi implementasi example_library menghasilkan tindakan yang memanggil compiler, meskipun pengguna tidak meneruskan labelnya sebagai input. Karena _compiler adalah atribut pribadi, ctx.attr._compiler akan selalu mengarah ke //tools:example_compiler di semua target jenis aturan ini. Atau, Anda dapat memberi nama atribut compiler tanpa garis bawah dan mempertahankan nilai defaultnya. Hal ini memungkinkan pengguna mengganti compiler yang berbeda jika diperlukan, tetapi tidak memerlukan kesadaran akan label compiler.

Dependensi implisit umumnya digunakan untuk alat yang berada di repositori yang sama dengan implementasi aturan. Jika alat tersebut berasal dari platform eksekusi atau repositori yang berbeda, aturan harus mendapatkan alat tersebut dari Toolchain.

Atribut output

Atribut output, seperti attr.output dan attr.output_list, deklarasikan file output yang dihasilkan oleh target. Hal ini berbeda dengan atribut dependensi dalam dua hal:

• Fungsi tersebut menentukan target file output, bukan mengacu pada target yang ditentukan di tempat lain.
• Target file output bergantung pada target aturan yang dibuat instance, bukan sebaliknya.

Biasanya, atribut output hanya digunakan jika aturan perlu membuat output dengan nama yang ditentukan pengguna dan tidak dapat didasarkan pada nama target. Jika aturan memiliki satu atribut output, biasanya aturan tersebut bernama out atau outs.

Atribut output adalah cara yang lebih disukai untuk membuat output yang dideklarasikan sebelumnya, yang dapat bergantung secara khusus pada atau diminta pada command line.

Fungsi implementasi

Setiap aturan memerlukan fungsi implementation. Fungsi ini dijalankan secara ketat dalam fase analisis dan mengubah grafik target yang dihasilkan dalam fase pemuatan menjadi grafik tindakan yang akan dilakukan selama fase eksekusi. Dengan demikian, fungsi implementasi tidak dapat benar-benar membaca atau menulis file.

Fungsi penerapan aturan biasanya bersifat pribadi (diberi nama dengan garis bawah di awal). Secara konvensional, nama tersebut sama dengan aturannya, tetapi diakhiri dengan _impl.

Fungsi implementasi mengambil satu parameter: konteks aturan, yang secara konvensional bernama ctx. Permintaan tersebut menampilkan daftar penyedia.

Targets

Dependensi diwakili pada waktu analisis sebagai objek Target. Objek ini berisi penyedia yang dihasilkan saat fungsi implementasi target dieksekusi.

ctx.attr memiliki kolom yang sesuai dengan nama setiap atribut dependensi, yang berisi objek Target yang mewakili setiap dependensi langsung melalui atribut tersebut. Untuk atribut label_list, ini adalah daftar Targets. Untuk atribut label, ini adalah Target atau None tunggal.

Daftar objek penyedia ditampilkan oleh fungsi implementasi target:

return [ExampleInfo(headers = depset(...))]

Variabel tersebut dapat diakses menggunakan notasi indeks ([]), dengan jenis penyedia sebagai kunci. Ini dapat berupa penyedia kustom yang ditentukan di Starlark atau penyedia untuk aturan native yang tersedia sebagai variabel global Starlark.

Misalnya, jika aturan mengambil file header melalui atribut hdrs dan memberikannya ke tindakan kompilasi target dan konsumennya, aturan tersebut dapat mengumpulkannya seperti berikut:

def _example_library_impl(ctx):
    ...
    transitive_headers = [hdr[ExampleInfo].headers for hdr in ctx.attr.hdrs]

Untuk gaya lama tempat struct ditampilkan dari fungsi penerapan target, bukan daftar objek penyedia:

return struct(example_info = struct(headers = depset(...)))

Penyedia dapat diambil dari kolom objek Target yang sesuai:

transitive_headers = [hdr.example_info.headers for hdr in ctx.attr.hdrs]

Gaya ini sangat tidak disarankan dan aturan harus dimigrasikan darinya.

File

File direpresentasikan oleh objek File. Karena Bazel tidak melakukan file I/O selama fase analisis, objek ini tidak dapat digunakan untuk membaca atau menulis konten file secara langsung. Sebaliknya, elemen ini diteruskan ke fungsi yang memunculkan tindakan (lihat ctx.actions) untuk membuat grafik tindakan.

File dapat berupa file sumber atau file yang dihasilkan. Setiap file yang dihasilkan harus berupa output dari satu tindakan. File sumber tidak boleh berupa output tindakan apa pun.

Untuk setiap atribut dependensi, kolom ctx.files yang sesuai berisi daftar output default semua dependensi melalui atribut tersebut:

def _example_library_impl(ctx):
    ...
    headers = depset(ctx.files.hdrs, transitive=transitive_headers)
    srcs = ctx.files.srcs
    ...

ctx.file berisi satu File atau None untuk atribut dependensi yang spesifikasinya menetapkan allow_single_file=True. ctx.executable berperilaku sama seperti ctx.file, tetapi hanya berisi kolom untuk atribut dependensi yang spesifikasinya menetapkan executable=True.

Mendeklarasikan output

Selama fase analisis, fungsi implementasi aturan dapat membuat output. Karena semua label harus diketahui selama fase pemuatan, output tambahan ini tidak memiliki label. Objek File untuk output dapat dibuat menggunakan ctx.actions.declare_file dan ctx.actions.declare_directory. Sering kali, nama output didasarkan pada nama target, ctx.label.name:

def _example_library_impl(ctx):
  ...
  output_file = ctx.actions.declare_file(ctx.label.name + ".output")
  ...

Untuk output yang dideklarasikan sebelumnya, seperti yang dibuat untuk atribut output, objek File sebagai gantinya dapat diambil dari kolom ctx.outputs yang sesuai.

Tindakan

Tindakan menjelaskan cara menghasilkan satu kumpulan output dari sekumpulan input, misalnya "jalankan gcc di hello.c dan dapatkan hello.o". Saat tindakan dibuat, Bazel tidak akan langsung menjalankan perintah. Peristiwa ini mendaftarkannya dalam grafik dependensi, karena suatu tindakan dapat bergantung pada output tindakan lain. Misalnya, di C, penaut harus dipanggil setelah compiler.

Fungsi tujuan umum yang membuat tindakan ditentukan dalam ctx.actions:

• ctx.actions.run, untuk menjalankan file yang dapat dieksekusi.
• ctx.actions.run_shell, untuk menjalankan perintah shell.
• ctx.actions.write, untuk menulis string ke file.
• ctx.actions.expand_template, untuk membuat file dari template.

ctx.actions.args dapat digunakan untuk mengakumulasi argumen untuk tindakan secara efisien. Hal ini untuk menghindari depset yang diratakan hingga waktu eksekusi:

def _example_library_impl(ctx):
    ...

    transitive_headers = [dep[ExampleInfo].headers for dep in ctx.attr.deps]
    headers = depset(ctx.files.hdrs, transitive=transitive_headers)
    srcs = ctx.files.srcs
    inputs = depset(srcs, transitive=[headers])
    output_file = ctx.actions.declare_file(ctx.label.name + ".output")

    args = ctx.actions.args()
    args.add_joined("-h", headers, join_with=",")
    args.add_joined("-s", srcs, join_with=",")
    args.add("-o", output_file)

    ctx.actions.run(
        mnemonic = "ExampleCompile",
        executable = ctx.executable._compiler,
        arguments = [args],
        inputs = inputs,
        outputs = [output_file],
    )
    ...

Tindakan mengambil daftar atau dependensi file input dan membuat daftar file output (yang tidak kosong). Kumpulan file input dan output harus diketahui selama fase analisis. Hal ini mungkin bergantung pada nilai atribut, termasuk penyedia dari dependensi, tetapi tidak dapat bergantung pada hasil eksekusi. Misalnya, jika tindakan menjalankan perintah unzip, Anda harus menentukan file mana yang akan di-inflate (sebelum menjalankan unzip). Tindakan yang membuat sejumlah variabel file secara internal dapat menggabungkan beberapa file tersebut dalam satu file (seperti zip, tar, atau format arsip lainnya).

Tindakan harus mencantumkan semua inputnya. Input daftar yang tidak digunakan diizinkan, tetapi tidak efisien.

Tindakan harus membuat semua outputnya. Mereka dapat menulis file lain, tetapi apa pun yang tidak ada dalam output tidak akan tersedia bagi konsumen. Semua output yang dideklarasikan harus ditulis oleh beberapa tindakan.

Tindakan sebanding dengan fungsi murni: Tindakan hanya boleh bergantung pada input yang disediakan, dan tidak mengakses informasi komputer, nama pengguna, jam, jaringan, atau perangkat I/O (kecuali untuk membaca input dan menulis output). Hal ini penting karena output akan di-cache dan digunakan kembali.

Dependensi diselesaikan oleh Bazel, yang akan menentukan tindakan mana yang dieksekusi. Ini merupakan error jika ada siklus dalam grafik dependensi. Membuat tindakan tidak menjamin bahwa tindakan akan dijalankan, yang bergantung pada apakah outputnya diperlukan untuk build.

Penyedia

Penyedia adalah bagian informasi yang diekspos oleh aturan ke aturan lain yang bergantung padanya. Data ini dapat mencakup file output, library, parameter yang akan diteruskan pada command line alat, atau apa pun yang harus diketahui oleh konsumen target.

Karena fungsi implementasi aturan hanya dapat membaca penyedia dari dependensi langsung target yang dibuat instance-nya, aturan harus meneruskan informasi apa pun dari dependensi target yang perlu diketahui oleh konsumen target, umumnya dengan mengumpulkannya menjadi depset.

Penyedia target ditentukan oleh daftar objek Provider yang ditampilkan oleh fungsi implementasi.

Fungsi implementasi lama juga dapat ditulis dalam gaya lama, di mana fungsi implementasi menampilkan struct, bukan daftar objek penyedia. Gaya ini sangat tidak disarankan dan aturan harus dimigrasikan darinya.

Output default

Output default target adalah output yang diminta secara default saat target diminta untuk build pada command line. Misalnya, target //pkg:foo java_library memiliki foo.jar sebagai output default, sehingga akan dibuat oleh perintah bazel build //pkg:foo.

Output default ditentukan oleh parameter files dari DefaultInfo:

def _example_library_impl(ctx):
    ...
    return [
        DefaultInfo(files = depset([output_file]), ...),
        ...
    ]

Jika DefaultInfo tidak ditampilkan oleh implementasi aturan atau parameter files tidak ditentukan, DefaultInfo.files akan ditetapkan secara default ke semua output yang dideklarasikan sebelumnya (umumnya, yang dibuat oleh atribut output).

Aturan yang melakukan tindakan harus menyediakan output default, meskipun output tersebut tidak diharapkan untuk langsung digunakan. Tindakan yang tidak ada dalam grafik output yang diminta akan dipangkas. Jika output hanya digunakan oleh konsumen target, tindakan tersebut tidak akan dilakukan saat target dibuat secara terpisah. Hal ini membuat proses debug lebih sulit karena membuat ulang target yang gagal tidak akan mereproduksi kegagalan.

File run

Runfile adalah kumpulan file yang digunakan oleh target pada runtime (bukan waktu build). Selama fase eksekusi, Bazel membuat hierarki direktori yang berisi symlink yang mengarah ke runfile. Tindakan ini membuat lingkungan untuk biner sehingga dapat mengakses runfile selama runtime.

Runfile dapat ditambahkan secara manual selama pembuatan aturan. Objek runfiles dapat dibuat dengan metode runfiles di konteks aturan, ctx.runfiles dan diteruskan ke parameter runfiles di DefaultInfo. Output yang dapat dieksekusi dari aturan yang dapat dieksekusi secara implisit ditambahkan ke runfile.

Beberapa aturan menentukan atribut, umumnya bernama data, yang output-nya ditambahkan ke runfile target. Runfile juga harus digabungkan dari data, serta dari atribut apa pun yang dapat memberikan kode untuk eksekusi akhir, umumnya srcs (yang mungkin berisi target filegroup dengan data terkait) dan deps.

def _example_library_impl(ctx):
    ...
    runfiles = ctx.runfiles(files = ctx.files.data)
    transitive_runfiles = []
    for runfiles_attr in (
        ctx.attr.srcs,
        ctx.attr.hdrs,
        ctx.attr.deps,
        ctx.attr.data,
    ):
        for target in runfiles_attr:
            transitive_runfiles.append(target[DefaultInfo].default_runfiles)
    runfiles = runfiles.merge_all(transitive_runfiles)
    return [
        DefaultInfo(..., runfiles = runfiles),
        ...
    ]

Penyedia kustom

Penyedia dapat ditentukan menggunakan fungsi provider untuk menyampaikan informasi khusus aturan:

ExampleInfo = provider(
    "Info needed to compile/link Example code.",
    fields={
        "headers": "depset of header Files from transitive dependencies.",
        "files_to_link": "depset of Files from compilation.",
    })

Fungsi penerapan aturan kemudian dapat membuat dan menampilkan instance penyedia:

def _example_library_impl(ctx):
  ...
  return [
      ...
      ExampleInfo(
          headers = headers,
          files_to_link = depset(
              [output_file],
              transitive = [
                  dep[ExampleInfo].files_to_link for dep in ctx.attr.deps
              ],
          ),
      )
  ]

Inisialisasi kustom penyedia

Anda dapat melindungi pembuatan instance penyedia dengan logika pra-pemrosesan dan validasi kustom. Hal ini dapat digunakan untuk memastikan bahwa semua instance penyedia mematuhi invarian tertentu, atau memberikan API yang lebih bersih kepada pengguna untuk mendapatkan instance.

Hal ini dilakukan dengan meneruskan callback init ke fungsi provider. Jika callback ini diberikan, jenis nilai yang ditampilkan provider() akan berubah menjadi tuple dari dua nilai: simbol penyedia yang merupakan nilai return biasa ketika init tidak digunakan, dan "konstruktor mentah".

Dalam hal ini, saat simbol penyedia dipanggil, peristiwa akan meneruskan argumen ke callback init, bukan langsung menampilkan instance baru. Nilai callback callback harus berupa nama kolom pemetaan (string) ke nilai; nilai ini digunakan untuk menginisialisasi kolom instance baru. Perhatikan bahwa callback mungkin memiliki tanda tangan apa pun, dan jika argumen tidak cocok dengan tanda tangan, error akan dilaporkan seolah-olah callback dipanggil secara langsung.

Sebaliknya, konstruktor mentah akan mengabaikan callback init.

Contoh berikut menggunakan init untuk melakukan pra-proses dan memvalidasi argumennya:

# //pkg:exampleinfo.bzl

_core_headers = [...]  # private constant representing standard library files

# It's possible to define an init accepting positional arguments, but
# keyword-only arguments are preferred.
def _exampleinfo_init(*, files_to_link, headers = None, allow_empty_files_to_link = False):
    if not files_to_link and not allow_empty_files_to_link:
        fail("files_to_link may not be empty")
    all_headers = depset(_core_headers, transitive = headers)
    return {'files_to_link': files_to_link, 'headers': all_headers}

ExampleInfo, _new_exampleinfo = provider(
    ...
    init = _exampleinfo_init)

export ExampleInfo

Implementasi aturan kemudian dapat membuat instance penyedia sebagai berikut:

    ExampleInfo(
        files_to_link=my_files_to_link,  # may not be empty
        headers = my_headers,  # will automatically include the core headers
    )

Konstruktor mentah dapat digunakan untuk menentukan fungsi factory publik alternatif yang tidak melalui logika init. Misalnya, dalam exampleinfo.bzl, kita dapat menentukan:

def make_barebones_exampleinfo(headers):
    """Returns an ExampleInfo with no files_to_link and only the specified headers."""
    return _new_exampleinfo(files_to_link = depset(), headers = all_headers)

Biasanya, konstruktor mentah terikat ke variabel yang namanya dimulai dengan garis bawah (_new_exampleinfo di atas), sehingga kode pengguna tidak dapat memuatnya dan menghasilkan instance penyedia arbitrer.

Penggunaan lain untuk init adalah hanya untuk mencegah pengguna memanggil simbol penyedia secara keseluruhan, dan memaksanya untuk menggunakan fungsi factory:

def _exampleinfo_init_banned(*args, **kwargs):
    fail("Do not call ExampleInfo(). Use make_exampleinfo() instead.")

ExampleInfo, _new_exampleinfo = provider(
    ...
    init = _exampleinfo_init_banned)

def make_exampleinfo(...):
    ...
    return _new_exampleinfo(...)

Aturan yang dapat dieksekusi dan aturan pengujian

Aturan yang dapat dieksekusi menentukan target yang dapat dipanggil dengan perintah bazel run. Aturan pengujian adalah jenis aturan khusus yang dapat dijalankan yang targetnya juga dapat dipanggil dengan perintah bazel test. Aturan yang dapat dieksekusi dan pengujian dibuat dengan menyetel argumen executable atau test masing-masing ke True dalam panggilan ke rule:

example_binary = rule(
   implementation = _example_binary_impl,
   executable = True,
   ...
)

example_test = rule(
   implementation = _example_binary_impl,
   test = True,
   ...
)

Aturan pengujian harus memiliki nama yang diakhiri dengan _test. (Nama target pengujian juga sering kali diakhiri dengan _test berdasarkan konvensi, tetapi tidak wajib). Aturan non-pengujian tidak boleh memiliki akhiran ini.

Kedua jenis aturan harus menghasilkan file output yang dapat dieksekusi (yang dapat atau tidak dideklarasikan sebelumnya) yang akan dipanggil oleh perintah run atau test. Untuk memberi tahu Bazel mana dari output aturan yang akan digunakan sebagai file yang dapat dieksekusi ini, teruskan sebagai argumen executable dari penyedia DefaultInfo yang ditampilkan. executable tersebut ditambahkan ke output default aturan (sehingga Anda tidak perlu meneruskannya ke executable dan files). Ini juga secara implisit ditambahkan ke runfile:

def _example_binary_impl(ctx):
    executable = ctx.actions.declare_file(ctx.label.name)
    ...
    return [
        DefaultInfo(executable = executable, ...),
        ...
    ]

Tindakan yang menghasilkan file ini harus menetapkan bit yang dapat dieksekusi pada file. Untuk tindakan ctx.actions.run atau ctx.actions.run_shell, tindakan ini harus dilakukan oleh alat dasar yang dipanggil oleh tindakan. Untuk tindakan ctx.actions.write, teruskan is_executable=True.

Sebagai perilaku lama, aturan yang dapat dieksekusi memiliki output khusus ctx.outputs.executable yang telah dideklarasikan sebelumnya. File ini berfungsi sebagai file yang dapat dieksekusi default jika Anda tidak menentukannya menggunakan DefaultInfo; file tidak boleh digunakan sebaliknya. Mekanisme output ini tidak digunakan lagi karena tidak mendukung penyesuaian nama file yang dapat dieksekusi pada waktu analisis.

Lihat contoh aturan yang dapat dieksekusi dan aturan pengujian.

Aturan yang dapat dieksekusi dan aturan pengujian memiliki atribut tambahan yang ditentukan secara implisit, selain yang ditambahkan untuk semua aturan. Default atribut yang ditambahkan secara implisit tidak dapat diubah, meskipun hal ini dapat diatasi dengan menggabungkan aturan pribadi dalam makro Starlar yang mengubah default:

def example_test(size="small", **kwargs):
  _example_test(size=size, **kwargs)

_example_test = rule(
 ...
)

Lokasi runfile

Saat target yang dapat dieksekusi dijalankan dengan bazel run (atau test), root direktori runfile berdekatan dengan file yang dapat dieksekusi. Jalurnya berhubungan sebagai berikut:

# Given launcher_path and runfile_file:
runfiles_root = launcher_path.path + ".runfiles"
workspace_name = ctx.workspace_name
runfile_path = runfile_file.short_path
execution_root_relative_path = "%s/%s/%s" % (
    runfiles_root, workspace_name, runfile_path)

Jalur ke File pada direktori runfiles sesuai dengan File.short_path.

Biner yang dieksekusi secara langsung oleh bazel berdekatan dengan root direktori runfiles. Namun, biner yang disebut dari runfile tidak dapat membuat asumsi yang sama. Untuk mengurangi hal ini, setiap biner harus menyediakan cara untuk menyetujui root runfile-nya sebagai parameter menggunakan argumen/flag command line atau lingkungan. Hal ini memungkinkan biner untuk meneruskan root runfile kanonis yang benar ke biner yang dipanggilnya. Jika tidak disetel, biner dapat menebak bahwa biner tersebut adalah biner pertama yang dipanggil dan mencari direktori runfile yang berdekatan.

Topik lanjutan

Meminta file output

Satu target dapat memiliki beberapa file output. Saat perintah bazel build dijalankan, beberapa output dari target yang diberikan ke perintah dianggap diminta. Bazel hanya mem-build file yang diminta dan file yang menjadi dependensinya secara langsung atau tidak langsung. (Dalam hal grafik tindakan, Bazel hanya menjalankan tindakan yang dapat dijangkau sebagai dependensi transitif dari file yang diminta.)

Selain output default, setiap output yang dideklarasikan sebelumnya dapat diminta secara eksplisit di command line. Aturan dapat menentukan output yang telah dideklarasikan sebelumnya melalui atribut output. Dalam hal ini, pengguna secara eksplisit memilih label untuk output saat membuat instance aturan. Guna mendapatkan objek File untuk atribut output, gunakan atribut yang sesuai dari ctx.outputs. Aturan dapat secara implisit menentukan output yang telah dideklarasikan sebelumnya berdasarkan nama target, tetapi fitur ini tidak digunakan lagi.

Selain output default, ada grup output, yang merupakan kumpulan file output yang dapat diminta bersama. Permintaan ini dapat diminta dengan --output_groups. Misalnya, jika //pkg:mytarget target adalah jenis aturan yang memiliki grup output debug_files, file ini dapat di-build dengan menjalankan bazel build //pkg:mytarget --output_groups=debug_files. Karena output yang tidak dideklarasikan tidak memiliki label, output hanya dapat diminta dengan muncul di output default atau grup output.

Grup output dapat ditentukan dengan penyedia OutputGroupInfo. Perhatikan bahwa tidak seperti banyak penyedia bawaan, OutputGroupInfo dapat mengambil parameter dengan nama arbitrer untuk menentukan grup output dengan nama tersebut:

def _example_library_impl(ctx):
    ...
    debug_file = ctx.actions.declare_file(name + ".pdb")
    ...
    return [
        DefaultInfo(files = depset([output_file]), ...),
        OutputGroupInfo(
            debug_files = depset([debug_file]),
            all_files = depset([output_file, debug_file]),
        ),
        ...
    ]

Selain itu, tidak seperti sebagian besar penyedia, OutputGroupInfo dapat ditampilkan oleh aspek dan target aturan yang menerapkan aspek tersebut, selama tidak menentukan grup output yang sama. Pada kasus ini, penyedia yang dihasilkan akan digabungkan.

Perhatikan bahwa OutputGroupInfo umumnya tidak boleh digunakan untuk menyampaikan jenis file tertentu dari target ke tindakan konsumennya. Sebagai gantinya, tentukan penyedia khusus aturan.

Konfigurasi

Bayangkan Anda ingin membuat biner C++ untuk arsitektur yang berbeda. Build dapat menjadi kompleks dan melibatkan beberapa langkah. Beberapa biner perantara, seperti compiler dan generator kode, harus berjalan di platform eksekusi (yang dapat berupa host Anda, atau eksekutor jarak jauh). Beberapa biner seperti output akhir harus dibuat untuk arsitektur target.

Karena alasan ini, Bazel memiliki konsep "konfigurasi" dan transisi. Target teratas (yang diminta pada command line) dibuat dalam konfigurasi "target", sedangkan alat yang harus berjalan di platform eksekusi dibuat dalam konfigurasi "exec". Aturan dapat menghasilkan tindakan berbeda berdasarkan konfigurasi, misalnya untuk mengubah arsitektur cpu yang diteruskan ke compiler. Dalam beberapa kasus, library yang sama mungkin diperlukan untuk konfigurasi yang berbeda. Jika hal ini terjadi, model akan dianalisis dan berpotensi dibuat beberapa kali.

Secara default, Bazel membuat dependensi target dalam konfigurasi yang sama seperti target itu sendiri, dengan kata lain tanpa transisi. Jika dependensi adalah alat yang diperlukan untuk membantu mem-build target, atribut yang sesuai harus menentukan transisi ke konfigurasi eksekutif. Hal ini menyebabkan alat tersebut dan semua dependensinya di-build untuk platform eksekusi.

Untuk setiap atribut dependensi, Anda dapat menggunakan cfg untuk menentukan apakah dependensi harus dibuat dalam konfigurasi yang sama atau bertransisi ke konfigurasi eksekutif. Jika atribut dependensi memiliki flag executable=True, cfg harus ditetapkan secara eksplisit. Langkah ini dilakukan untuk melindungi alat dari konfigurasi yang salah secara tidak sengaja. Lihat contoh

Secara umum, sumber, library dependen, dan file yang dapat dieksekusi yang diperlukan saat runtime dapat menggunakan konfigurasi yang sama.

Alat yang dijalankan sebagai bagian dari build (seperti compiler atau generator kode) harus dibuat untuk konfigurasi exec. Dalam hal ini, tentukan cfg="exec" dalam atribut.

Jika tidak, file yang dapat dieksekusi yang digunakan saat runtime (seperti sebagai bagian dari pengujian) harus dibuat untuk konfigurasi target. Dalam hal ini, tentukan cfg="target" dalam atribut.

cfg="target" sebenarnya tidak melakukan apa pun: ini hanyalah nilai kemudahan untuk membantu desainer aturan bersikap eksplisit tentang niat mereka. Jika executable=False, yang berarti cfg bersifat opsional, hanya setel atribut ini jika benar-benar membantu meningkatkan keterbacaan.

Anda juga dapat menggunakan cfg=my_transition untuk menggunakan transisi yang ditentukan pengguna, yang memungkinkan penulis aturan memiliki fleksibilitas dalam mengubah konfigurasi, dengan kekurangan membuat grafik build lebih besar dan kurang mudah dipahami.

Catatan: Secara historis, Bazel tidak memiliki konsep platform eksekusi, dan sebagai gantinya, semua tindakan build dianggap berjalan di mesin host. Versi Bazel sebelum 6.0 membuat konfigurasi "host" yang berbeda untuk merepresentasikan hal ini. Jika Anda melihat referensi ke "host" dalam kode atau dokumentasi lama, itulah yang dimaksud. Sebaiknya gunakan Bazel 6.0 atau yang lebih baru untuk menghindari overhead konseptual tambahan ini.

Fragmen konfigurasi

Aturan dapat mengakses fragmen konfigurasi seperti cpp, java, dan jvm. Namun, semua fragmen yang diperlukan harus dideklarasikan untuk menghindari error akses:

def _impl(ctx):
    # Using ctx.fragments.cpp leads to an error since it was not declared.
    x = ctx.fragments.java
    ...

my_rule = rule(
    implementation = _impl,
    fragments = ["java"],      # Required fragments of the target configuration
    host_fragments = ["java"], # Required fragments of the host configuration
    ...
)

symlink runfile

Biasanya, jalur relatif file di hierarki runfile sama dengan jalur relatif file tersebut di hierarki sumber atau hierarki output yang dihasilkan. Jika perbedaan ini perlu berbeda karena beberapa alasan, Anda dapat menentukan argumen root_symlinks atau symlinks. root_symlinks adalah kamus yang memetakan jalur ke file, dengan jalur tersebut relatif terhadap root direktori runfiles. Kamus symlinks sama, tetapi jalur diawali secara implisit dengan nama ruang kerja.

    ...
    runfiles = ctx.runfiles(
        root_symlinks = {"some/path/here.foo": ctx.file.some_data_file2}
        symlinks = {"some/path/here.bar": ctx.file.some_data_file3}
    )
    # Creates something like:
    # sometarget.runfiles/
    #     some/
    #         path/
    #             here.foo -> some_data_file2
    #     <workspace_name>/
    #         some/
    #             path/
    #                 here.bar -> some_data_file3

Jika symlinks atau root_symlinks digunakan, berhati-hatilah untuk tidak memetakan dua file yang berbeda ke jalur yang sama di hierarki runfiles. Ini akan menyebabkan build gagal dengan error yang menjelaskan konflik. Untuk memperbaikinya, Anda harus memodifikasi argumen ctx.runfiles untuk menghapus konflik. Pemeriksaan ini akan dilakukan untuk target apa pun yang menggunakan aturan, serta target apa pun yang bergantung pada target tersebut. Hal ini sangat berisiko jika alat Anda kemungkinan akan digunakan secara transitif oleh alat lain; nama symlink harus unik di seluruh file run alat dan semua dependensinya.

Cakupan kode

Saat perintah coverage dijalankan, build mungkin perlu menambahkan instrumentasi cakupan untuk target tertentu. Build juga mengumpulkan daftar file sumber yang diinstrumentasikan. Subkumpulan target yang dipertimbangkan dikontrol oleh flag --instrumentation_filter. Target pengujian dikecualikan, kecuali --instrument_test_targets ditentukan.

Jika implementasi aturan menambahkan instrumentasi cakupan pada waktu build, implementasi aturan tersebut harus memperhitungkan hal tersebut dalam fungsi implementasinya. ctx.coverage_instrumented menampilkan true dalam mode cakupan jika sumber target harus diinstrumentasi:

# Are this rule's sources instrumented?
if ctx.coverage_instrumented():
  # Do something to turn on coverage for this compile action

Logika yang harus selalu aktif dalam mode cakupan (baik sumber yang ditarget secara khusus maupun tidak) dapat dikondisikan pada ctx.configuration.coverage_enabled.

Jika aturan secara langsung menyertakan sumber dari dependensinya sebelum kompilasi (seperti file header), aturan ini mungkin juga perlu mengaktifkan instrumentasi waktu kompilasi jika sumber dependensi harus diinstrumentasi:

# Are this rule's sources or any of the sources for its direct dependencies
# in deps instrumented?
if (ctx.configuration.coverage_enabled and
    (ctx.coverage_instrumented() or
     any([ctx.coverage_instrumented(dep) for dep in ctx.attr.deps]))):
    # Do something to turn on coverage for this compile action

Aturan juga harus memberikan informasi tentang atribut mana yang relevan untuk cakupan dengan penyedia InstrumentedFilesInfo, yang dibuat menggunakan coverage_common.instrumented_files_info. Parameter dependency_attributes dari instrumented_files_info harus mencantumkan semua atribut dependensi runtime, termasuk dependensi kode seperti deps dan dependensi data seperti data. Parameter source_attributes harus mencantumkan atribut file sumber aturan tersebut jika instrumentasi cakupan dapat ditambahkan:

def _example_library_impl(ctx):
    ...
    return [
        ...
        coverage_common.instrumented_files_info(
            ctx,
            dependency_attributes = ["deps", "data"],
            # Omitted if coverage is not supported for this rule:
            source_attributes = ["srcs", "hdrs"],
        )
        ...
    ]

Jika InstrumentedFilesInfo tidak ditampilkan, atribut default akan dibuat dengan setiap atribut dependensi non-alat yang tidak menetapkan cfg ke "host" atau "exec" dalam skema atribut) di dependency_attributes. (Ini bukan perilaku yang ideal, karena menempatkan atribut seperti srcs di dependency_attributes dan bukan source_attributes, tetapi menghindari kebutuhan akan konfigurasi cakupan eksploitasi untuk semua aturan dalam rantai dependensi.)

Tindakan Validasi

Terkadang Anda perlu memvalidasi sesuatu terkait build, dan informasi yang diperlukan untuk melakukan validasi tersebut hanya tersedia dalam artefak (file sumber atau file yang dihasilkan). Karena informasi ini masih dalam artefak, aturan tidak dapat melakukan validasi ini pada waktu analisis karena aturan tidak dapat membaca file. Sebagai gantinya, tindakan harus melakukan validasi ini pada waktu eksekusi. Jika validasi gagal, tindakan akan gagal, sehingga build akan terjadi.

Contoh validasi yang mungkin dijalankan adalah analisis statis, analisis lint, dependensi dan pemeriksaan konsistensi, serta pemeriksaan gaya.

Tindakan validasi juga dapat membantu meningkatkan performa build dengan memindahkan bagian dari tindakan yang tidak diperlukan untuk membuat artefak ke dalam tindakan terpisah. Misalnya, jika satu tindakan yang melakukan kompilasi dan analisis lint dapat dipisahkan menjadi tindakan kompilasi dan tindakan analisis lint, tindakan analisis lint dapat dijalankan sebagai tindakan validasi dan dijalankan secara paralel dengan tindakan lainnya.

"Tindakan validasi" ini sering kali tidak menghasilkan apa pun yang digunakan di tempat lain dalam build, karena hanya perlu menyatakan hal-hal tentang input mereka. Namun, hal ini menimbulkan masalah: Jika tindakan validasi tidak menghasilkan apa pun yang digunakan di tempat lain dalam build, bagaimana cara aturan mendapatkan tindakan tersebut untuk dijalankan? Secara historis, pendekatannya adalah memiliki tindakan validasi yang menghasilkan file kosong, dan menambahkan output tersebut ke input beberapa tindakan penting lainnya dalam build secara buatan:

Ini berfungsi, karena Bazel akan selalu menjalankan tindakan validasi saat tindakan kompilasi dijalankan, tetapi memiliki kelemahan yang signifikan:

1. Tindakan validasi berada di jalur penting build. Karena Bazel menganggap output kosong diperlukan untuk menjalankan tindakan kompilasi, output akan menjalankan tindakan validasi terlebih dahulu, meskipun tindakan kompilasi akan mengabaikan input. Hal ini mengurangi paralelisme dan memperlambat build.

2. Jika tindakan lain dalam build mungkin berjalan, bukan tindakan kompilasi, maka output kosong dari tindakan validasi juga perlu ditambahkan ke tindakan tersebut (misalnya, output jar sumber java_library). Hal ini juga menjadi masalah jika tindakan baru yang mungkin berjalan, bukan tindakan kompilasi, akan ditambahkan nanti, dan output validasi kosong tidak sengaja ditinggalkan.

Solusi untuk masalah ini adalah dengan menggunakan Grup Output Validasi.

Grup Output Validasi

Grup Output Validasi adalah grup output yang dirancang untuk menyimpan output tindakan validasi yang tidak digunakan, sehingga tidak perlu ditambahkan secara artifisial ke input tindakan lain.

Grup ini khusus karena outputnya selalu diminta, terlepas dari nilai flag --output_groups, dan terlepas dari bagaimana dependensi bergantung pada (misalnya, pada command line, sebagai dependensi, atau melalui output implisit dari target). Perhatikan bahwa caching normal dan inkrementalitas tetap berlaku: jika input ke tindakan validasi tidak berubah dan tindakan validasi sebelumnya berhasil, tindakan validasi tidak akan dijalankan.

Penggunaan grup output ini tetap mewajibkan tindakan validasi menghasilkan beberapa file, bahkan file kosong. Hal ini mungkin memerlukan penggabungan beberapa alat yang biasanya tidak membuat output agar file dapat dibuat.

Tindakan validasi target tidak dijalankan dalam tiga kasus:

• Saat target diandalkan sebagai alat
• Jika target diandalkan sebagai dependensi implisit (misalnya, atribut yang diawali dengan "_")
• Saat target dibuat di konfigurasi host atau exec.

Diasumsikan bahwa target ini memiliki build dan pengujiannya sendiri yang terpisah yang akan mengungkap kegagalan validasi.

Menggunakan Grup Output Validasi

Grup Output Validasi bernama _validation dan digunakan seperti grup output lainnya:

def _rule_with_validation_impl(ctx):

  ctx.actions.write(ctx.outputs.main, "main output\n")

  ctx.actions.write(ctx.outputs.implicit, "implicit output\n")

  validation_output = ctx.actions.declare_file(ctx.attr.name + ".validation")
  ctx.actions.run(
      outputs = [validation_output],
      executable = ctx.executable._validation_tool,
      arguments = [validation_output.path])

  return [
    DefaultInfo(files = depset([ctx.outputs.main])),
    OutputGroupInfo(_validation = depset([validation_output])),
  ]


rule_with_validation = rule(
  implementation = _rule_with_validation_impl,
  outputs = {
    "main": "%{name}.main",
    "implicit": "%{name}.implicit",
  },
  attrs = {
    "_validation_tool": attr.label(
        default = Label("//validation_actions:validation_tool"),
        executable = True,
        cfg = "exec"),
  }
)

Perhatikan bahwa file output validasi tidak ditambahkan ke DefaultInfo atau input ke tindakan lainnya. Tindakan validasi untuk target jenis aturan ini akan tetap berjalan jika target tersebut bergantung pada label, atau output implisit dari target tersebut bergantung secara langsung atau tidak langsung.

Biasanya penting, output tindakan validasi hanya masuk ke grup output validasi, dan tidak ditambahkan ke input tindakan lain, karena dapat mengalahkan perolehan paralelisme. Namun, perlu diketahui bahwa Bazel saat ini tidak memiliki pemeriksaan khusus untuk menerapkannya. Oleh karena itu, Anda harus menguji bahwa output tindakan validasi tidak ditambahkan ke input tindakan apa pun dalam pengujian untuk aturan Starlark. Contoh:

load("@bazel_skylib//lib:unittest.bzl", "analysistest")

def _validation_outputs_test_impl(ctx):
  env = analysistest.begin(ctx)

  actions = analysistest.target_actions(env)
  target = analysistest.target_under_test(env)
  validation_outputs = target.output_groups._validation.to_list()
  for action in actions:
    for validation_output in validation_outputs:
      if validation_output in action.inputs.to_list():
        analysistest.fail(env,
            "%s is a validation action output, but is an input to action %s" % (
                validation_output, action))

  return analysistest.end(env)

validation_outputs_test = analysistest.make(_validation_outputs_test_impl)

Tanda Tindakan Validasi

Menjalankan tindakan validasi dikontrol oleh flag command line --run_validations, yang secara default disetel ke benar (true).

Fitur yang tidak digunakan lagi

Output yang dideklarasikan sebelumnya tidak digunakan lagi

Ada dua cara untuk menghentikan penggunaan output yang telah dideklarasikan sebelumnya:

• Parameter outputs dari rule menentukan pemetaan antara nama atribut output dan template string untuk menghasilkan label output yang telah dideklarasikan sebelumnya. Memilih menggunakan output yang tidak dideklarasikan sebelumnya dan menambahkan output secara eksplisit ke DefaultInfo.files. Gunakan label target aturan sebagai input untuk aturan yang menggunakan output, bukan label output yang telah dideklarasikan sebelumnya.

• Untuk aturan yang dapat dieksekusi, ctx.outputs.executable mengacu pada output yang dapat dieksekusi yang telah dideklarasikan sebelumnya dengan nama yang sama dengan target aturan. Pilih mendeklarasikan output secara eksplisit, misalnya dengan ctx.actions.declare_file(ctx.label.name), dan pastikan bahwa perintah yang membuat file yang dapat dieksekusi menetapkan izinnya untuk mengizinkan eksekusi. Secara eksplisit teruskan output yang dapat dieksekusi ke parameter executable dari DefaultInfo.

Fitur runfiles yang perlu dihindari

Jenis ctx.runfiles dan runfiles memiliki serangkaian fitur yang kompleks, banyak di antaranya disimpan untuk alasan lama. Rekomendasi berikut membantu mengurangi kompleksitas:

• Hindari penggunaan mode collect_data dan collect_default dari ctx.runfiles. Mode ini secara implisit mengumpulkan runfile di seluruh tepi dependensi hardcode tertentu dengan cara yang membingungkan. Sebagai gantinya, tambahkan file menggunakan parameter files atau transitive_files dari ctx.runfiles, atau dengan menggabungkan runfile dari dependensi dengan runfiles = runfiles.merge(dep[DefaultInfo].default_runfiles).

• Hindari penggunaan data_runfiles dan default_runfiles dari konstruktor DefaultInfo. Tentukan DefaultInfo(runfiles = ...) sebagai gantinya. Perbedaan antara runfile "default" dan "data" dipertahankan karena alasan lama. Misalnya, beberapa aturan menempatkan output default-nya di data_runfiles, tetapi tidak di default_runfiles. Daripada menggunakan data_runfiles, aturan harus keduanya menyertakan output default dan menggabungkan default_runfiles dari atribut yang menyediakan runfile (sering kali data).

• Saat mengambil runfiles dari DefaultInfo (umumnya hanya untuk menggabungkan runfile antara aturan saat ini dan dependensinya), gunakan DefaultInfo.default_runfiles, bukan DefaultInfo.data_runfiles.

Bermigrasi dari penyedia lama

Secara historis, penyedia Bazel adalah kolom sederhana pada objek Target. Aturan tersebut diakses menggunakan operator titik, dan dibuat dengan menempatkan kolom dalam struct yang ditampilkan oleh fungsi penerapan aturan.

Gaya ini tidak digunakan lagi dan tidak boleh digunakan dalam kode baru; lihat di bawah untuk mengetahui informasi yang dapat membantu Anda melakukan migrasi. Mekanisme penyedia yang baru menghindari konflik nama. Hal ini juga mendukung penyembunyian data, dengan mewajibkan kode apa pun yang mengakses instance penyedia untuk mengambilnya menggunakan simbol penyedia.

Untuk saat ini, penyedia lama masih didukung. Aturan dapat menampilkan penyedia lama dan modern seperti berikut:

def _old_rule_impl(ctx):
  ...
  legacy_data = struct(x="foo", ...)
  modern_data = MyInfo(y="bar", ...)
  # When any legacy providers are returned, the top-level returned value is a
  # struct.
  return struct(
      # One key = value entry for each legacy provider.
      legacy_info = legacy_data,
      ...
      # Additional modern providers:
      providers = [modern_data, ...])

Jika dep adalah objek Target yang dihasilkan untuk instance aturan ini, penyedia dan kontennya dapat diambil sebagai dep.legacy_info.x dan dep[MyInfo].y.

Selain providers, struct yang ditampilkan juga dapat menggunakan beberapa kolom lain yang memiliki arti khusus (sehingga tidak membuat penyedia lama yang sesuai):

• Kolom files, runfiles, data_runfiles, default_runfiles, dan executable sesuai dengan kolom bernama sama DefaultInfo. Anda tidak diizinkan untuk menentukan kolom ini sekaligus menampilkan penyedia DefaultInfo.

• Kolom output_groups menggunakan nilai struct dan sesuai dengan OutputGroupInfo.

Dalam deklarasi aturan provides, dan dalam deklarasi providers atribut dependensi, penyedia lama diteruskan sebagai string dan penyedia modern diteruskan dengan simbol *Info. Pastikan untuk mengubah dari string menjadi simbol saat melakukan migrasi. Untuk kumpulan aturan yang kompleks atau besar yang sulit untuk memperbarui semua aturan secara atomis, Anda mungkin memiliki waktu yang lebih mudah jika mengikuti urutan langkah-langkah ini:

1. Ubah aturan yang menghasilkan penyedia lama untuk menghasilkan penyedia lama dan modern, menggunakan sintaksis di atas. Untuk aturan yang mendeklarasikan penyedia tersebut menampilkan penyedia lama, perbarui deklarasi tersebut agar menyertakan penyedia lama dan modern.

2. Ubah aturan yang memakai penyedia lama agar menggunakan penyedia modern sebagai gantinya. Jika ada deklarasi atribut yang memerlukan penyedia lama, perbarui juga untuk mewajibkan penyedia modern. Secara opsional, Anda dapat menyisipkan tugas ini dengan langkah 1 dengan meminta konsumen menyetujui/memerlukan salah satu penyedia: Uji keberadaan penyedia lama menggunakan hasattr(target, 'foo'), atau penyedia baru menggunakan FooInfo in target.

3. Hapus penyedia lama sepenuhnya dari semua aturan.