Como otimizar o desempenho

Informar um problema Ver código-fonte Nightly · 7.4 . 7.3 · 7.2 · 7.1 · 7.0 · 6.5

Ao escrever regras, o problema de desempenho mais comum é atravessar ou copiar dados acumulados de dependências. Quando agregadas em toda a versão, essas operações podem facilmente ocupar espaço ou tempo O(N^2). Para evitar isso, é fundamental entender como usar os depsets de maneira eficaz.

Isso pode ser difícil de fazer corretamente. Por isso, o Bazel também fornece um perfilador de memória que ajuda a encontrar pontos em que você pode ter cometido um erro. Aviso: o custo de escrever uma regra ineficiente pode não ser evidente até que ela seja usada amplamente.

Usar depsets

Sempre que você estiver agrupando informações de dependências de regras, use depsets. Use apenas listas simples ou dicionários para publicar informações locais para a regra atual.

Um depset representa informações como um gráfico aninhado que permite o compartilhamento.

Considere o seguinte gráfico:

C -> B -> A
D ---^

Cada nó publica uma única string. Com os depsets, os dados ficam assim:

a = depset(direct=['a'])
b = depset(direct=['b'], transitive=[a])
c = depset(direct=['c'], transitive=[b])
d = depset(direct=['d'], transitive=[b])

Cada item é mencionado apenas uma vez. Com listas, você teria o seguinte:

a = ['a']
b = ['b', 'a']
c = ['c', 'b', 'a']
d = ['d', 'b', 'a']

Nesse caso, 'a' é mencionado quatro vezes. Com gráficos maiores, esse problema só vai piorar.

Confira um exemplo de implementação de regra que usa depssets corretamente para publicar informações transitivas. Não há problema em publicar informações locais de regras usando listas, se você quiser, já que isso não é O(N^2).

MyProvider = provider()

def _impl(ctx):
  my_things = ctx.attr.things
  all_things = depset(
      direct=my_things,
      transitive=[dep[MyProvider].all_things for dep in ctx.attr.deps]
  )
  ...
  return [MyProvider(
    my_things=my_things,  # OK, a flat list of rule-local things only
    all_things=all_things,  # OK, a depset containing dependencies
  )]

Consulte a página Visão geral do conjunto de dependências para mais informações.

Evite chamar depset.to_list()

É possível forçar um depset a uma lista plana usando to_list(), mas isso geralmente resulta em um custo O(N^2). Se possível, evite qualquer nivelamento de depsets, exceto para fins de depuração.

Um equívoco comum é que você pode achatar livremente os conjuntos de dependências se fizer isso apenas em destinos de nível superior, como uma regra <xx>_binary, já que o custo não é acumulado em cada nível do gráfico de build. No entanto, isso ainda é O(N^2) quando você cria um conjunto de destinos com dependências sobrepostas. Isso acontece ao criar os testes //foo/tests/... ou ao importar um projeto do ambiente de desenvolvimento integrado.

Reduzir o número de chamadas para depset

Chamar depset dentro de um loop geralmente é um erro. Isso pode levar a detecções com aninhamento muito profundo, que têm desempenho ruim. Exemplo:

x = depset()
for i in inputs:
    # Do not do that.
    x = depset(transitive = [x, i.deps])

Esse código pode ser substituído facilmente. Primeiro, colete os depsets transitivos e mescle todos de uma só vez:

transitive = []

for i in inputs:
    transitive.append(i.deps)

x = depset(transitive = transitive)

Às vezes, isso pode ser reduzido usando uma compreensão de lista:

x = depset(transitive = [i.deps for i in inputs])

Usar ctx.actions.args() para linhas de comando

Ao criar linhas de comando, use ctx.actions.args(). Isso adia a expansão de qualquer depset para a fase de execução.

Além de ser estritamente mais rápido, isso reduzirá o consumo de memória das regras, às vezes em 90% ou mais.

Confira alguns truques:

  • Transmita depsets e listas diretamente como argumentos, em vez de aplaná-los você mesmo. Elas serão expandidas por ctx.actions.args() para você. Se você precisar de transformações no conteúdo do depset, consulte ctx.actions.args#add para ver se algo se encaixa.

  • Você está transmitindo File#path como argumentos? Não é necessário. Qualquer arquivo é automaticamente transformado no caminho, adiado para o momento da expansão.

  • Evite construir strings concatenando-as. O melhor argumento de string é uma constante, já que a memória dele será compartilhada entre todas as instâncias da regra.

  • Se os argumentos forem muito longos para a linha de comando, um objeto ctx.actions.args() poderá ser gravado condicionalmente ou incondicionalmente em um arquivo de parâmetro usando ctx.actions.args#use_param_file. Isso é feito nos bastidores, quando a ação é executada. Se você precisar controlar explicitamente o arquivo de parâmetros, grave-o manualmente usando ctx.actions.write.

Exemplo:

def _impl(ctx):
  ...
  args = ctx.actions.args()
  file = ctx.declare_file(...)
  files = depset(...)

  # Bad, constructs a full string "--foo=<file path>" for each rule instance
  args.add("--foo=" + file.path)

  # Good, shares "--foo" among all rule instances, and defers file.path to later
  # It will however pass ["--foo", <file path>] to the action command line,
  # instead of ["--foo=<file_path>"]
  args.add("--foo", file)

  # Use format if you prefer ["--foo=<file path>"] to ["--foo", <file path>]
  args.add(format="--foo=%s", value=file)

  # Bad, makes a giant string of a whole depset
  args.add(" ".join(["-I%s" % file.short_path for file in files])

  # Good, only stores a reference to the depset
  args.add_all(files, format_each="-I%s", map_each=_to_short_path)

# Function passed to map_each above
def _to_short_path(f):
  return f.short_path

As entradas de ação transitiva precisam ser depsets

Ao criar uma ação usando ctx.actions.run, não se esqueça de que o campo inputs aceita um depset. Use essa opção sempre que as entradas forem coletadas das dependências transitivamente.

inputs = depset(...)
ctx.actions.run(
  inputs = inputs,  # Do *not* turn inputs into a list
  ...
)

Pendurado

Se o Bazel parecer travado, pressione Ctrl-\ ou envie um sinal SIGQUIT (kill -3 $(bazel info server_pid)) para receber um despejo de linha de execução no arquivo $(bazel info output_base)/server/jvm.out.

Como talvez não seja possível executar bazel info se o Bazel estiver travado, o diretório output_base geralmente é o pai do link simbólico bazel-<workspace> no diretório do espaço de trabalho.

Criação de perfis de desempenho

O perfil de rastreamento JSON pode ser muito útil para entender rapidamente em que o Bazel gastou tempo durante a invocação.

A flag --experimental_command_profile pode ser usada para capturar perfis do Java Flight Recorder de vários tipos (tempo de CPU, tempo decorrido, alocações de memória e contenção de bloqueio).

A flag --starlark_cpu_profile pode ser usada para gravar um perfil pprof do uso da CPU por todas as linhas de execução do Starlark.

Criação de perfil de memória

O Bazel vem com um perfilador de memória integrado que pode ajudar a verificar o uso de memória da sua regra. Se houver um problema, você poderá fazer um despejo da pilha para encontrar a linha exata de código que está causando o problema.

Ativar o rastreamento de memória

É necessário transmitir estas duas flags de inicialização para todas as invocações do Bazel:

  STARTUP_FLAGS=\
  --host_jvm_args=-javaagent:<path to java-allocation-instrumenter-3.3.0.jar> \
  --host_jvm_args=-DRULE_MEMORY_TRACKER=1

Eles iniciam o servidor no modo de rastreamento de memória. Se você esquecer isso em pelo menos uma invocação do Bazel, o servidor será reiniciado e você terá que começar de novo.

Como usar o rastreador de memória

Por exemplo, observe o alvo foo e veja o que ele faz. Para executar apenas a análise e não a fase de execução do build, adicione a flag --nobuild.

$ bazel $(STARTUP_FLAGS) build --nobuild //foo:foo

Em seguida, confira quanta memória toda a instância do Bazel consome:

$ bazel $(STARTUP_FLAGS) info used-heap-size-after-gc
> 2594MB

Divida por classe de regra usando bazel dump --rules:

$ bazel $(STARTUP_FLAGS) dump --rules
>

RULE                                 COUNT     ACTIONS          BYTES         EACH
genrule                             33,762      33,801    291,538,824        8,635
config_setting                      25,374           0     24,897,336          981
filegroup                           25,369      25,369     97,496,272        3,843
cc_library                           5,372      73,235    182,214,456       33,919
proto_library                        4,140     110,409    186,776,864       45,115
android_library                      2,621      36,921    218,504,848       83,366
java_library                         2,371      12,459     38,841,000       16,381
_gen_source                            719       2,157      9,195,312       12,789
_check_proto_library_deps              719         668      1,835,288        2,552
... (more output)

Confira para onde a memória está indo produzindo um arquivo pprof usando bazel dump --skylark_memory:

$ bazel $(STARTUP_FLAGS) dump --skylark_memory=$HOME/prof.gz
> Dumping Starlark heap to: /usr/local/google/home/$USER/prof.gz

Use a ferramenta pprof para investigar a pilha. Um bom ponto de partida é gerar um gráfico de chama usando pprof -flame $HOME/prof.gz.

Acesse pprof em https://github.com/google/pprof.

Receba um despejo de texto dos melhores sites de chamadas anotados com as linhas:

$ pprof -text -lines $HOME/prof.gz
>
      flat  flat%   sum%        cum   cum%
  146.11MB 19.64% 19.64%   146.11MB 19.64%  android_library <native>:-1
  113.02MB 15.19% 34.83%   113.02MB 15.19%  genrule <native>:-1
   74.11MB  9.96% 44.80%    74.11MB  9.96%  glob <native>:-1
   55.98MB  7.53% 52.32%    55.98MB  7.53%  filegroup <native>:-1
   53.44MB  7.18% 59.51%    53.44MB  7.18%  sh_test <native>:-1
   26.55MB  3.57% 63.07%    26.55MB  3.57%  _generate_foo_files /foo/tc/tc.bzl:491
   26.01MB  3.50% 66.57%    26.01MB  3.50%  _build_foo_impl /foo/build_test.bzl:78
   22.01MB  2.96% 69.53%    22.01MB  2.96%  _build_foo_impl /foo/build_test.bzl:73
   ... (more output)