Plataformas

Introducción

Bazel puede compilar y probar código en una variedad de hardware, sistemas operativos y configuraciones del sistema. Esto puede incluir diferentes versiones de herramientas de compilación, como vinculadores y compiladores. Para ayudar a administrar esta complejidad, Bazel tiene los conceptos de restricciones y plataformas.

Una restricción es una propiedad distintiva de una máquina de compilación o producción. Las restricciones comunes son la arquitectura de CPU, la presencia o ausencia de una GPU o la versión de un compilador instalado de forma local. Sin embargo, las restricciones pueden ser cualquier cosa que distinga de manera significativa las máquinas cuando se organiza el trabajo de compilación.

Una plataforma es una colección de restricciones que especifica una máquina completa. Bazel usa este concepto para permitir que los desarrolladores elijan para qué máquinas desean compilar, qué máquinas deben ejecutar acciones de compilación y prueba, y con qué cadenas de herramientas deben compilarse las acciones de compilación.

Los desarrolladores también pueden usar restricciones para seleccionar propiedades o dependencias personalizadas en sus reglas de compilación. Por ejemplo: "use src_arm.cc when the build targets an Arm machine".

Tipos de plataformas

Bazel reconoce tres roles que puede desempeñar una plataforma:

• Host : Es la plataforma en la que se ejecuta Bazel.
• Execution : Es una plataforma que ejecuta acciones de compilación para producir resultados de compilación.
• Target : Es una plataforma en la que se debe ejecutar el código que se está compilando.

Por lo general, las compilaciones tienen tres tipos de relaciones con las plataformas:

• Compilaciones de una sola plataforma : Las plataformas de host, ejecución y destino son las mismas. Por ejemplo, compilar en una máquina de desarrollador sin ejecución remota y, luego, ejecutar el objeto binario compilado en la misma máquina.

• Compilaciones de compilación cruzada : Las plataformas de host y ejecución son las mismas, pero la plataforma de destino es diferente. Por ejemplo, compilar una app para iOS en una Macbook Pro sin ejecución remota.

• Compilaciones de varias plataformas : Las plataformas de host, ejecución y destino son todas diferentes. Por ejemplo, compilar una app para iOS en una Macbook Pro y usar máquinas Linux remotas para compilar acciones de C++ que no necesiten Xcode.

Cómo especificar plataformas

La forma más común en que los desarrolladores usan plataformas es especificar las máquinas de destino deseadas con la marca --platforms:

$ bazel build //:my_linux_app --platforms=//myplatforms:linux_x86

Por lo general, las organizaciones mantienen sus propias definiciones de plataforma porque la configuración de la máquina de compilación varía entre las organizaciones.

Cuando no se establece --platforms, el valor predeterminado es @platforms//host. Esto se define especialmente para detectar automáticamente las propiedades del SO y la CPU de la máquina host, de modo que las compilaciones se orienten a la misma máquina en la que se ejecuta Bazel. Las reglas de compilación pueden seleccionar estas propiedades con las @platforms/os y @platforms/cpu restricciones.

Plataformas y restricciones generalmente útiles

Para mantener la coherencia del ecosistema, el equipo de Bazel mantiene un repositorio con definiciones de restricciones para las arquitecturas de CPU y los sistemas operativos más populares. Todas se definen en https://github.com/bazelbuild/platforms.

Bazel se envía con la siguiente definición de plataforma especial: @platforms//host (con el alias @bazel_tools//tools:host_platform). Esto detecta automáticamente las propiedades del SO y la CPU de la máquina en la que se ejecuta Bazel.

Define las restricciones

Las restricciones se modelan con las constraint_setting y constraint_value reglas de compilación.

constraint_setting declara un tipo de propiedad. Por ejemplo:

constraint_setting(name = "cpu")

constraint_value declara un valor posible para esa propiedad:

constraint_value(
    name = "x86",
    constraint_setting = ":cpu"
)

Se puede hacer referencia a ellos como etiquetas cuando se definen plataformas o se personalizan reglas de compilación en ellas. Si los ejemplos anteriores se definen en cpus/BUILD, puedes hacer referencia a la restricción x86 como //cpus:x86.

Si la visibilidad lo permite, puedes extender un constraint_setting existente definiendo tu propio valor.

Define las plataformas

La regla de compilación platform define una plataforma como una colección de constraint_values:

platform(
    name = "linux_x86",
    constraint_values = [
        "//oses:linux",
        "//cpus:x86",
    ],
)

Esto modela una máquina que debe tener las restricciones //oses:linux y //cpus:x86.

Las plataformas solo pueden tener un constraint_value para un constraint_setting determinado. Esto significa que, por ejemplo, una plataforma no puede tener dos CPUs, a menos que crees otro tipo constraint_setting para modelar el segundo valor.

Omite los destinos incompatibles

Cuando se compila para una plataforma de destino específica, suele ser conveniente omitir los destinos que nunca funcionarán en esa plataforma. Por ejemplo, es probable que el controlador de dispositivos de Windows genere muchos errores del compilador cuando se compila en una máquina Linux con //.... Usa el target_compatible_with atributo para indicarle a Bazel qué restricciones de plataforma de destino tiene tu código.

El uso más simple de este atributo restringe un destino a una sola plataforma. El destino no se compilará para ninguna plataforma que no cumpla con todas las restricciones. En el siguiente ejemplo, se restringe win_driver_lib.cc a Windows de 64 bits.

cc_library(
    name = "win_driver_lib",
    srcs = ["win_driver_lib.cc"],
    target_compatible_with = [
        "@platforms//cpu:x86_64",
        "@platforms//os:windows",
    ],
)

:win_driver_lib solo es compatible con la compilación con Windows de 64 bits y es incompatible con todo lo demás. La incompatibilidad es transitiva. Cualquier destino que dependa de forma transitiva de un destino incompatible se considera incompatible.

¿Cuándo se omiten los destinos?

Los destinos se omiten cuando se consideran incompatibles y se incluyen en la compilación como parte de una expansión de patrón de destino. Por ejemplo, las siguientes dos invocaciones omiten cualquier destino incompatible que se encuentre en una expansión de patrón de destino.

$ bazel build --platforms=//:myplatform //...

$ bazel build --platforms=//:myplatform //:all

Las pruebas incompatibles en un test_suite también se omiten si se especifica test_suite en la línea de comandos con --expand_test_suites. En otras palabras, los destinos test_suite en la línea de comandos se comportan como :all y .... El uso de --noexpand_test_suites evita la expansión y hace que test_suite los destinos con pruebas incompatibles también sean incompatibles.

Si se especifica explícitamente un destino incompatible en la línea de comandos, se genera un mensaje de error y falla la compilación.

$ bazel build --platforms=//:myplatform //:target_incompatible_with_myplatform
...
ERROR: Target //:target_incompatible_with_myplatform is incompatible and cannot be built, but was explicitly requested.
...
FAILED: Build did NOT complete successfully

Los destinos explícitos incompatibles se omiten de forma silenciosa si se habilita --skip_incompatible_explicit_targets.

Restricciones más expresivas

Para obtener más flexibilidad en la expresión de restricciones, usa el @platforms//:incompatible constraint_value que ninguna plataforma satisface.

Usa select() en combinación con @platforms//:incompatible para expresar restricciones más complicadas. Por ejemplo, úsalo para implementar la lógica OR básica. Lo siguiente marca una biblioteca compatible con macOS y Linux, pero no con otras plataformas.

cc_library(
    name = "unixish_lib",
    srcs = ["unixish_lib.cc"],
    target_compatible_with = select({
        "@platforms//os:osx": [],
        "@platforms//os:linux": [],
        "//conditions:default": ["@platforms//:incompatible"],
    }),
)

Lo anterior se puede interpretar de la siguiente manera:

1. Cuando se orienta a macOS, el destino no tiene restricciones.
2. Cuando se orienta a Linux, el destino no tiene restricciones.
3. De lo contrario, el destino tiene la restricción @platforms//:incompatible. Debido a que @platforms//:incompatible no forma parte de ninguna plataforma, el destino se considera incompatible.

Para que tus restricciones sean más legibles, usa skylib's selects.with_or().

Puedes expresar la compatibilidad inversa de manera similar. En el siguiente ejemplo, se describe una biblioteca que es compatible con todo excepto ARM.

cc_library(
    name = "non_arm_lib",
    srcs = ["non_arm_lib.cc"],
    target_compatible_with = select({
        "@platforms//cpu:arm": ["@platforms//:incompatible"],
        "//conditions:default": [],
    }),
)

Detecta destinos incompatibles con bazel cquery

Puedes usar el IncompatiblePlatformProvider en bazel cquery's formato de salida de Starlark para distinguir los destinos incompatibles de los compatibles.

Esto se puede usar para filtrar destinos incompatibles. En el siguiente ejemplo, solo se imprimirán las etiquetas de los destinos compatibles. No se imprimen los destinos incompatibles.

$ cat example.cquery

def format(target):
  if "IncompatiblePlatformProvider" not in providers(target):
    return target.label
  return ""


$ bazel cquery //... --output=starlark --starlark:file=example.cquery

Problemas conocidos

Los destinos incompatibles ignoran las restricciones de visibilidad.