การใช้ชุดพัฒนาซอฟต์แวร์แบบเนทีฟของ Android กับ Bazel

หากคุณเพิ่งเริ่มใช้ Bazel โปรดเริ่มต้นด้วยบทแนะนำการสร้าง Android ด้วย Bazel

ภาพรวม

Bazel สามารถทำงานในการกำหนดค่าการสร้างที่แตกต่างกันได้มากมาย รวมถึงการกำหนดค่าหลายรายการที่ใช้ชุดเครื่องมือ Android Native Development Kit (NDK) ซึ่งหมายความว่ากฎปกติ cc_libraryและcc_binaryสามารถคอมไพล์สำหรับ Android ได้โดยตรงภายใน Bazel Bazel ทำได้โดยใช้android_ndk_repositoryกฎที่เก็บandroid_ndk_repositoryและส่วนขยาย bzlmod ที่เกี่ยวข้อง

สำหรับการคอมไพล์ Android ทั่วไป ให้ใช้ rules_android บทแนะนำนี้แสดงวิธีผสานรวมทรัพยากร Dependency ของไลบรารี C++ เข้ากับ แอป Android และใช้ rules_android_ndk สำหรับการค้นหาและการลงทะเบียนชุดเครื่องมือ NDK

ข้อกำหนดเบื้องต้น

โปรดตรวจสอบว่าคุณได้ติดตั้ง Android SDK และ NDK แล้ว

การตั้งค่า NDK และ SDK

การตั้งค่าที่เก็บภายนอกจะแตกต่างกันไปโดยขึ้นอยู่กับว่าคุณใช้ WORKSPACE หรือ bzlmod (MODULE.bazel) Bzlmod เป็นโซลูชันที่แนะนำสำหรับ Bazel 7 ขึ้นไป โปรดทราบว่า Stanza การตั้งค่า MODULE.bazel และ WORKSPACE ไม่ขึ้นต่อกัน หากใช้โซลูชันการจัดการการขึ้นต่อกันอย่างใดอย่างหนึ่ง คุณไม่จำเป็นต้องเพิ่ม โค้ดมาตรฐานสำหรับโซลูชันอื่นๆ

การตั้งค่า MODULE.bazel ของ Bzlmod

เพิ่มข้อมูลโค้ดต่อไปนี้ลงใน MODULE.bazel

# NDK
bazel_dep(name = "rules_android_ndk", version = "0.1.3")
android_ndk_repository_extension = use_extension("@rules_android_ndk//:extension.bzl", "android_ndk_repository_extension")
use_repo(android_ndk_repository_extension, "androidndk")
register_toolchains("@androidndk//:all")

# SDK
bazel_dep(name = "rules_android", version = "0.6.6")
register_toolchains(
    "@rules_android//toolchains/android:android_default_toolchain",
    "@rules_android//toolchains/android_sdk:android_sdk_tools",
)
android_sdk_repository_extension = use_extension("@rules_android//rules/android_sdk_repository:rule.bzl", "android_sdk_repository_extension")
use_repo(android_sdk_repository_extension, "androidsdk")
register_toolchains("@androidsdk//:sdk-toolchain", "@androidsdk//:all")

การตั้งค่า WORKSPACE เดิม

เพิ่มข้อมูลโค้ดต่อไปนี้ลงใน WORKSPACE

load("@rules_android//rules:rules.bzl", "android_sdk_repository")
android_sdk_repository(
    name = "androidsdk", # Required. Name *must* be "androidsdk".
    path = "/path/to/sdk", # Optional. Can be omitted if `ANDROID_HOME` environment variable is set.
)

load("@rules_android_ndk//:rules.bzl", "android_ndk_repository")
android_ndk_repository(
    name = "androidndk", # Required. Name *must* be "androidndk".
    path = "/path/to/ndk", # Optional. Can be omitted if `ANDROID_NDK_HOME` environment variable is set.
)

หมายเหตุเกี่ยวกับความเข้ากันได้สำหรับ WORKSPACE

• ทั้งกฎ rules_android และ rules_android_ndk ต้องมีข้อความมาตรฐานเพิ่มเติมซึ่งไม่ได้แสดงในตัวอย่าง WORKSPACE ด้านบน ดูส่วนการเริ่มต้นที่อัปเดตแล้วและสมบูรณ์ได้ในไฟล์ WORKSPACE ของแอปตัวอย่างพื้นฐานของ rules_android_ndk

ดูข้อมูลเพิ่มเติมเกี่ยวกับandroid_ndk_repositoryกฎได้ที่สตริงเอกสาร

การเริ่มใช้งานอย่างง่าย

หากต้องการสร้าง C++ สำหรับ Android เพียงเพิ่มcc_libraryการอ้างอิงไปยังกฎ android_binary หรือ android_library

เช่น หากมีไฟล์ BUILD ต่อไปนี้สำหรับแอป Android

# In <project>/app/src/main/BUILD.bazel
load("@rules_cc//cc:cc_library.bzl", "cc_library")
load("@rules_android//rules:rules.bzl", "android_binary", "android_library")

cc_library(
    name = "jni_lib",
    srcs = ["cpp/native-lib.cpp"],
)

android_library(
    name = "lib",
    srcs = ["java/com/example/android/bazel/MainActivity.java"],
    resource_files = glob(["res/**/*"]),
    custom_package = "com.example.android.bazel",
    manifest = "LibraryManifest.xml",
    deps = [":jni_lib"],
)

android_binary(
    name = "app",
    deps = [":lib"],
    manifest = "AndroidManifest.xml",
)

ไฟล์ BUILD นี้จะส่งผลให้เกิดกราฟเป้าหมายต่อไปนี้

รูปที่ 1 สร้างกราฟของโปรเจ็กต์ Android ด้วยทรัพยากร Dependency ของ cc_library

หากต้องการสร้างแอป ให้เรียกใช้คำสั่งต่อไปนี้

bazel build //app/src/main:app --android_platforms=<your platform>

โปรดทราบว่าหากคุณไม่ระบุ --android_platforms บิลด์จะล้มเหลวพร้อมข้อผิดพลาดเกี่ยวกับส่วนหัว JNI ที่ขาดหายไป

คำสั่ง bazel build จะคอมไพล์ไฟล์ Java, ไฟล์ทรัพยากร Android และกฎ cc_library รวมถึงแพ็กเกจทุกอย่างเป็น APK

$ zipinfo -1 bazel-bin/app/src/main/app.apk
nativedeps
lib/armeabi-v7a/libapp.so
classes.dex
AndroidManifest.xml
...
res/...
...
META-INF/CERT.SF
META-INF/CERT.RSA
META-INF/MANIFEST.MF

Bazel จะคอมไพล์ cc_libraries ทั้งหมดเป็นไฟล์ออบเจ็กต์ที่แชร์เดียว (.so) ซึ่งกำหนดเป้าหมายเป็นสถาปัตยกรรมที่ระบุโดย --android_platforms ดูรายละเอียดเพิ่มเติมได้ที่ส่วนการกำหนดค่า ABI เป้าหมาย

ตัวอย่างการตั้งค่า

ตัวอย่างนี้อยู่ในที่เก็บตัวอย่าง Bazel

ในไฟล์ BUILD.bazel มีการกำหนดเป้าหมาย 3 รายการด้วยกฎ android_binary android_library และ cc_library

android_binary เป้าหมายระดับบนสุดจะสร้าง APK

cc_library เป้าหมายมีไฟล์ต้นฉบับ C++ ไฟล์เดียวที่มีฟังก์ชัน JNI การใช้งาน:

#include <jni.h>
#include <string>

extern "C"
JNIEXPORT jstring

JNICALL
Java_com_example_android_bazel_MainActivity_stringFromJNI(
        JNIEnv *env,
        jobject /* this */) {
    std::string hello = "Hello from C++";
    return env->NewStringUTF(hello.c_str());
}

android_library เป้าหมายระบุแหล่งที่มาของ Java, ไฟล์ทรัพยากร และ การขึ้นต่อกันในcc_library เป้าหมาย ในตัวอย่างนี้ MainActivity.java จะโหลด ไฟล์ออบเจ็กต์ที่แชร์ libapp.so และกำหนดลายเซ็นเมธอดสำหรับฟังก์ชัน JNI

public class MainActivity extends AppCompatActivity {

    static {
        System.loadLibrary("app");
    }

    @Override
    protected void onCreate(Bundle savedInstanceState) {
       // ...
    }

    public native String stringFromJNI();

}

การกำหนดค่า ABI เป้าหมาย

หากต้องการกำหนดค่า ABI เป้าหมาย ให้ใช้แฟล็ก --android_platforms ดังนี้

bazel build //:app --android_platforms=comma-separated list of platforms

ค่าที่ส่งไปยัง --android_platforms จะเป็นป้ายกำกับของเป้าหมาย platform โดยใช้ค่าข้อจำกัดมาตรฐานเพื่ออธิบายอุปกรณ์ของคุณ เช่นเดียวกับแฟล็ก --platforms

ตัวอย่างเช่น สำหรับอุปกรณ์ Android ที่มีโปรเซสเซอร์ ARM 64 บิต คุณจะต้องกำหนด แพลตฟอร์มดังนี้

platform(
    name = "android_arm64",
    constraint_values = [
        "@platforms//os:android",
        "@platforms//cpu:arm64",
    ],
)

Android ทุกรุ่นplatformควรใช้ข้อจํากัดของ @platforms//os:android OS หากต้องการย้ายข้อมูลข้อจำกัดของ CPU ให้ดูแผนภูมินี้

และแน่นอนว่าสำหรับ APK แบบหลายสถาปัตยกรรม คุณจะส่งป้ายกำกับหลายป้าย เช่น --android_platforms=//:arm64,//:x86_64 (สมมติว่าคุณกำหนดป้ายกำกับเหล่านั้นในไฟล์ BUILD.bazel ระดับบนสุด)

Bazel ไม่สามารถเลือกแพลตฟอร์ม Android เริ่มต้นได้ จึงต้องกำหนดและ ระบุด้วย --android_platforms

ABI ต่อไปนี้พร้อมใช้งาน ทั้งนี้ขึ้นอยู่กับการแก้ไข NDK และระดับ API ของ Android

ดูข้อมูลเพิ่มเติมเกี่ยวกับ ABI เหล่านี้ได้ในเอกสาร NDK

เราไม่แนะนำให้ใช้ APK แบบ Fat ที่มีหลาย ABI สำหรับบิลด์ที่เผยแพร่ เนื่องจากจะเพิ่ม ขนาดของ APK แต่ก็อาจมีประโยชน์สำหรับบิลด์ที่ใช้ในการพัฒนาและ QA

การเลือกมาตรฐาน C++

ใช้แฟล็กต่อไปนี้เพื่อสร้างตามมาตรฐาน C++

เช่น

bazel build //:app --cxxopt=-std=c++11

อ่านเพิ่มเติมเกี่ยวกับการส่งแฟล็กคอมไพเลอร์และลิงเกอร์ด้วย --cxxopt, --copt และ --linkopt ในคู่มือผู้ใช้

คุณยังระบุแฟล็กคอมไพเลอร์และลิงเกอร์เป็นแอตทริบิวต์ใน cc_library โดยใช้ copts และ linkopts ได้ด้วย เช่น

cc_library(
    name = "jni_lib",
    srcs = ["cpp/native-lib.cpp"],
    copts = ["-std=c++11"],
    linkopts = ["-ldl"], # link against libdl
)

การสร้าง cc_library สำหรับ Android โดยไม่ใช้ android_binary

หากต้องการสร้าง cc_binary หรือ cc_library แบบสแตนด์อโลนสำหรับ Android โดยไม่ใช้ android_binary ให้ใช้แฟล็ก --platforms

เช่น สมมติว่าคุณได้กำหนดแพลตฟอร์ม Android ใน my/platforms/BUILD

bazel build //my/cc/jni:target \
      --platforms=//my/platforms:x86_64

วิธีนี้จะส่งผลต่อทั้งทรีการสร้าง

คุณใส่แฟล็กเหล่านี้ลงในbazelrcการกำหนดค่า (1 รายการต่อ ABI) ได้ใน project/.bazelrc

common:android_x86 --platforms=//my/platforms:x86

common:android_armeabi-v7a --platforms=//my/platforms:armeabi-v7a

# In general
common:android_<abi> --platforms=//my/platforms:<abi>

จากนั้นหากต้องการสร้าง cc_library สำหรับ x86 เช่น ให้เรียกใช้คำสั่งต่อไปนี้

bazel build //my/cc/jni:target --config=android_x86

โดยทั่วไป ให้ใช้วิธีนี้กับเป้าหมายระดับต่ำ (เช่น cc_library) หรือเมื่อคุณทราบแน่ชัดว่ากำลังสร้างอะไรอยู่ ส่วนเป้าหมายระดับสูงที่คุณคาดว่าจะสร้างเป้าหมายจำนวนมากซึ่งคุณควบคุมไม่ได้ ให้ใช้การเปลี่ยนการกำหนดค่าอัตโนมัติจาก android_binary