Menangani Dependensi Eksternal

Bazel dapat bergantung pada target dari project lain. Dependensi dari project lain ini disebut dependensi eksternal.

File WORKSPACE (atau file WORKSPACE.bazel) di direktori ruang kerja memberi tahu Bazel cara mendapatkan sumber project lain. Project lain ini dapat berisi satu atau beberapa file BUILD dengan targetnya sendiri. File BUILD dalam project utama dapat bergantung pada target eksternal ini menggunakan namanya dari file WORKSPACE.

Misalnya, terdapat dua project di sistem:

/
  home/
    user/
      project1/
        WORKSPACE
        BUILD
        srcs/
          ...
      project2/
        WORKSPACE
        BUILD
        my-libs/

Jika project1 ingin bergantung pada target, :foo, yang ditetapkan dalam /home/user/project2/BUILD, repositori ini dapat menentukan bahwa repositori bernama project2 dapat ditemukan di /home/user/project2. Kemudian, target dalam /home/user/project1/BUILD dapat bergantung pada @project2//:foo.

File WORKSPACE memungkinkan pengguna bergantung pada target dari bagian lain sistem file atau yang didownload dari internet. Kode ini menggunakan sintaksis yang sama dengan file BUILD, tetapi memungkinkan kumpulan aturan berbeda yang disebut aturan repositori (terkadang juga dikenal sebagai aturan ruang kerja) Domain . Bazel memiliki beberapa aturan repositori bawaan dan serangkaian aturan repositori Starlark yang disematkan. Pengguna juga dapat menulis aturan repositori kustom untuk mendapatkan perilaku yang lebih kompleks.

Jenis-jenis dependensi eksternal yang didukung

Beberapa jenis dependensi eksternal dasar dapat digunakan:

Bergantung pada project Bazel lainnya

Jika ingin menggunakan target dari project Bazel kedua, Anda dapat menggunakan local_repository, git_repository atau http_archive untuk menautkannya dari sistem file lokal, merujuk ke repositori git atau mendownloadnya (masing-masing).

Misalnya, Anda sedang mengerjakan project, my-project/, dan ingin bergantung pada target dari project rekan kerja Anda, coworkers-project/. Kedua project menggunakan Bazel, sehingga Anda dapat menambahkan project rekan kerja sebagai dependensi eksternal, lalu menggunakan target yang telah ditentukan oleh rekan kerja dari file BUILD Anda sendiri. Anda akan menambahkan hal berikut ke my_project/WORKSPACE:

local_repository(
    name = "coworkers_project",
    path = "/path/to/coworkers-project",
)

Jika rekan kerja Anda memiliki //foo:bar target, project Anda dapat merujuknya sebagai @coworkers_project//foo:bar. Nama project eksternal harus nama ruang kerja yang valid.

Bergantung pada project non-Bazel

Aturan yang diawali dengan new_, seperti new_local_repository, memungkinkan Anda membuat target dari project yang tidak menggunakan Bazel.

Misalnya, Anda sedang mengerjakan project, my-project/, dan ingin bergantung pada project rekan kerja Anda, coworkers-project/. Project rekan kerja Anda menggunakan make untuk mem-build, tetapi Anda ingin bergantung pada salah satu file .so yang dihasilkannya. Untuk melakukannya, tambahkan kode berikut ke my_project/WORKSPACE:

new_local_repository(
    name = "coworkers_project",
    path = "/path/to/coworkers-project",
    build_file = "coworker.BUILD",
)

build_file menentukan file BUILD untuk ditempatkan di project yang sudah ada, misalnya:

cc_library(
    name = "some-lib",
    srcs = glob(["**"]),
    visibility = ["//visibility:public"],
)

Kemudian, Anda dapat bergantung pada @coworkers_project//:some-lib dari file BUILD project Anda.

Bergantung pada paket eksternal

Artefak dan repositori Maven

Gunakan kumpulan aturan rules_jvm_external untuk mendownload artefak dari repositori Maven dan menyediakannya sebagai dependensi Java.

Mengambil dependensi

Secara default, dependensi eksternal diambil sesuai kebutuhan selama bazel build. Jika Anda ingin mengambil dependensi yang diperlukan untuk kumpulan target tertentu, gunakan bazel fetch. Untuk mengambil semua dependensi eksternal tanpa syarat, gunakan bazel sync. Karena repositori yang diambil disimpan di basis output, pengambilan akan terjadi per ruang kerja.

Dependensi bayangan

Jika memungkinkan, sebaiknya Anda memiliki kebijakan versi tunggal dalam project Anda. Hal ini diperlukan untuk dependensi yang Anda kompilasi dan berakhir di biner akhir. Namun, jika tidak benar, Anda dapat membayangkan dependensi. Pertimbangkan skenario berikut:

proyeksaya/WORKSPACE

workspace(name = "myproject")

local_repository(
    name = "A",
    path = "../A",
)
local_repository(
    name = "B",
    path = "../B",
)

A/WORKSPACE

workspace(name = "A")

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")
http_archive(
    name = "testrunner",
    urls = ["https://github.com/testrunner/v1.zip"],
    sha256 = "...",
)

B/Ruang Kerja

workspace(name = "B")

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")
http_archive(
    name = "testrunner",
    urls = ["https://github.com/testrunner/v2.zip"],
    sha256 = "..."
)

Baik dependensi A maupun B bergantung pada testrunner, tetapi keduanya bergantung pada versi testrunner yang berbeda. Tidak ada alasan untuk runner pengujian ini tidak berdampingan secara damai dalam myproject, tetapi mereka akan berbenturan satu sama lain karena memiliki nama yang sama. Untuk mendeklarasikan kedua dependensi tersebut, update myproject/WORKSPACE:

workspace(name = "myproject")

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")
http_archive(
    name = "testrunner-v1",
    urls = ["https://github.com/testrunner/v1.zip"],
    sha256 = "..."
)
http_archive(
    name = "testrunner-v2",
    urls = ["https://github.com/testrunner/v2.zip"],
    sha256 = "..."
)
local_repository(
    name = "A",
    path = "../A",
    repo_mapping = {"@testrunner" : "@testrunner-v1"}
)
local_repository(
    name = "B",
    path = "../B",
    repo_mapping = {"@testrunner" : "@testrunner-v2"}
)

Mekanisme ini juga dapat digunakan untuk menggabungkan diamond. Misalnya, jika A dan B memiliki dependensi yang sama tetapi memanggilnya dengan nama berbeda, dependensi tersebut dapat digabungkan dalam myproject/WORKSPACE.

Mengganti repositori dari command line

Untuk mengganti repositori yang dideklarasikan dengan repositori lokal dari command line, gunakan tanda --override_repository. Penggunaan flag ini akan mengubah konten repositori eksternal tanpa mengubah kode sumber Anda.

Misalnya, untuk mengganti @foo ke direktori lokal /path/to/local/foo, teruskan flag --override_repository=foo=/path/to/local/foo.

Beberapa kasus penggunaan mencakup:

  • Masalah proses debug. Misalnya, Anda dapat mengganti repositori http_archive ke direktori lokal tempat Anda dapat membuat perubahan dengan lebih mudah.
  • Vendor. Jika Anda berada di lingkungan tempat Anda tidak dapat melakukan panggilan jaringan, ganti aturan repositori berbasis jaringan agar mengarah ke direktori lokal.

Menggunakan proxy

Bazel akan mengambil alamat proxy dari variabel lingkungan HTTPS_PROXY dan HTTP_PROXY serta menggunakannya untuk mendownload file HTTP/HTTPS (jika ditentukan).

Dukungan untuk IPv6

Pada komputer khusus IPv6, Bazel akan dapat mendownload dependensi tanpa perubahan. Namun, pada mesin IPv4/IPv6 stack ganda, Bazel mengikuti konvensi yang sama seperti Java: jika IPv4 diaktifkan, IPv4 akan lebih disukai. Dalam beberapa situasi, misalnya saat jaringan IPv4 tidak dapat menyelesaikan/menjangkau alamat eksternal, hal ini dapat menyebabkan pengecualian Network unreachable dan kegagalan build. Dalam hal ini, Anda dapat mengganti perilaku Bazel untuk memilih IPv6 dengan menggunakan properti sistem java.net.preferIPv6Addresses=true. Khususnya:

  • Gunakan --host_jvm_args=-Djava.net.preferIPv6Addresses=true opsi startup, misalnya dengan menambahkan baris berikut dalam file .bazelrc Anda:

    startup --host_jvm_args=-Djava.net.preferIPv6Addresses=true

  • Jika Anda menjalankan target build Java yang juga perlu terhubung ke internet (pengujian integrasi terkadang memerlukan hal tersebut), gunakan juga --jvmopt=-Djava.net.preferIPv6Addresses=true flag alat, untuk dengan memiliki baris berikut di file .bazelrc:

    build --jvmopt=-Djava.net.preferIPv6Addresses

  • Jika Anda menggunakan aturan_jvm_eksternal , misalnya, untuk resolusi versi dependensi, tambahkan juga -Djava.net.preferIPv6Addresses=true keCOURSIER_OPTS variabel lingkungan kemenyediakan opsi JVM untuk Coursier

Dependensi transitif

Bazel hanya membaca dependensi yang tercantum dalam file WORKSPACE Anda. Jika project Anda (A) bergantung pada project lain (B) yang mencantumkan dependensi pada project ketiga (C) di file WORKSPACE-nya, Anda akan harus menambahkan B dan C ke file WORKSPACE project Anda. Persyaratan ini dapat balon ukuran file WORKSPACE, tetapi membatasi kemungkinan memiliki satu library yang menyertakan C pada versi 1.0 dan yang lainnya menyertakan C pada 2.0.

Menyimpan cache dependensi eksternal

Secara default, Bazel hanya akan mendownload ulang dependensi eksternal jika definisinya berubah. Perubahan pada file yang direferensikan dalam definisi (seperti patch atau file BUILD) juga dipertimbangkan oleh bazel.

Untuk memaksa download ulang, gunakan bazel sync.

Tata Letak

Semua dependensi eksternal didownload ke direktori di bagian subdirektori external dalambasis keluaran Domain. Untuk repositori lokal, symlink akan dibuat di sana, bukan membuat direktori baru. Anda dapat melihat direktori external dengan menjalankan:

ls $(bazel info output_base)/external

Perlu diperhatikan bahwa menjalankan bazel clean sebenarnya tidak akan menghapus direktori eksternal. Untuk menghapus semua artefak eksternal, gunakan bazel clean --expunge.

Build offline

Kadang-kadang diinginkan atau diperlukan untuk menjalankan build secara offline. Untuk kasus penggunaan sederhana, seperti bepergian di pesawat, mengambil data repositori yang diperlukan dengan bazel fetch atau bazel sync sudah cukup; selain itu, menggunakan opsi --nofetch, pengambilan repositori lebih lanjut dapat dinonaktifkan selama build.

Untuk build offline sebenarnya, yang menyediakan file yang diperlukan oleh entitas yang berbeda dari bazel, bazel mendukung opsi --distdir. Setiap kali aturan repositori meminta bazel untuk mengambil file melalui ctx.download atau ctx.download_and_extract dan memberikan jumlah hash yang diperlukan, bazel akan melihat direktori yang ditentukan oleh opsi tersebut untuk file yang cocok dengan nama dasar URL pertama yang disediakan, dan menggunakan salinan lokal tersebut jika hash cocok.

Bazel sendiri menggunakan teknik ini untuk melakukan bootstrap secara offline dari artefak distribusi. Hal ini dilakukan dengan mengumpulkan semua dependensi eksternal yang diperlukan dalam distdir_tar internal.

Namun, bazel memungkinkan eksekusi perintah arbitrer dalam aturan repositori, tanpa mengetahui apakah panggilan tersebut ke jaringan. Oleh karena itu, bazel tidak memiliki opsi untuk menerapkan build yang sedang offline sepenuhnya. Jadi, menguji apakah build berfungsi dengan benar secara offline memerlukan pemblokiran jaringan eksternal, seperti yang dilakukan bazel dalam pengujian bootstrapnya.

Praktik terbaik

Aturan repositori

Aturan repositori secara umum bertanggung jawab atas:

  • Mendeteksi setelan sistem dan menuliskannya ke file.
  • Menemukan resource di sistem.
  • Mendownload resource dari URL.
  • Membuat atau membuat symlink file BUILD ke direktori repositori eksternal.

Hindari penggunaan repository_ctx.execute jika memungkinkan. Misalnya, jika menggunakan library C++ non-Bazel yang memiliki build menggunakan Make, sebaiknya gunakan repository_ctx.download(), lalu tulis file BUILD yang mem-build-nya, daripada menjalankan ctx.execute(["make"]) Domain.

Pilih http_archive untuk git_repository dan new_git_repository. Alasannya adalah:

  • Aturan repositori Git bergantung pada sistem git(1), sedangkan downloader HTTP di-build ke dalam Bazel dan tidak memiliki dependensi sistem.
  • http_archive mendukung daftar urls sebagai pencerminan, dan git_repository hanya mendukung satu remote.
  • http_archive berfungsi dengan cache repositori, tetapi tidak dengan git_repository. Lihat #5116 untuk informasi selengkapnya.

Jangan gunakan bind(). Lihat "Pertimbangkan untuk menghapus pengikatan" untuk diskusi panjang tentang masalah dan alternatifnya.