Build Foundation เริ่มรับสมัครสมาชิกผู้ก่อตั้งแล้ว เข้าร่วมรายชื่ออีเมล อ่านข้อตกลงในการเข้าร่วม และลงทะเบียน

Google uses AI technology to translate content into your preferred language. AI translations can contain errors.

การเพิ่มประสิทธิภาพ

Nightly · 9.1 · 9.0 · 8.7 · 8.6 · 8.5 · 8.4 · 8.3 · 8.2 · 8.1

เมื่อเขียนกฎ ข้อผิดพลาดด้านประสิทธิภาพที่พบบ่อยที่สุดคือการข้ามหรือคัดลอกข้อมูลที่สะสมจากทรัพยากร Dependency เมื่อรวมข้อมูลไว้ในบิลด์ทั้งหมด การดำเนินการเหล่านี้อาจใช้เวลาหรือพื้นที่ O(N^2) ได้อย่างง่ายดาย คุณจึงต้องทำความเข้าใจวิธีใช้ depsets อย่างมีประสิทธิภาพเพื่อหลีกเลี่ยงปัญหานี้

การทำความเข้าใจวิธีใช้ depsets อย่างมีประสิทธิภาพอาจเป็นเรื่องยาก Bazel จึงมีเครื่องมือสร้างโปรไฟล์หน่วยความจำที่จะช่วยคุณค้นหาจุดที่คุณอาจทำผิดพลาด โปรดทราบว่าค่าใช้จ่ายในการเขียนกฎที่ไม่มีประสิทธิภาพอาจไม่ชัดเจนจนกว่าจะมีการใช้งานอย่างแพร่หลาย

ใช้ depsets

คุณควรใช้ depsetsทุกครั้งที่รวบรวมข้อมูลจากทรัพยากร Dependency ของกฎ ใช้รายการหรือดิกชันนารีธรรมดาเพื่อเผยแพร่ข้อมูลเฉพาะกฎปัจจุบันเท่านั้น

depset แสดงข้อมูลเป็นกราฟแบบซ้อน ซึ่งช่วยให้แชร์ข้อมูลได้

ลองดูตัวอย่างกราฟต่อไปนี้

C -> B -> A
D ---^

แต่ละโหนดจะเผยแพร่สตริงเดียว เมื่อใช้ depsets ข้อมูลจะมีลักษณะดังนี้

a = depset(direct=['a'])
b = depset(direct=['b'], transitive=[a])
c = depset(direct=['c'], transitive=[b])
d = depset(direct=['d'], transitive=[b])

โปรดทราบว่าแต่ละรายการจะกล่าวถึงเพียงครั้งเดียว หากใช้รายการ คุณจะได้ผลลัพธ์ดังนี้

a = ['a']
b = ['b', 'a']
c = ['c', 'b', 'a']
d = ['d', 'b', 'a']

โปรดทราบว่าในกรณีนี้มีการกล่าวถึง 'a' 4 ครั้ง! และปัญหานี้จะแย่ลงเมื่อกราฟมีขนาดใหญ่ขึ้น

ต่อไปนี้เป็นตัวอย่างการใช้กฎที่ใช้ depsets อย่างถูกต้องเพื่อเผยแพร่ข้อมูลแบบทรานซิทีฟ โปรดทราบว่าคุณสามารถเผยแพร่ข้อมูลเฉพาะกฎโดยใช้รายการได้หากต้องการ เนื่องจากวิธีนี้ไม่ใช่ O(N^2)

MyProvider = provider()

def _impl(ctx):
  my_things = ctx.attr.things
  all_things = depset(
      direct=my_things,
      transitive=[dep[MyProvider].all_things for dep in ctx.attr.deps]
  )
  ...
  return [MyProvider(
    my_things=my_things,  # OK, a flat list of rule-local things only
    all_things=all_things,  # OK, a depset containing dependencies
  )]

ดูข้อมูลเพิ่มเติมได้ที่หน้าภาพรวมของ depset

หลีกเลี่ยงการเรียก `depset.to_list()`

คุณสามารถบังคับให้ depset เป็นรายการแบบแบนได้โดยใช้ to_list() แต่วิธีนี้มักจะมีค่าใช้จ่าย O(N^2) ดังนั้นให้หลีกเลี่ยงการทำให้ depset เป็นแบบแบน ยกเว้นเพื่อวัตถุประสงค์ในการแก้ไขข้อบกพร่อง

ความเข้าใจผิดที่พบบ่อยคือคุณสามารถทำให้ depset เป็นแบบแบนได้อย่างอิสระหากทำเฉพาะในเป้าหมายระดับบนสุด เช่น กฎ <xx>_binary เนื่องจากค่าใช้จ่ายจะไม่ สะสมในแต่ละระดับของกราฟบิลด์ แต่การดำเนินการนี้ ยังคง เป็น O(N^2) เมื่อคุณสร้างชุดเป้าหมายที่มีทรัพยากร Dependency ที่ทับซ้อนกัน ซึ่งจะเกิดขึ้นเมื่อสร้างการทดสอบ //foo/tests/... หรือเมื่อนำเข้าโปรเจ็กต์ IDE

ลดจำนวนการเรียก `depset`

การเรียก depset ภายในลูปมักเป็นข้อผิดพลาด ซึ่งอาจทำให้เกิด depsets ที่มีการซ้อนกันลึกมาก ซึ่งส่งผลให้ประสิทธิภาพไม่ดี ตัวอย่างเช่น

x = depset()
for i in inputs:
    # Do not do that.
    x = depset(transitive = [x, i.deps])

คุณสามารถแทนที่โค้ดนี้ได้อย่างง่ายดาย โดยขั้นแรก ให้รวบรวม depsets แบบทรานซิทีฟและผสานรวมทั้งหมดพร้อมกัน

transitive = []

for i in inputs:
    transitive.append(i.deps)

x = depset(transitive = transitive)

บางครั้งคุณสามารถลดการดำเนินการนี้ได้โดยใช้การทำความเข้าใจรายการ

x = depset(transitive = [i.deps for i in inputs])

ใช้ ctx.actions.args() สำหรับบรรทัดคำสั่ง

เมื่อสร้างบรรทัดคำสั่ง คุณควรใช้ ctx.actions.args() ซึ่งจะเลื่อนการขยาย depsets ไปยังระยะการดำเนินการ

นอกเหนือจากความเร็วที่เพิ่มขึ้นอย่างเห็นได้ชัดแล้ว วิธีนี้ยังช่วยลดการใช้หน่วยความจำของกฎได้ด้วย ซึ่งบางครั้งอาจลดลงถึง 90% หรือมากกว่า

เคล็ดลับบางอย่างมีดังนี้

ส่ง depsets และรายการเป็นอาร์กิวเมนต์โดยตรงแทนการทำให้เป็นแบบแบนด้วยตนเอง ctx.actions.args() จะขยายรายการและ depsets ให้คุณ หากต้องการทำการแปลงเนื้อหา depset ให้ดูที่ ctx.actions.args#add เพื่อดูว่ามีฟังก์ชันใดที่เหมาะกับความต้องการของคุณหรือไม่
คุณส่ง File#path เป็นอาร์กิวเมนต์อยู่ใช่ไหม ไม่จำเป็น ระบบจะเปลี่ยน ไฟล์เป็น เส้นทางโดยอัตโนมัติและเลื่อนการขยายเวลาออกไป
หลีกเลี่ยงการสร้างสตริงโดยการเชื่อมสตริงเข้าด้วยกัน อาร์กิวเมนต์สตริงที่ดีที่สุดคือค่าคงที่ เนื่องจากหน่วยความจำจะแชร์ระหว่างอินสแตนซ์ทั้งหมดของกฎ
หากอาร์กิวเมนต์ยาวเกินไปสำหรับบรรทัดคำสั่ง คุณสามารถเขียนออบเจ็กต์ ctx.actions.args() ลงในไฟล์พารามิเตอร์แบบมีเงื่อนไขหรือไม่มีเงื่อนไขได้โดยใช้ ctx.actions.args#use_param_file ซึ่งจะดำเนินการเบื้องหลังเมื่อมีการดำเนินการ หากต้องการควบคุมไฟล์พารามิเตอร์อย่างชัดเจน คุณสามารถเขียนไฟล์ด้วยตนเองโดยใช้ ctx.actions.write

ตัวอย่าง

def _impl(ctx):
  ...
  args = ctx.actions.args()
  file = ctx.declare_file(...)
  files = depset(...)

  # Bad, constructs a full string "--foo=<file path>" for each rule instance
  args.add("--foo=" + file.path)

  # Good, shares "--foo" among all rule instances, and defers file.path to later
  # It will however pass ["--foo", <file path>] to the action command line,
  # instead of ["--foo=<file_path>"]
  args.add("--foo", file)

  # Use format if you prefer ["--foo=<file path>"] to ["--foo", <file path>]
  args.add(format="--foo=%s", value=file)

  # Bad, makes a giant string of a whole depset
  args.add(" ".join(["-I%s" % file.short_path for file in files])

  # Good, only stores a reference to the depset
  args.add_all(files, format_each="-I%s", map_each=_to_short_path)

# Function passed to map_each above
def _to_short_path(f):
  return f.short_path

อินพุตการดำเนินการแบบทรานซิทีฟควรเป็น depsets

เมื่อสร้างการดำเนินการโดยใช้ ctx.actions.run อย่าลืมว่าช่อง inputs ยอมรับ depset ให้ใช้ช่องนี้ทุกครั้งที่รวบรวมอินพุตจากทรัพยากร Dependency แบบทรานซิทีฟ

inputs = depset(...)
ctx.actions.run(
  inputs = inputs,  # Do *not* turn inputs into a list
  ...
)

การหยุดทำงาน

หาก Bazel ดูเหมือนจะหยุดทำงาน คุณสามารถกด Ctrl-\ หรือส่ง สัญญาณ SIGQUIT ไปยัง Bazel (kill -3 $(bazel info server_pid)) เพื่อรับการดัมพ์เธรด ในไฟล์ $(bazel info output_base)/server/jvm.out

เนื่องจากคุณอาจเรียกใช้ bazel info ไม่ได้หาก Bazel หยุดทำงาน ไดเรกทอรี output_base มักจะเป็นไดเรกทอรีระดับบนสุดของ bazel-<workspace> ลิงก์สัญลักษณ์ในไดเรกทอรีพื้นที่ทำงาน

การสร้างโปรไฟล์ประสิทธิภาพ

โปรไฟล์การติดตาม JSON มีประโยชน์มาก ในการทำความเข้าใจอย่างรวดเร็วว่า Bazel ใช้เวลาไปกับอะไรบ้างระหว่างการเรียกใช้

คุณสามารถใช้แฟล็ก --experimental_command_profile เพื่อบันทึกโปรไฟล์ Java Flight Recorder ประเภทต่างๆ (เวลา CPU, เวลาจริง, การจัดสรรหน่วยความจำ และการแย่งชิงการล็อก)

คุณสามารถใช้--starlark_cpu_profile แฟล็ก เพื่อเขียนโปรไฟล์ pprof ของการใช้ CPU โดยเธรด Starlark ทั้งหมด

การสร้างโปรไฟล์หน่วยความจำ

Bazel มาพร้อมกับเครื่องมือสร้างโปรไฟล์หน่วยความจำในตัวที่จะช่วยคุณตรวจสอบการใช้หน่วยความจำของกฎ หากพบปัญหา คุณสามารถดัมพ์ฮีปเพื่อค้นหาบรรทัดโค้ดที่ทำให้เกิดปัญหาได้อย่างแม่นยำ

การเปิดใช้การติดตามหน่วยความจำ

คุณต้องส่งแฟล็กเริ่มต้น 2 รายการนี้ไปยังการเรียกใช้ Bazel ทุกครั้ง

  STARTUP_FLAGS=\
  --host_jvm_args=-javaagent:<path to java-allocation-instrumenter-3.3.4.jar> \
  --host_jvm_args=-DRULE_MEMORY_TRACKER=1

แฟล็กเหล่านี้จะเริ่มเซิร์ฟเวอร์ในโหมดการติดตามหน่วยความจำ หากคุณลืมแฟล็กเหล่านี้แม้แต่การเรียกใช้ Bazel เพียงครั้งเดียว เซิร์ฟเวอร์จะรีสตาร์ทและคุณจะต้องเริ่มต้นใหม่

การใช้เครื่องมือติดตามหน่วยความจำ

ตัวอย่างเช่น ให้ดูเป้าหมาย foo และดูว่าเป้าหมายนี้ทำอะไรบ้าง หากต้องการเรียกใช้เฉพาะการวิเคราะห์และไม่เรียกใช้ระยะการดำเนินการบิลด์ ให้เพิ่มแฟล็ก --nobuild

$ bazel $(STARTUP_FLAGS) build --nobuild //foo:foo

จากนั้นดูว่าอินสแตนซ์ Bazel ทั้งหมดใช้หน่วยความจำเท่าใด

$ bazel $(STARTUP_FLAGS) info used-heap-size-after-gc
> 2594MB

แยกตามคลาสกฎโดยใช้ bazel dump --rules

$ bazel $(STARTUP_FLAGS) dump --rules
>

RULE                                 COUNT     ACTIONS          BYTES         EACH
genrule                             33,762      33,801    291,538,824        8,635
config_setting                      25,374           0     24,897,336          981
filegroup                           25,369      25,369     97,496,272        3,843
cc_library                           5,372      73,235    182,214,456       33,919
proto_library                        4,140     110,409    186,776,864       45,115
android_library                      2,621      36,921    218,504,848       83,366
java_library                         2,371      12,459     38,841,000       16,381
_gen_source                            719       2,157      9,195,312       12,789
_check_proto_library_deps              719         668      1,835,288        2,552
... (more output)

ดูว่าหน่วยความจำไปอยู่ที่ใดบ้างโดยสร้างไฟล์ pprof โดยใช้ bazel dump --skylark_memory

$ bazel $(STARTUP_FLAGS) dump --skylark_memory=$HOME/prof.gz
> Dumping Starlark heap to: /usr/local/google/home/$USER/prof.gz

ใช้เครื่องมือ pprof เพื่อตรวจสอบฮีป จุดเริ่มต้นที่ดีคือการรับกราฟ Flame โดยใช้ pprof -flame $HOME/prof.gz

ดาวน์โหลด pprof จาก https://github.com/google/pprof

รับการดัมพ์ข้อความของไซต์การเรียกที่ใช้งานมากที่สุดซึ่งมีคำอธิบายประกอบเป็นบรรทัด

$ pprof -text -lines $HOME/prof.gz
>
      flat  flat%   sum%        cum   cum%
  146.11MB 19.64% 19.64%   146.11MB 19.64%  android_library <native>:-1
  113.02MB 15.19% 34.83%   113.02MB 15.19%  genrule <native>:-1
   74.11MB  9.96% 44.80%    74.11MB  9.96%  glob <native>:-1
   55.98MB  7.53% 52.32%    55.98MB  7.53%  filegroup <native>:-1
   53.44MB  7.18% 59.51%    53.44MB  7.18%  sh_test <native>:-1
   26.55MB  3.57% 63.07%    26.55MB  3.57%  _generate_foo_files /foo/tc/tc.bzl:491
   26.01MB  3.50% 66.57%    26.01MB  3.50%  _build_foo_impl /foo/build_test.bzl:78
   22.01MB  2.96% 69.53%    22.01MB  2.96%  _build_foo_impl /foo/build_test.bzl:73
   ... (more output)