Aturan Umum

Tetap teratur dengan koleksi Simpan dan kategorikan konten berdasarkan preferensi Anda.
Laporkan masalah Lihat sumber

Aturan

alias

Lihat sumber aturan
alias(name, actual, compatible_with, deprecation, features, restricted_to, tags, target_compatible_with, testonly, visibility)

Aturan alias membuat nama lain yang dapat disebut aturan.

Alias hanya berfungsi untuk target "biasa". Secara khusus, package_group dan test_suite tidak dapat dialiaskan.

Aturan alias memiliki deklarasi visibilitasnya sendiri. Dalam semua hal, perilaku ini berperilaku seperti aturan yang direferensikan (misalnya, hanya pengujian pada alias yang diabaikan; status "hanya pengujian" dari aturan yang direferensikan digunakan) dengan beberapa pengecualian kecil:

  • Pengujian tidak akan dijalankan jika aliasnya disebutkan pada command line. Untuk menentukan alias yang menjalankan pengujian yang direferensikan, gunakan aturan test_suite dengan satu target dalam atribut tests.
  • Saat menentukan grup lingkungan, alias ke aturan environment tidak didukung. Keduanya juga tidak didukung dalam opsi command line --target_environment.

Contoh

filegroup(
    name = "data",
    srcs = ["data.txt"],
)

alias(
    name = "other",
    actual = ":data",
)

Argumen

Atribut
name

Name; required

Nama unik untuk target ini.

actual

Label; required

Target yang dirujuk alias ini. Tidak perlu berupa aturan, tetapi juga dapat berupa file input.

konfigurasi_setelan

Lihat sumber aturan
config_setting(name, constraint_values, define_values, deprecation, distribs, features, flag_values, licenses, tags, testonly, values, visibility)

Mencocokkan status konfigurasi yang diharapkan (dinyatakan sebagai flag build atau batasan platform) untuk memicu pemicu atribut yang dapat dikonfigurasi. Baca bagian memilih cara menggunakan aturan ini dan Atribut yang dapat dikonfigurasi untuk ringkasan fitur umum.

Contoh

Berikut ini adalah build yang menetapkan --compilation_mode=opt atau -c opt (baik secara eksplisit pada command line atau secara implisit dari file .bazelrc):

  config_setting(
      name = "simple",
      values = {"compilation_mode": "opt"}
  )
  

Berikut adalah semua build yang menargetkan ARM dan menerapkan FOO=bar yang ditentukan secara khusus (misalnya, bazel build --cpu=arm --define FOO=bar ...):

  config_setting(
      name = "two_conditions",
      values = {
          "cpu": "arm",
          "define": "FOO=bar"
      }
  )
  

Berikut ini adalah build yang menetapkan flag yang ditentukan pengguna --//custom_flags:foo=1 (baik secara eksplisit di command line atau secara implisit dari file .bazelrc):

  config_setting(
      name = "my_custom_flag_is_set",
      flag_values = { "//custom_flags:foo": "1" },
  )
  

Berikut ini adalah build yang menargetkan platform dengan arsitektur x86_64 dan glibc versi 2.25, dengan asumsi adanya constraint_value dengan label //example:glibc_2_25. Perhatikan bahwa platform tetap cocok jika menentukan nilai batasan tambahan di luar keduanya.

  config_setting(
      name = "64bit_glibc_2_25",
      constraint_values = [
          "@platforms//cpu:x86_64",
          "//example:glibc_2_25",
      ]
  )
  
Dalam semua kasus ini, konfigurasi dapat berubah dalam build, misalnya jika target perlu dibuat untuk platform yang berbeda dari dependensinya. Artinya, meskipun config_setting tidak cocok dengan flag command line level teratas, flag ini mungkin masih cocok dengan beberapa target build.

Catatan

  • Lihat pilih untuk yang akan terjadi jika beberapa config_setting cocok dengan status konfigurasi saat ini.
  • Untuk flag yang mendukung formulir singkat (misalnya --compilation_mode vs. -c), definisi values harus menggunakan formulir lengkap. Ini akan otomatis mencocokkan pemanggilan menggunakan salah satu bentuk tersebut.
  • Jika flag mengambil beberapa nilai (seperti --copt=-Da --copt=-Db atau flag Starlark berjenis daftar), values = { "flag": "a" } akan cocok jika "a" ada di mana saja dalam daftar yang sebenarnya.

    values = { "myflag": "a,b" } berfungsi dengan cara yang sama: ini cocok dengan --myflag=a --myflag=b, --myflag=a --myflag=b --myflag=c, --myflag=a,b, dan --myflag=c,b,a. Semantik yang tepat bervariasi antar flag. Misalnya, --copt tidak mendukung banyak nilai dalam instance yang sama: --copt=a,b menghasilkan ["a,b"], sementara --copt=a --copt=b menghasilkan ["a", "b"] (sehingga values = { "copt": "a,b" } cocok dengan yang pertama, tetapi tidak yang kedua). Namun, --ios_multi_cpus (untuk aturan Apple) memang: -ios_multi_cpus=a,b dan ios_multi_cpus=a --ios_multi_cpus=b menghasilkan ["a", "b"]. Periksa definisi flag dan uji kondisi Anda dengan cermat untuk memverifikasi ekspektasi yang tepat.

  • Jika Anda perlu menentukan kondisi yang tidak dimodelkan oleh flag build bawaan, gunakan Flag yang ditentukan Starlark. Anda juga dapat menggunakan --define, tetapi cara ini menawarkan dukungan yang lebih lemah dan tidak direkomendasikan. Lihat di sini untuk diskusi lebih lanjut.
  • Hindari mengulangi definisi config_setting yang identik dalam paket yang berbeda. Sebagai gantinya, referensikan config_setting umum yang ditentukan dalam paket kanonis.
  • values, define_values, dan constraint_values dapat digunakan dalam kombinasi apa pun dalam config_setting yang sama, tetapi setidaknya satu harus ditetapkan untuk config_setting tertentu.

Argumen

Atribut
name

Name; required

Nama unik untuk target ini.

constraint_values

List of labels; optional; nonconfigurable

Kumpulan minimum constraint_values yang harus ditentukan oleh platform target agar cocok dengan config_setting ini. (Platform eksekusi tidak dipertimbangkan di sini.) Semua nilai batasan tambahan yang dimiliki platform akan diabaikan. Lihat Atribut Build yang Dapat Dikonfigurasi untuk mengetahui detailnya.

Jika dua config_setting keduanya cocok dalam select yang sama, atribut ini tidak dipertimbangkan untuk tujuan menentukan apakah salah satu dari config_setting adalah spesialisasi dari yang lain. Dengan kata lain, satu config_setting tidak boleh lebih cocok dengan platform.

define_values

Dictionary: String -> String; optional; nonconfigurable

Sama seperti values, tetapi khusus untuk flag --define.

--define bersifat khusus karena sintaksisnya (--define KEY=VAL) berarti KEY=VAL adalah nilai dari perspektif flag Bazel.

Artinya:

            config_setting(
                name = "a_and_b",
                values = {
                    "define": "a=1",
                    "define": "b=2",
                })
          

tidak berfungsi karena kunci yang sama (define) muncul dua kali dalam kamus. Atribut ini mengatasi masalah tersebut:

            config_setting(
                name = "a_and_b",
                define_values = {
                    "a": "1",
                    "b": "2",
                })
          

cocok dengan bazel build //foo --define a=1 --define b=2.

--define masih dapat muncul di values dengan sintaksis flag normal, dan dapat digabungkan secara bebas dengan atribut ini selama kunci kamus tetap berbeda.

flag_values

Dictionary: label -> String; optional; nonconfigurable

Sama seperti values, tetapi untuk flag build buatan pengguna.

Ini adalah atribut yang berbeda karena flag yang ditentukan pengguna direferensikan sebagai label, sementara flag bawaan direferensikan sebagai string arbitrer.

values

Dictionary: String -> String; optional; nonconfigurable

Kumpulan nilai konfigurasi yang cocok dengan aturan ini (dinyatakan sebagai tanda build)

Aturan ini mewarisi konfigurasi target yang dikonfigurasi dan merujuknya dalam pernyataan select. Ini dianggap "cocok" dengan pemanggilan Bazel jika, untuk setiap entri dalam kamus, konfigurasinya cocok dengan nilai entri yang diharapkan. Misalnya, values = {"compilation_mode": "opt"} cocok dengan pemanggilan bazel build --compilation_mode=opt ... dan bazel build -c opt ... pada aturan yang dikonfigurasi target.

Demi kenyamanan, nilai konfigurasi ditentukan sebagai flag build (tanpa "--" sebelumnya). Namun, perlu diingat bahwa keduanya tidak sama. Hal ini karena target dapat dibuat dalam beberapa konfigurasi dalam build yang sama. Misalnya, "cpu" konfigurasi host cocok dengan nilai --host_cpu, bukan --cpu. Jadi, instance yang berbeda dari config_setting yang sama mungkin cocok dengan pemanggilan yang sama secara berbeda bergantung pada konfigurasi aturan yang menggunakannya.

Jika flag tidak ditetapkan secara eksplisit pada command line, nilai defaultnya akan digunakan. Jika kunci muncul beberapa kali dalam kamus, hanya instance terakhir yang digunakan. Jika kunci mereferensikan flag yang dapat ditetapkan beberapa kali pada command line (misalnya bazel build --copt=foo --copt=bar --copt=baz ...), kecocokan akan terjadi jika ada salah satu dari setelan tersebut yang cocok.

grup file

Lihat sumber aturan
filegroup(name, srcs, data, compatible_with, deprecation, distribs, features, licenses, output_group, restricted_to, tags, target_compatible_with, testonly, visibility)

Gunakan filegroup untuk memberi nama yang mudah untuk koleksi target. Kemudian, aturan tersebut dapat dirujuk dari aturan lain.

Sebaiknya gunakan filegroup, bukan mereferensikan direktori secara langsung. Yang kedua tidak lagi bagus karena sistem build tidak memiliki pengetahuan penuh tentang semua file di bawah direktori, sehingga sistem tidak dapat mem-build ulang saat file ini berubah. Jika dikombinasikan dengan glob, filegroup dapat memastikan bahwa semua file secara eksplisit diketahui oleh sistem build.

Contoh

Untuk membuat filegroup yang terdiri dari dua file sumber, lakukan

filegroup(
    name = "mygroup",
    srcs = [
        "a_file.txt",
        "some/subdirectory/another_file.txt",
    ],
)

Atau, gunakan glob untuk mengubah direktori data pengujian:

filegroup(
    name = "exported_testdata",
    srcs = glob([
        "testdata/*.dat",
        "testdata/logs/**/*.log",
    ]),
)

Untuk memanfaatkan definisi ini, referensikan filegroup dengan label dari aturan mana pun:

cc_library(
    name = "my_library",
    srcs = ["foo.cc"],
    data = [
        "//my_package:exported_testdata",
        "//my_package:mygroup",
    ],
)

Argumen

Atribut
name

Name; required

Nama unik untuk target ini.

srcs

List of labels; optional

Daftar target adalah anggota grup file.

Sangatlah umum untuk menggunakan hasil ekspresi glob untuk nilai atribut srcs.

data

List of labels; optional

Daftar file yang diperlukan oleh aturan ini saat runtime.

Target yang disebutkan dalam atribut data akan ditambahkan ke runfiles aturan filegroup ini. Saat filegroup direferensikan dalam atribut data aturan lain, runfiles-nya akan ditambahkan ke runfiles dari aturan yang bergantung. Lihat bagian dependensi data dan dokumentasi umum data untuk informasi selengkapnya tentang cara bergantung dan menggunakan file data.

output_group

String; optional

Grup output tempat mengumpulkan artefak dari sumber. Jika atribut ini ditentukan, artefak dari grup output dependensi yang ditentukan akan diekspor, bukan grup output default.

"Grup output" adalah kategori artefak output dari target, yang ditentukan dalam penerapan aturan tersebut.

kueri

Lihat sumber aturan
genquery(name, deps, data, compatible_with, deprecation, distribs, exec_compatible_with, exec_properties, expression, features, licenses, opts, restricted_to, scope, strict, tags, target_compatible_with, testonly, visibility)

genquery() menjalankan kueri yang ditentukan dalam bahasa kueri Blaze dan membuang hasilnya ke dalam file.

Agar build tetap konsisten, kueri hanya diizinkan untuk mengunjungi penutupan transitif dari target yang ditentukan dalam atribut scope. Kueri yang melanggar aturan ini akan gagal selama eksekusi jika strict tidak ditentukan atau bernilai benar (jika strict bernilai salah, target di luar cakupan akan dilewati dengan peringatan). Cara termudah untuk memastikan hal ini tidak terjadi adalah dengan menyebutkan label yang sama dalam cakupan seperti dalam ekspresi kueri.

Satu-satunya perbedaan antara kueri yang diizinkan di sini dan pada command line adalah bahwa kueri yang berisi spesifikasi target karakter pengganti (misalnya //pkg:* atau //pkg:all) tidak diizinkan di sini. Alasannya adalah dua kali lipat: pertama, karena genquery harus menentukan cakupan untuk mencegah target di luar penutupan transitif kueri untuk memengaruhi outputnya; dan, kedua, karena file BUILD tidak mendukung dependensi karakter pengganti (misalnya, deps=["//a/..."] tidak diizinkan).

Output genquery diurutkan menggunakan --order_output=full untuk menerapkan output deterministik.

Nama file output adalah nama aturan.

Contoh

Contoh ini menulis daftar label dalam penutupan transitif target yang ditentukan untuk file.

genquery(
    name = "kiwi-deps",
    expression = "deps(//kiwi:kiwi_lib)",
    scope = ["//kiwi:kiwi_lib"],
)

Argumen

Atribut
name

Name; required

Nama unik untuk target ini.

expression

String; required

Kueri yang akan dieksekusi. Berbeda dengan command line dan tempat lain di file BUILD, label di sini diselesaikan secara relatif terhadap direktori utama ruang kerja. Misalnya, label :b dalam atribut ini di file a/BUILD akan merujuk ke target //:b.
opts

List of strings; optional

Opsi yang diteruskan ke mesin kueri. Ini sama dengan opsi command line yang dapat diteruskan ke bazel query. Beberapa opsi kueri tidak diizinkan di sini: --keep_going, --query_file, --universe_scope, --order_results, dan --order_output. Opsi yang tidak ditentukan di sini akan memiliki nilai default seperti pada command line bazel query.
scope

null; required

Cakupan kueri. Kueri tidak diizinkan menyentuh target di luar penutupan transitif target ini.
strict

Boolean; optional; default is True

Jika true (benar), target yang kuerinya menghindari penutupan transitif cakupannya akan gagal dibuat. Jika salah, Bazel akan mencetak peringatan dan melewati jalur kueri mana pun yang menyebabkannya berada di luar cakupan, sembari menyelesaikan sisa kueri.

Genrule

Lihat sumber aturan
genrule(name, srcs, outs, cmd, cmd_bash, cmd_bat, cmd_ps, compatible_with, deprecation, distribs, exec_compatible_with, exec_properties, exec_tools, executable, features, licenses, local, message, output_licenses, output_to_bindir, restricted_to, tags, target_compatible_with, testonly, toolchains, tools, visibility)

genrule menghasilkan satu atau beberapa file menggunakan perintah Bash yang ditentukan pengguna.

Genrules adalah aturan build umum yang dapat Anda gunakan jika tidak ada aturan khusus untuk tugas tersebut. Misalnya, Anda dapat menjalankan one-liner Bash. Namun, jika Anda perlu mengompilasi file C++, tetap gunakan aturan cc_* yang ada, karena semua tugas berat telah dilakukan untuk Anda.

Perlu diperhatikan bahwa genrule memerlukan shell untuk menafsirkan argumen perintah. Anda juga dapat mereferensikan program arbitrer yang tersedia di PATH dengan mudah, tetapi tindakan ini akan membuat perintah non-hermetic dan mungkin tidak dapat direproduksi. Jika Anda hanya perlu menjalankan satu alat, sebaiknya gunakan run_binary.

Jangan gunakan genrule untuk menjalankan pengujian. Ada dispensasi khusus untuk pengujian dan hasil pengujian, termasuk kebijakan cache dan variabel lingkungan. Pengujian umumnya harus dijalankan setelah build selesai dan pada arsitektur target, sedangkan genrules dieksekusi selama build dan arsitektur host (keduanya mungkin berbeda). Jika Anda memerlukan aturan pengujian tujuan umum, gunakan sh_test.

Pertimbangan Lintas Kompilasi

Lihat panduan pengguna untuk mengetahui info selengkapnya tentang kompilasi silang.

Meskipun aturan berjalan selama proses build, output sering kali digunakan setelah proses build, untuk deployment atau pengujian. Pertimbangkan contoh untuk mengompilasi kode C untuk pengontrol mikro: compiler menerima file sumber C dan menghasilkan kode yang berjalan pada pengontrol mikro. Kode yang dihasilkan jelas tidak dapat dijalankan di CPU yang digunakan untuk membuatnya, tetapi compiler C (jika dikompilasi dari sumber) harus melakukannya.

Sistem build menggunakan konfigurasi host untuk menjelaskan mesin tempat build berjalan dan konfigurasi target untuk mendeskripsikan mesin tempat output build seharusnya berjalan. Bagian ini menyediakan opsi untuk mengonfigurasi setiap file dan memisahkan file yang sesuai ke dalam direktori terpisah untuk menghindari konflik.

Untuk genrules, sistem build memastikan bahwa dependensi dibuat dengan benar: srcs dibuat (jika diperlukan) untuk konfigurasi target, tools dibuat untuk konfigurasi host, dan output dianggap untuk konfigurasi target. Atribut ini juga menyediakan variabel "Make" yang dapat diteruskan oleh perintah genrule ke alat yang sesuai.

Hal ini memang sengaja dibuat agar genrule tidak menetapkan atribut deps: aturan bawaan lainnya menggunakan informasi meta yang bergantung pada bahasa yang diteruskan antar-aturan untuk secara otomatis menentukan cara menangani aturan dependen, tetapi tingkat otomatisasi ini tidak mungkin dilakukan untuk genrules. Genrules berfungsi sepenuhnya pada tingkat file dan runfiles.

Kasus Khusus

Kompilasi host-host: dalam beberapa kasus, sistem build perlu menjalankan genrules sehingga output juga dapat dijalankan selama build. Jika misalnya, Gengen membuat beberapa compiler kustom yang kemudian digunakan oleh genrule lain, yang pertama harus menghasilkan outputnya untuk konfigurasi host, karena di situlah compiler akan berjalan di genrule lainnya. Dalam hal ini, sistem build melakukan hal yang benar secara otomatis: sistem mem-build srcs dan outs genrule pertama untuk konfigurasi host, bukan konfigurasi target. Lihat panduan pengguna untuk info selengkapnya.

JDK & amp; C++ Tooling: untuk menggunakan alat dari JDK atau suite compiler C++, sistem build akan menyediakan kumpulan variabel yang akan digunakan. Lihat Variabel "Make" untuk detailnya.

Lingkungan Genrule

Perintah genrule dieksekusi oleh shell Bash yang dikonfigurasi agar gagal saat perintah atau pipeline gagal, menggunakan set -e -o pipefail.

Alat build mengeksekusi perintah Bash dalam lingkungan proses yang bersih yang hanya menentukan variabel inti seperti PATH, PWD, TMPDIR, dan beberapa lainnya. Untuk memastikan bahwa build dapat direproduksi, sebagian besar variabel yang ditentukan di lingkungan shell pengguna tidak diteruskan ke perintah genrule. Namun, Bazel (tetapi bukan Blaze) meneruskan nilai variabel lingkungan PATH pengguna. Setiap perubahan pada nilai PATH akan menyebabkan Bazel menjalankan kembali perintah pada build berikutnya.

Perintah genrule tidak boleh mengakses jaringan kecuali untuk menghubungkan proses yang merupakan turunan dari perintah itu sendiri, meskipun saat ini tidak diterapkan.

Sistem build otomatis menghapus file output yang ada, tetapi membuat direktori induk yang diperlukan sebelum menjalankan genrule. Tindakan ini juga akan menghapus file output jika terjadi kegagalan.

Saran Umum

  • Pastikan alat yang dijalankan oleh genrule bersifat deterministik dan hermetik. Pengujian tidak boleh menulis stempel waktu ke outputnya, dan harus menggunakan pengurutan yang stabil untuk kumpulan dan peta, serta hanya menulis jalur file relatif ke output, bukan jalur absolut. Tidak mengikuti aturan ini akan menyebabkan perilaku build yang tidak terduga (Bazel tidak membuat kembali genrule yang Anda kira akan melakukannya) dan menurunkan performa cache.
  • Gunakan $(location) secara ekstensif, untuk output, alat, dan sumber. Karena pemisahan file output untuk konfigurasi yang berbeda, genrules tidak dapat mengandalkan jalur hard code dan/atau absolut.
  • Menulis makro Starlark umum jika genaturan yang sama atau sangat mirip digunakan di beberapa tempat. Jika genrule bersifat kompleks, pertimbangkan untuk menerapkannya dalam skrip atau sebagai aturan Starlark. Hal ini meningkatkan keterbacaan serta kemudahan untuk diuji.
  • Pastikan bahwa kode keluar menunjukkan dengan benar keberhasilan atau kegagalan genrule.
  • Jangan menulis pesan informasi untuk stdout atau stderr. Meskipun berguna untuk proses debug, hal ini dapat dengan mudah menjadi derau; genrule yang berhasil akan diam. Di sisi lain, genrule yang gagal akan menghasilkan pesan error yang baik.
  • $$ evaluates to a $, a literal dollar-sign, so in order to invoke a shell command containing dollar-signs such as ls $(dirname $x), one must escape it thus: ls $$(dirname $$x).
  • Hindari membuat symlink dan direktori. Bazel tidak akan menyalin struktur direktori/symlink yang dibuat oleh genrules dan pemeriksaan dependensi direktorinya tidak akan baik.
  • Saat mereferensikan genrule dalam aturan lain, Anda dapat menggunakan label genrule atau label file output individual. Terkadang satu pendekatan lebih mudah dibaca, terkadang yang lain: mereferensikan output berdasarkan nama dalam srcs aturan yang pemakaiannya akan menghindari pengambilan output lain dari genrule secara tidak sengaja, tetapi bisa merepotkan jika genrule menghasilkan banyak output.

Contoh

Contoh ini menghasilkan foo.h. Tidak ada sumber, karena perintah tersebut tidak menggunakan input apa pun. "Biner" yang dijalankan oleh perintah adalah skrip perl dalam paket yang sama dengan genrule.

genrule(
    name = "foo",
    srcs = [],
    outs = ["foo.h"],
    cmd = "./$(location create_foo.pl) > \"$@\"",
    tools = ["create_foo.pl"],
)

Contoh berikut menunjukkan cara menggunakan filegroup dan output genrule lainnya. Perlu diperhatikan bahwa penggunaan $(SRCS), bukan perintah $(location) eksplisit, juga akan berfungsi; contoh ini menggunakan perintah terakhir demi demonstrasi.

genrule(
    name = "concat_all_files",
    srcs = [
        "//some:files",  # a filegroup with multiple files in it ==> $(locations)
        "//other:gen",   # a genrule with a single output ==> $(location)
    ],
    outs = ["concatenated.txt"],
    cmd = "cat $(locations //some:files) $(location //other:gen) > $@",
)

Argumen

Atribut
name

Name; required

Nama unik untuk target ini.


Anda dapat merujuk aturan ini berdasarkan nama di bagian srcs atau deps pada aturan BUILD lainnya. Jika aturan menghasilkan file sumber, Anda harus menggunakan atribut srcs.
srcs

List of labels; optional

Daftar input untuk aturan ini, seperti file sumber yang akan diproses.

Atribut ini tidak cocok untuk mencantumkan alat yang dijalankan oleh cmd; gunakan atribut tools untuk atribut tersebut.

Sistem build memastikan bahwa prasyarat ini di-build sebelum menjalankan perintah genrule; persyaratan ini di-build menggunakan konfigurasi yang sama dengan permintaan build asli. Nama file prasyarat ini tersedia untuk perintah sebagai daftar yang dipisahkan spasi di $(SRCS); atau, jalur dari setiap target srcs //x:y dapat diperoleh menggunakan $(location //x:y), atau menggunakan $< asalkan itu adalah satu-satunya entri di srcs.

outs

List of filenames; required; nonconfigurable

Daftar file yang dibuat oleh aturan ini.

File output tidak boleh melintasi batas paket. Nama file output diinterpretasikan sebagai relatif terhadap paket.

Jika tanda executable ditetapkan, outs harus berisi tepat satu label.

Perintah genrule diharapkan membuat setiap file output di lokasi yang telah ditetapkan. Lokasi tersedia dalam cmd menggunakan variabel "Make" khusus aturan ($@, $(OUTS), $(@D), atau $(RULEDIR)) atau menggunakan substitusi $(location).

cmd

String; optional

Perintah yang akan dijalankan. Tunduk pada substitusi $(location) dan variabel "Buat".
  1. Penggantian $(location) pertama diterapkan, menggantikan semua kemunculan $(location label) dan $(locations label) (dan konstruksi serupa menggunakan variabel terkait execpath, execpaths, rootpath, dan rootpaths).
  2. Selanjutnya, variabel "Buat" akan diperluas. Perhatikan bahwa variabel yang telah ditetapkan $(JAVA), $(JAVAC), dan $(JAVABASE) diperluas di bagian konfigurasi host, sehingga pemanggilan Java yang berjalan sebagai bagian dari langkah build dapat memuat library bersama dan dependensi lainnya dengan benar.
  3. Terakhir, perintah yang dihasilkan dijalankan menggunakan shell Bash. Jika kode keluarnya bukan nol, perintah dianggap gagal.
Ini adalah penggantian cmd_bash, cmd_ps, dan cmd_bat, jika tidak ada yang berlaku.

Jika panjang command line melebihi batas platform (64K pada Linux/macOS, 8K pada Windows), genrule akan menulis perintah ke skrip dan mengeksekusi skrip tersebut untuk mengatasinya. Ini berlaku untuk semua atribut cmd (cmd, cmd_bash, cmd_ps, cmd_bat).

cmd_bash

String; optional

Perintah Bash untuk dijalankan.

Atribut ini memiliki prioritas yang lebih tinggi daripada cmd. Perintah diperluas dan berjalan dengan cara yang sama persis seperti atribut cmd.

cmd_bat

String; optional

Perintah Batch untuk dijalankan di Windows.

Atribut ini memiliki prioritas yang lebih tinggi daripada cmd dan cmd_bash. Perintah berjalan dengan cara yang sama seperti atribut cmd, dengan perbedaan berikut:

  • Atribut ini hanya berlaku di Windows.
  • Perintah berjalan dengan cmd.exe /c dengan argumen default berikut:
    • /S - menghapus tanda kutip pertama dan terakhir serta mengeksekusi yang lainnya sebagaimana adanya.
    • /E:ON - mengaktifkan set perintah yang diperluas.
    • /V:ON - aktifkan perluasan variabel yang tertunda
    • /D - abaikan entri registry AutoRun.
  • Setelah substitusi $(location) dan variabel "Make", jalur akan diperluas ke jalur gaya Windows (dengan garis miring terbalik).
cmd_ps

String; optional

Perintah Powershell yang akan dijalankan di Windows.

Atribut ini memiliki prioritas yang lebih tinggi daripada cmd, cmd_bash, dan cmd_bat. Perintah berjalan dengan cara yang sama seperti atribut cmd, dengan perbedaan berikut:

  • Atribut ini hanya berlaku di Windows.
  • Perintah berjalan dengan powershell.exe /c.

Agar Powershell lebih mudah digunakan dan tidak terlalu rentan mengalami error, kami menjalankan perintah berikut untuk menyiapkan lingkungan sebelum menjalankan perintah Powershell di genrule.

  • Set-ExecutionPolicy -Scope CurrentUser RemoteSigned - mengizinkan menjalankan skrip yang tidak ditandatangani.
  • $errorActionPreference='Stop' - Jika ada beberapa perintah yang dipisahkan oleh ;, tindakan tersebut akan segera keluar jika PowerCmd CmdLet gagal, tetapi ini TIDAK berfungsi untuk perintah eksternal.
  • $PSDefaultParameterValues['*:Encoding'] = 'utf8' - ubah encoding default dari utf-16 menjadi utf-8.
exec_tools

List of labels; optional

Daftar dependensi tool untuk aturan ini. Perilaku ini persis seperti atribut tools, kecuali bahwa dependensi ini akan dikonfigurasi untuk platform eksekusi aturan, bukan konfigurasi host. Ini berarti dependensi di exec_tools tidak tunduk pada batasan yang sama seperti dependensi di tools. Secara khusus, host ini tidak perlu menggunakan konfigurasi host untuk dependensi transitifnya sendiri. Lihat tools untuk detail selengkapnya.

Tim Blaze memigrasikan semua penggunaan tools untuk menggunakan semantik exec_tools. Pengguna disarankan untuk memilih exec_tools daripada tools jika tidak ada masalah. Setelah migrasi fungsional selesai, kami dapat mengganti nama exec_tools menjadi tools. Anda akan menerima peringatan penghentian dan petunjuk migrasi sebelum hal ini terjadi.

executable

Boolean; optional; nonconfigurable; default is False

Mendeklarasikan output menjadi dapat dieksekusi.

Jika tanda ini ditetapkan ke Benar (True), output akan berupa file yang dapat dieksekusi dan dapat dijalankan menggunakan perintah run. Dalam hal ini, genrule harus menghasilkan tepat satu output. Jika atribut ini ditetapkan, run akan mencoba menjalankan file apa pun kontennya.

Mendeklarasikan dependensi data untuk file yang dapat dieksekusi yang dihasilkan tidak didukung.

local

Boolean; optional; default is False

Jika disetel ke Benar (True), opsi ini akan memaksa genrule ini berjalan menggunakan strategi "lokal", yang berarti tidak ada eksekusi jarak jauh, tidak ada sandbox, tidak ada pekerja persisten.

Hal ini setara dengan memberikan 'lokal' sebagai tag (tags=["local"]).

message

String; optional

Pesan progres.

Pesan progres yang akan dicetak saat langkah build ini dieksekusi. Secara default, pesannya adalah "Menghasilkan output" (atau sesuatu yang kurang lebih sama), tetapi Anda dapat memberikan output yang lebih spesifik. Gunakan atribut ini, bukan echo, atau pernyataan cetak lainnya dalam perintah cmd Anda, karena hal ini memungkinkan alat build mengontrol apakah pesan progres tersebut dicetak atau tidak.

output_licenses

Licence type; optional

Lihat common attributes
output_to_bindir

Boolean; optional; nonconfigurable; default is False

Jika disetel ke Benar (True), opsi ini akan menyebabkan file output ditulis ke direktori bin, bukan direktori genfiles.

tools

List of labels; optional

Daftar dependensi tool untuk aturan ini. Lihat definisi dependensi untuk informasi selengkapnya.

Sistem build memastikan prasyarat ini di-build sebelum menjalankan perintah genrule; di-build menggunakan konfigurasi host , karena alat ini dieksekusi sebagai bagian dari build. Jalur //x:y target tools individual dapat diperoleh menggunakan $(location //x:y).

Setiap *_binary atau alat yang akan dieksekusi oleh cmd harus muncul dalam daftar ini, bukan di srcs, untuk memastikan keduanya dibuat dalam konfigurasi yang benar.

suite_pengujian

Lihat sumber aturan
test_suite(name, compatible_with, deprecation, distribs, features, licenses, restricted_to, tags, target_compatible_with, testonly, tests, visibility)

test_suite menentukan serangkaian pengujian yang dianggap "berguna" bagi manusia. Hal ini memungkinkan project untuk menentukan set pengujian, seperti "pengujian yang harus Anda jalankan sebelum check in", "uji stres project kami", atau "semua pengujian kecil". Perintah blaze test mematuhi jenis organisasi ini: Untuk pemanggilan seperti blaze test //some/test:suite, Blaze akan terlebih dahulu menggabungkan semua target pengujian yang disertakan secara transitif oleh target //some/test:suite (kami menyebutnya "ekspansi test_suite"), lalu Blaze membuat dan menguji target tersebut.

Contoh

Suite pengujian untuk menjalankan semua pengujian kecil dalam paket saat ini.

test_suite(
    name = "small_tests",
    tags = ["small"],
)

Rangkaian pengujian yang menjalankan serangkaian pengujian yang ditentukan:

test_suite(
    name = "smoke_tests",
    tests = [
        "system_unittest",
        "public_api_unittest",
    ],
)

Suite pengujian untuk menjalankan semua pengujian dalam paket saat ini yang tidak stabil.

test_suite(
    name = "non_flaky_test",
    tags = ["-flaky"],
)

Argumen

Atribut
name

Name; required

Nama unik untuk target ini.

tags

List of strings; optional; nonconfigurable

Daftar tag teks seperti "small" atau "database" atau "-flaky". Tag dapat berupa string apa pun yang valid.

Tag yang diawali dengan karakter "-" dianggap sebagai tag negatif. Karakter "-" sebelumnya tidak dianggap sebagai bagian dari tag, sehingga tag suite "-small" cocok dengan ukuran "kecil" pengujian. Semua tag lainnya dianggap sebagai tag positif.

Secara opsional, untuk membuat tag positif lebih eksplisit, tag juga dapat dimulai dengan karakter "+", yang tidak akan dievaluasi sebagai bagian dari teks tag. Kode ini hanya membuat perbedaan positif dan negatif lebih mudah dibaca.

Hanya aturan pengujian yang cocok dengan semua tag positif dan tidak ada tag negatif yang akan disertakan dalam rangkaian pengujian. Perhatikan bahwa ini tidak berarti bahwa pemeriksaan error untuk dependensi pada pengujian yang difilter akan dilewati; dependensi pada pengujian yang dilewati masih harus bersifat legal (misalnya, tidak diblokir oleh batasan visibilitas).

Kata kunci tag manual diperlakukan secara berbeda dari yang di atas oleh "perluasan_test_suite" yang dijalankan oleh perintah blaze test pada pemanggilan yang melibatkan pola target karakter pengganti. Di sana, target test_suite yang diberi tag "manual" difilter (sehingga tidak diperluas). Perilaku ini konsisten dengan cara blaze build dan blaze test menangani pola target karakter pengganti secara umum. Perlu diperhatikan bahwa hal ini secara eksplisit berbeda dari perilaku blaze query 'tests(E)', karena suite selalu diperluas oleh fungsi kueri tests, terlepas dari tag manual.

Perhatikan bahwa size pengujian dianggap sebagai tag untuk tujuan pemfilteran.

Jika memerlukan test_suite yang berisi pengujian dengan tag yang saling eksklusif (misalnya, semua pengujian kecil dan sedang), Anda harus membuat tiga aturan test_suite: satu untuk semua pengujian kecil, satu untuk semua pengujian sedang, dan satu lagi menyertakan dua pengujian sebelumnya.

tests

List of labels; optional; nonconfigurable

Daftar rangkaian pengujian dan target pengujian dalam bahasa apa pun.

Semua *_test dapat diterima di sini, apa pun bahasanya. Namun, tidak ada target *_binary yang diterima, meskipun jika pengujian tersebut benar-benar dijalankan. Pemfilteran berdasarkan tags yang ditentukan hanya dilakukan untuk pengujian yang dicantumkan langsung dalam atribut ini. Jika atribut ini berisi test_suite, pengujian di dalamnya tidak akan difilter oleh test_suite ini (dianggap sudah difilter).

Jika atribut tests tidak ditentukan atau kosong, aturan secara default akan menyertakan semua aturan pengujian dalam file BUILD saat ini yang tidak diberi tag sebagai manual. Aturan ini tetap tunduk pada pemfilteran tag.