Để xem tài liệu về bản phát hành ổn định, vui lòng sử dụng trình đơn thả xuống "Tài liệu được tạo phiên bản". Chế độ xem mặc định phản ánh phiên bản mới nhất ở HEAD.

Trang này được dịch bởi Cloud Translation API.

Quy tắc

Báo cáo sự cố Xem nguồn

Quy tắc xác định một loạt hành động mà Bazel thực hiện trên dữ liệu đầu vào để tạo ra một tập hợp đầu ra. Tập hợp này được tham chiếu trong trình cung cấp do hàm triển khai của quy tắc trả về. Ví dụ: quy tắc nhị phân C++ có thể:

Lấy một nhóm gồm .cpp tệp nguồn (dữ liệu đầu vào).
Chạy g++ trên các tệp nguồn (hành động).
Trả về trình cung cấp DefaultInfo cùng với dữ liệu đầu ra có thể thực thi và các tệp khác để cung cấp trong thời gian chạy.
Trả về trình cung cấp CcInfo có thông tin dành riêng cho C++ được thu thập từ mục tiêu và các phần phụ thuộc của mục tiêu đó.

Từ góc độ của Bazel, g++ và các thư viện C++ tiêu chuẩn cũng là dữ liệu đầu vào cho quy tắc này. Là người ghi quy tắc, bạn không chỉ phải xem xét dữ liệu đầu vào do người dùng cung cấp cho quy tắc, mà còn phải xem xét tất cả các công cụ và thư viện cần thiết để thực thi thao tác.

Trước khi tạo hoặc sửa đổi bất kỳ quy tắc nào, hãy đảm bảo bạn hiểu rõ các giai đoạn xây dựng của Bazel. Điều quan trọng là bạn phải hiểu được 3 giai đoạn của quá trình tạo bản dựng (tải, phân tích và thực thi). Bạn cũng nên tìm hiểu về macro để hiểu được sự khác biệt giữa các quy tắc và macro. Để bắt đầu, trước tiên hãy xem Hướng dẫn về quy tắc. Sau đó, sử dụng trang này làm tài liệu tham khảo.

Một vài quy tắc được tích hợp vào chính Bazel. Các quy tắc gốc này (chẳng hạn như genrule và filegroup) cung cấp một số dịch vụ hỗ trợ cốt lõi. Bằng cách xác định các quy tắc của riêng mình, bạn có thể thêm tính năng hỗ trợ cho các ngôn ngữ và công cụ mà Bazel không hỗ trợ sẵn.

Bazel cung cấp mô hình mở rộng để viết quy tắc bằng ngôn ngữ Starlark. Các quy tắc này được viết trong tệp .bzl và có thể được tải trực tiếp từ tệp BUILD.

Khi xác định quy tắc của riêng mình, bạn sẽ quyết định quy tắc đó hỗ trợ những thuộc tính nào và cách quy tắc tạo kết quả đầu ra.

Hàm implementation của quy tắc xác định hành vi chính xác của hàm này trong giai đoạn phân tích. Hàm này không chạy bất kỳ lệnh bên ngoài nào. Thay vào đó, hệ thống này đăng ký các hành động sẽ được dùng sau này trong giai đoạn thực thi để tạo kết quả của quy tắc (nếu cần).

Tạo quy tắc

Trong tệp .bzl, hãy dùng hàm quy tắc để xác định quy tắc mới và lưu trữ kết quả trong biến toàn cục. Lệnh gọi đến rule chỉ định các thuộc tính và một hàm triển khai:

example_library = rule(
    implementation = _example_library_impl,
    attrs = {
        "deps": attr.label_list(),
        ...
    },
)

Việc này xác định một loại quy tắc có tên example_library.

Lệnh gọi đến rule cũng phải chỉ định xem quy tắc sẽ tạo đầu ra có thể thực thi (với executable = True) hay cụ thể là tệp thực thi kiểm thử (với test = True). Nếu quy tắc thứ hai là quy tắc kiểm thử và tên quy tắc phải kết thúc bằng _test.

Tạo thực thể mục tiêu

Có thể tải các quy tắc và gọi trong tệp BUILD:

load('//some/pkg:rules.bzl', 'example_library')

example_library(
    name = "example_target",
    deps = [":another_target"],
    ...
)

Mỗi lệnh gọi đến một quy tắc bản dựng không trả về giá trị nào nhưng có tác dụng phụ là xác định mục tiêu. Đây được gọi là tạo thực thể cho quy tắc. Thao tác này chỉ định tên cho mục tiêu mới và các giá trị cho các thuộc tính của mục tiêu.

Bạn cũng có thể gọi các quy tắc qua các hàm Starlark và tải trong tệp .bzl. Các hàm Starlark gọi quy tắc được gọi là Macro Starlark. Cuối cùng, các macro Starlark phải được gọi từ các tệp BUILD và chỉ có thể được gọi trong giai đoạn tải, khi các tệp BUILD được đánh giá để tạo thực thể cho mục tiêu.

Thuộc tính

Thuộc tính là một đối số quy tắc. Thuộc tính có thể cung cấp giá trị cụ thể cho quá trình triển khai của một mục tiêu hoặc có thể tham chiếu đến các mục tiêu khác, tạo ra biểu đồ các phần phụ thuộc.

Các thuộc tính dành riêng cho quy tắc, chẳng hạn như srcs hoặc deps, được xác định bằng cách truyền một bản đồ từ tên thuộc tính đến giản đồ (được tạo bằng mô-đun attr) đến tham số attrs của rule. Các thuộc tính phổ biến, chẳng hạn như name và visibility, được ngầm thêm vào tất cả quy tắc. Các thuộc tính bổ sung được ngầm thêm vào riêng các quy tắc thực thi và kiểm thử. Bạn không thể đưa các thuộc tính được ngầm thêm vào quy tắc vào từ điển được chuyển đến attrs.

Thuộc tính phần phụ thuộc

Các quy tắc xử lý mã nguồn thường xác định các thuộc tính sau đây để xử lý nhiều loại phần phụ thuộc:

srcs chỉ định các tệp nguồn được xử lý bởi hành động của mục tiêu. Thông thường, giản đồ thuộc tính chỉ định đuôi tệp nào dự kiến cho loại tệp nguồn mà quy tắc xử lý. Các quy tắc cho các ngôn ngữ có tệp tiêu đề thường chỉ định một thuộc tính hdrs riêng cho các tiêu đề do mục tiêu và đối tượng sử dụng xử lý.
deps chỉ định các phần phụ thuộc mã cho một mục tiêu. Giản đồ thuộc tính phải chỉ định nhà cung cấp nào các phần phụ thuộc đó phải cung cấp. (Ví dụ: cc_library cung cấp CcInfo.)
data chỉ định các tệp được cung cấp trong thời gian chạy cho mọi tệp thực thi phụ thuộc vào một mục tiêu. Điều đó sẽ cho phép chỉ định các tệp tuỳ ý.

example_library = rule(
    implementation = _example_library_impl,
    attrs = {
        "srcs": attr.label_list(allow_files = [".example"]),
        "hdrs": attr.label_list(allow_files = [".header"]),
        "deps": attr.label_list(providers = [ExampleInfo]),
        "data": attr.label_list(allow_files = True),
        ...
    },
)

Sau đây là ví dụ về các thuộc tính phần phụ thuộc. Bất kỳ thuộc tính nào chỉ định nhãn dữ liệu đầu vào (các nhãn được xác định bằng attr.label_list, attr.label hoặc attr.label_keyed_string_dict) đều chỉ định các phần phụ thuộc thuộc một loại nhất định giữa một mục tiêu và các mục tiêu có nhãn (hoặc các đối tượng Label tương ứng) được liệt kê trong thuộc tính đó khi mục tiêu được xác định. Kho lưu trữ và có thể là đường dẫn cho các nhãn này được phân giải tương ứng với mục tiêu đã xác định.

example_library(
    name = "my_target",
    deps = [":other_target"],
)

example_library(
    name = "other_target",
    ...
)

Trong ví dụ này, other_target là phần phụ thuộc của my_target, do đó, other_target được phân tích trước tiên. Đó là lỗi nếu có chu kỳ trong biểu đồ phần phụ thuộc của các mục tiêu.

Thuộc tính riêng tư và phần phụ thuộc ngầm ẩn

Thuộc tính phần phụ thuộc có giá trị mặc định sẽ tạo một phần phụ thuộc ngầm ẩn. Điều này được ngầm ẩn vì là một phần của biểu đồ mục tiêu mà người dùng không chỉ định trong tệp BUILD. Các phần phụ thuộc ngầm ẩn rất hữu ích cho việc mã hoá cứng mối quan hệ giữa quy tắc và một công cụ (phần phụ thuộc thời gian xây dựng, chẳng hạn như trình biên dịch), vì hầu hết người dùng thường không quan tâm đến việc chỉ định công cụ mà quy tắc sử dụng. Bên trong hàm triển khai của quy tắc, phần phụ thuộc này được xử lý giống như các phần phụ thuộc khác.

Nếu muốn cung cấp một phần phụ thuộc ngầm ẩn mà không cho phép người dùng ghi đè giá trị đó, bạn có thể đặt thuộc tính này ở chế độ riêng tư bằng cách đặt tên bắt đầu bằng dấu gạch dưới (_). Các thuộc tính riêng tư phải có giá trị mặc định. Thường thì bạn chỉ nên sử dụng các thuộc tính riêng tư cho các phần phụ thuộc ngầm ẩn.

example_library = rule(
    implementation = _example_library_impl,
    attrs = {
        ...
        "_compiler": attr.label(
            default = Label("//tools:example_compiler"),
            allow_single_file = True,
            executable = True,
            cfg = "exec",
        ),
    },
)

Trong ví dụ này, mọi mục tiêu của loại example_library đều có phần phụ thuộc ngầm ẩn trên trình biên dịch //tools:example_compiler. Điều này cho phép hàm triển khai của example_library tạo các hành động gọi trình biên dịch, ngay cả khi người dùng không truyền nhãn làm dữ liệu đầu vào. Vì _compiler là một thuộc tính riêng tư, nên ctx.attr._compiler sẽ luôn trỏ đến //tools:example_compiler trong mọi mục tiêu của loại quy tắc này. Ngoài ra, bạn có thể đặt tên cho thuộc tính là compiler mà không dùng dấu gạch dưới và giữ nguyên giá trị mặc định. Điều này cho phép người dùng thay thế một trình biên dịch khác nếu cần, nhưng không đòi hỏi việc nhận biết nhãn của trình biên dịch.

Các phần phụ thuộc ngầm ẩn thường được dùng cho những công cụ nằm trong cùng một kho lưu trữ khi triển khai quy tắc. Nếu công cụ đến từ nền tảng thực thi hoặc một kho lưu trữ khác, thì quy tắc sẽ lấy công cụ đó từ một chuỗi công cụ.

Thuộc tính đầu ra

Các thuộc tính đầu ra, chẳng hạn như attr.output và attr.output_list, khai báo tệp đầu ra mà mục tiêu tạo ra. Các thuộc tính này khác với các thuộc tính phần phụ thuộc theo 2 cách:

Loại tệp này xác định các mục tiêu tệp đầu ra thay vì tham chiếu đến các mục tiêu được xác định ở nơi khác.
Các mục tiêu tệp đầu ra phụ thuộc vào mục tiêu của quy tắc tạo bản sao, thay vì ngược lại.

Thông thường, các thuộc tính đầu ra chỉ được dùng khi một quy tắc cần tạo dữ liệu đầu ra có tên do người dùng xác định mà không dựa trên tên mục tiêu. Nếu quy tắc có một thuộc tính đầu ra, thuộc tính đó thường có tên là out hoặc outs.

Các thuộc tính đầu ra là cách ưu tiên để tạo kết quả được khai báo trước. Kết quả này có thể được phụ thuộc cụ thể vào hoặc được yêu cầu tại dòng lệnh.

Hàm triển khai

Mỗi quy tắc yêu cầu một hàm implementation. Các hàm này được thực thi nghiêm ngặt trong giai đoạn phân tích và biến đổi biểu đồ các mục tiêu được tạo trong giai đoạn tải thành biểu đồ hành động cần thực hiện trong giai đoạn thực thi. Do đó, các hàm triển khai không thể đọc hoặc ghi tệp thực sự.

Các hàm triển khai quy tắc thường ở chế độ riêng tư (được đặt tên bằng dấu gạch dưới ở đầu). Thông thường, các quy tắc này có tên giống như quy tắc nhưng có hậu tố là _impl.

Hàm triển khai nhận chính xác một tham số: ngữ cảnh quy tắc, thường được đặt tên là ctx. Phương thức này trả về danh sách nhà cung cấp.

Mục tiêu

Các phần phụ thuộc được biểu thị tại thời điểm phân tích dưới dạng đối tượng Target. Các đối tượng này chứa nhà cung cấp được tạo khi hàm triển khai của mục tiêu được thực thi.

ctx.attr có các trường tương ứng với tên của từng thuộc tính phần phụ thuộc, chứa các đối tượng Target đại diện cho từng phần phụ thuộc trực tiếp sử dụng thuộc tính đó. Đối với các thuộc tính label_list, đây là danh sách Targets. Đối với các thuộc tính label, đây là một Target hoặc None.

Danh sách đối tượng nhà cung cấp được hàm triển khai của mục tiêu trả về:

return [ExampleInfo(headers = depset(...))]

Bạn có thể truy cập các đối tượng đó bằng cách sử dụng ký hiệu chỉ mục ([]), với loại trình cung cấp là khoá. Đây có thể là trình cung cấp tuỳ chỉnh được xác định trong Starlark hoặc những nhà cung cấp cho quy tắc gốc có sẵn dưới dạng biến chung Starlark.

Ví dụ: nếu một quy tắc lấy các tệp tiêu đề bằng thuộc tính hdrs và cung cấp các tệp đó cho các thao tác biên dịch của mục tiêu và đối tượng sử dụng, thì quy tắc đó có thể thu thập các tệp đó như sau:

def _example_library_impl(ctx):
    ...
    transitive_headers = [hdr[ExampleInfo].headers for hdr in ctx.attr.hdrs]

Hiện bạn không nên dùng kiểu cấu trúc cũ nữa, và bạn nên di chuyển các quy tắc khỏi kiểu cấu trúc đó.

Files

Tệp được biểu thị bằng đối tượng File. Vì Bazel không thực hiện I/O tệp trong giai đoạn phân tích, nên bạn không thể dùng các đối tượng này để trực tiếp đọc hoặc ghi nội dung tệp. Thay vào đó, chúng được truyền đến các hàm tạo hành động (xem ctx.actions) để tạo các phần của biểu đồ hành động.

File có thể là tệp nguồn hoặc tệp được tạo. Mỗi tệp được tạo phải là đầu ra của đúng một hành động. Tệp nguồn không được là kết quả của bất kỳ hành động nào.

Đối với mỗi thuộc tính phần phụ thuộc, trường tương ứng của ctx.files chứa danh sách kết quả đầu ra mặc định của tất cả các phần phụ thuộc sử dụng thuộc tính đó:

def _example_library_impl(ctx):
    ...
    headers = depset(ctx.files.hdrs, transitive = transitive_headers)
    srcs = ctx.files.srcs
    ...

ctx.file chứa một File hoặc None duy nhất cho các thuộc tính phần phụ thuộc có thông số được đặt allow_single_file = True. ctx.executable hoạt động giống như ctx.file, nhưng chỉ chứa các trường cho các thuộc tính phần phụ thuộc có đặt thông số kỹ thuật executable = True.

Khai báo kết quả đầu ra

Trong giai đoạn phân tích, chức năng triển khai của quy tắc có thể tạo ra kết quả. Vì tất cả các nhãn phải được xác định trong giai đoạn tải, nên các đầu ra bổ sung này sẽ không có nhãn nào. Bạn có thể tạo các đối tượng File cho kết quả đầu ra bằng cách sử dụng ctx.actions.declare_file và ctx.actions.declare_directory. Thông thường, tên của đầu ra được dựa trên tên của mục tiêu, ctx.label.name:

def _example_library_impl(ctx):
  ...
  output_file = ctx.actions.declare_file(ctx.label.name + ".output")
  ...

Đối với các đầu ra được khai báo trước, như các đầu ra được tạo cho các thuộc tính đầu ra, bạn có thể truy xuất đối tượng File từ các trường tương ứng của ctx.outputs.

Thao tác

Một thao tác mô tả cách tạo một tập hợp đầu ra từ một tập hợp dữ liệu đầu vào, ví dụ: "chạy gcc trên hello.c và nhận hello.o". Khi một thao tác được tạo, Bazel sẽ không chạy lệnh này ngay lập tức. Nó đăng ký thực thể đó trong biểu đồ phần phụ thuộc, vì một thao tác có thể phụ thuộc vào kết quả của một thao tác khác. Ví dụ: trong C, trình liên kết phải được gọi sau trình biên dịch.

Các hàm đa năng tạo thao tác được xác định trong ctx.actions:

ctx.actions.run để chạy tệp thực thi.
ctx.actions.run_shell để chạy lệnh shell.
ctx.actions.write để ghi một chuỗi vào tệp.
ctx.actions.expand_template để tạo tệp từ mẫu.

Bạn có thể dùng ctx.actions.args để tích luỹ các đối số cho các hành động một cách hiệu quả. Điều này giúp tránh làm phẳng các phần phụ thuộc cho đến thời điểm thực thi:

def _example_library_impl(ctx):
    ...

    transitive_headers = [dep[ExampleInfo].headers for dep in ctx.attr.deps]
    headers = depset(ctx.files.hdrs, transitive = transitive_headers)
    srcs = ctx.files.srcs
    inputs = depset(srcs, transitive = [headers])
    output_file = ctx.actions.declare_file(ctx.label.name + ".output")

    args = ctx.actions.args()
    args.add_joined("-h", headers, join_with = ",")
    args.add_joined("-s", srcs, join_with = ",")
    args.add("-o", output_file)

    ctx.actions.run(
        mnemonic = "ExampleCompile",
        executable = ctx.executable._compiler,
        arguments = [args],
        inputs = inputs,
        outputs = [output_file],
    )
    ...

Các thao tác sẽ lấy một danh sách hoặc phần phụ thuộc của tệp đầu vào và tạo một danh sách tệp đầu ra (không trống). Bạn phải xác định tập hợp các tệp đầu vào và đầu ra trong giai đoạn phân tích. Điều này có thể phụ thuộc vào giá trị của các thuộc tính (bao gồm cả trình cung cấp từ các phần phụ thuộc), nhưng không thể phụ thuộc vào kết quả của quá trình thực thi. Ví dụ: nếu hành động của bạn chạy lệnh giải nén, bạn phải chỉ định những tệp mà bạn muốn được tăng cường (trước khi chạy giải nén). Các thao tác tạo ra số lượng tệp thay đổi nội bộ có thể gói các tệp đó trong một tệp duy nhất (chẳng hạn như zip, tar hoặc định dạng lưu trữ khác).

Thao tác phải liệt kê tất cả dữ liệu đầu vào. Trang thông tin đầu vào không được sử dụng là được phép, nhưng không hiệu quả.

Hành động phải tạo ra tất cả đầu ra của chúng. Họ có thể ghi các tệp khác, nhưng bất kỳ nội dung nào không có trong đầu ra sẽ không được cung cấp cho đối tượng sử dụng. Tất cả đầu ra đã khai báo phải được ghi bằng một thao tác nào đó.

Các thao tác có thể so sánh với các hàm thuần tuý: Các thao tác này chỉ nên phụ thuộc vào dữ liệu đầu vào được cung cấp và tránh truy cập vào thông tin máy tính, tên người dùng, đồng hồ, mạng hoặc thiết bị I/O (ngoại trừ thao tác đọc dữ liệu đầu vào và đầu ra ghi). Điều này rất quan trọng vì kết quả sẽ được lưu vào bộ nhớ đệm và sử dụng lại.

Các phần phụ thuộc sẽ được Bazel phân giải. Quá trình này sẽ quyết định hành động nào sẽ thực thi. Sẽ là lỗi nếu có chu kỳ trong biểu đồ phần phụ thuộc. Việc tạo một thao tác không đảm bảo rằng thao tác đó sẽ được thực thi, điều này phụ thuộc vào việc liệu đầu ra của thao tác đó có cần thiết cho bản dựng hay không.

Nhà cung cấp

Trình cung cấp là những thông tin mà quy tắc cho thấy các quy tắc khác phụ thuộc vào quy tắc đó. Dữ liệu này có thể bao gồm các tệp đầu ra, thư viện, tham số cần truyền vào dòng lệnh của công cụ hoặc bất kỳ điều gì khác mà người tiêu dùng của mục tiêu nên biết.

Vì hàm triển khai của quy tắc chỉ có thể đọc nhà cung cấp từ các phần phụ thuộc tức thì của mục tiêu được tạo bản sao, nên các quy tắc cần chuyển tiếp mọi thông tin từ các phần phụ thuộc của mục tiêu mà người tiêu dùng của mục tiêu cần biết, thường bằng cách tích luỹ thông tin đó vào một depset.

Nhà cung cấp của mục tiêu được chỉ định bởi danh sách đối tượng nhà cung cấp do hàm triển khai trả về.

Các hàm triển khai cũ cũng có thể được viết theo kiểu cũ, trong đó hàm triển khai trả về struct thay vì danh sách đối tượng của nhà cung cấp. Bạn không nên sử dụng kiểu này và nên di chuyển các quy tắc khỏi kiểu này.

Đầu ra mặc định

Đầu ra mặc định của mục tiêu là đầu ra được yêu cầu theo mặc định khi mục tiêu được yêu cầu xây dựng ở dòng lệnh. Ví dụ: mục tiêu java_library //pkg:foo có foo.jar làm đầu ra mặc định, do đó sẽ được tạo bằng lệnh bazel build //pkg:foo.

Đầu ra mặc định được chỉ định bởi tham số files của DefaultInfo:

def _example_library_impl(ctx):
    ...
    return [
        DefaultInfo(files = depset([output_file]), ...),
        ...
    ]

Nếu DefaultInfo không được quá trình triển khai quy tắc trả về hoặc tham số files không được chỉ định, thì DefaultInfo.files sẽ mặc định trở thành tất cả đầu ra được khai báo trước (thường là những kết quả do thuộc tính đầu ra tạo ra).

Các quy tắc thực hiện hành động sẽ cung cấp kết quả mặc định, ngay cả khi các kết quả đó không được dự kiến sử dụng trực tiếp. Các thao tác không có trong biểu đồ của dữ liệu đầu ra được yêu cầu sẽ bị cắt bớt. Nếu chỉ người dùng của một mục tiêu sử dụng đầu ra, thì các thao tác đó sẽ không được thực hiện khi mục tiêu được tạo riêng biệt. Điều này khiến việc gỡ lỗi trở nên khó khăn hơn vì việc chỉ tạo lại mục tiêu không đạt sẽ không tái hiện lỗi đó.

Tệp Runfile

Tệp Runfile là một tập hợp các tệp mà mục tiêu sử dụng trong thời gian chạy (thay vì thời gian tạo bản dựng). Trong giai đoạn thực thi, Bazel sẽ tạo một cây thư mục chứa các đường liên kết tượng trưng trỏ đến các tệp chạy. Thao tác này kiểm soát môi trường cho tệp nhị phân để tệp có thể truy cập vào các tệp chạy trong thời gian chạy.

Bạn có thể thêm tệp Runfile theo cách thủ công trong quá trình tạo quy tắc. Bạn có thể tạo đối tượng runfiles bằng phương thức runfiles trong ngữ cảnh quy tắc là ctx.runfiles và được truyền đến tham số runfiles trên DefaultInfo. Kết quả có thể thực thi của các quy tắc thực thi sẽ được ngầm thêm vào các tệp chạy.

Một số quy tắc chỉ định các thuộc tính, thường được đặt tên là data. Đầu ra của các thuộc tính này sẽ được thêm vào các tệp chạy của mục tiêu. Bạn cũng nên hợp nhất các tệp Runfile từ data, cũng như từ mọi thuộc tính có thể cung cấp mã để thực thi cuối cùng, thường là srcs (có thể chứa các mục tiêu filegroup có data được liên kết) và deps.

def _example_library_impl(ctx):
    ...
    runfiles = ctx.runfiles(files = ctx.files.data)
    transitive_runfiles = []
    for runfiles_attr in (
        ctx.attr.srcs,
        ctx.attr.hdrs,
        ctx.attr.deps,
        ctx.attr.data,
    ):
        for target in runfiles_attr:
            transitive_runfiles.append(target[DefaultInfo].default_runfiles)
    runfiles = runfiles.merge_all(transitive_runfiles)
    return [
        DefaultInfo(..., runfiles = runfiles),
        ...
    ]

Nhà cung cấp tuỳ chỉnh

Bạn có thể xác định trình cung cấp bằng hàm provider để truyền tải thông tin dành riêng cho quy tắc:

ExampleInfo = provider(
    "Info needed to compile/link Example code.",
    fields = {
        "headers": "depset of header Files from transitive dependencies.",
        "files_to_link": "depset of Files from compilation.",
    },
)

Sau đó, các hàm triển khai quy tắc có thể tạo và trả về các thực thể nhà cung cấp:

def _example_library_impl(ctx):
  ...
  return [
      ...
      ExampleInfo(
          headers = headers,
          files_to_link = depset(
              [output_file],
              transitive = [
                  dep[ExampleInfo].files_to_link for dep in ctx.attr.deps
              ],
          ),
      )
  ]

Khởi chạy tuỳ chỉnh nhà cung cấp

Bạn có thể bảo vệ quá trình tạo bản sao của trình cung cấp bằng logic xác thực và xử lý trước tuỳ chỉnh. Bạn có thể dùng tính năng này để đảm bảo tất cả các thực thể của nhà cung cấp đều đáp ứng một số bất biến nhất định hoặc để cung cấp cho người dùng một API rõ ràng hơn để nhận một thực thể.

Bạn có thể thực hiện việc này bằng cách truyền lệnh gọi lại init đến hàm provider. Nếu bạn sử dụng lệnh gọi lại này, loại dữ liệu trả về của provider() sẽ thay đổi thành một bộ dữ liệu gồm hai giá trị: biểu tượng nhà cung cấp là giá trị trả về thông thường khi không sử dụng init và "hàm khởi tạo thô".

Trong trường hợp này, khi biểu tượng nhà cung cấp được gọi, thay vì trực tiếp trả về một thực thể mới, hệ thống sẽ chuyển tiếp các đối số cùng với lệnh gọi lại init. Giá trị trả về của lệnh gọi lại phải là tên trường ánh xạ chính tả (chuỗi) đến các giá trị; giá trị này dùng để khởi tạo các trường của thực thể mới. Xin lưu ý rằng lệnh gọi lại có thể có bất kỳ chữ ký nào và nếu các đối số không khớp với chữ ký, hệ thống sẽ báo cáo lỗi như thể lệnh gọi lại được gọi trực tiếp.

Ngược lại, hàm khởi tạo thô sẽ bỏ qua lệnh gọi lại init.

Ví dụ sau đây sử dụng init để xử lý trước và xác thực các đối số của nó:

# //pkg:exampleinfo.bzl

_core_headers = [...]  # private constant representing standard library files

# Keyword-only arguments are preferred.
def _exampleinfo_init(*, files_to_link, headers = None, allow_empty_files_to_link = False):
    if not files_to_link and not allow_empty_files_to_link:
        fail("files_to_link may not be empty")
    all_headers = depset(_core_headers, transitive = headers)
    return {"files_to_link": files_to_link, "headers": all_headers}

ExampleInfo, _new_exampleinfo = provider(
    fields = ["files_to_link", "headers"],
    init = _exampleinfo_init,
)

Sau đó, việc triển khai quy tắc có thể tạo thực thể cho trình cung cấp như sau:

ExampleInfo(
    files_to_link = my_files_to_link,  # may not be empty
    headers = my_headers,  # will automatically include the core headers
)

Bạn có thể dùng hàm khởi tạo thô để xác định các hàm nhà máy công khai thay thế không thông qua logic init. Ví dụ: exampleinfo.bzl có thể xác định:

def make_barebones_exampleinfo(headers):
    """Returns an ExampleInfo with no files_to_link and only the specified headers."""
    return _new_exampleinfo(files_to_link = depset(), headers = all_headers)

Thông thường, hàm khởi tạo thô được liên kết với một biến có tên bắt đầu bằng dấu gạch dưới (_new_exampleinfo ở trên), do đó, mã người dùng không thể tải mã đó và tạo ra các thực thể nhà cung cấp tuỳ ý.

Một cách sử dụng khác cho init là ngăn người dùng gọi toàn bộ biểu tượng nhà cung cấp và buộc họ sử dụng hàm nhà máy:

def _exampleinfo_init_banned(*args, **kwargs):
    fail("Do not call ExampleInfo(). Use make_exampleinfo() instead.")

ExampleInfo, _new_exampleinfo = provider(
    ...
    init = _exampleinfo_init_banned)

def make_exampleinfo(...):
    ...
    return _new_exampleinfo(...)

Quy tắc thực thi và quy tắc kiểm thử

Quy tắc thực thi xác định các mục tiêu có thể được gọi bằng lệnh bazel run. Quy tắc kiểm thử là một loại quy tắc thực thi đặc biệt mà các mục tiêu này cũng có thể được gọi bằng lệnh bazel test. Các quy tắc thực thi và kiểm thử được tạo bằng cách đặt đối số executable hoặc test tương ứng thành True trong lệnh gọi tới rule:

example_binary = rule(
   implementation = _example_binary_impl,
   executable = True,
   ...
)

example_test = rule(
   implementation = _example_binary_impl,
   test = True,
   ...
)

Các quy tắc kiểm thử phải có tên kết thúc bằng _test. (Tên mục tiêu kiểm thử cũng thường kết thúc bằng _test theo quy ước, nhưng điều này là không bắt buộc.) Các quy tắc không kiểm thử không được có hậu tố này.

Cả hai loại quy tắc này đều phải tạo tệp đầu ra có thể thực thi (có thể được hoặc không được khai báo trước) và sẽ được các lệnh run hoặc test gọi. Để cho Bazel biết kết quả nào của quy tắc sẽ sử dụng khi thực thi tệp thực thi này, hãy truyền dữ liệu đó dưới dạng đối số executable của trình cung cấp DefaultInfo được trả về. executable đó được thêm vào kết quả mặc định của quy tắc (vì vậy, bạn không cần truyền dữ liệu đó vào cả executable và files). Hàm này cũng được ngầm thêm vào runfiles:

def _example_binary_impl(ctx):
    executable = ctx.actions.declare_file(ctx.label.name)
    ...
    return [
        DefaultInfo(executable = executable, ...),
        ...
    ]

Thao tác tạo tệp này phải đặt bit thực thi trên tệp. Đối với một thao tác ctx.actions.run hoặc ctx.actions.run_shell, bạn nên thực hiện việc này bằng công cụ cơ bản được thao tác đó gọi. Đối với thao tác ctx.actions.write, hãy truyền is_executable = True.

Do hành vi cũ, các quy tắc thực thi có đầu ra đặc biệt được khai báo trước là ctx.outputs.executable. Tệp này đóng vai trò là tệp thực thi mặc định nếu bạn không chỉ định tệp bằng DefaultInfo; bạn không được dùng tệp này theo cách khác. Cơ chế đầu ra này không được dùng nữa vì không hỗ trợ tuỳ chỉnh tên của tệp thực thi tại thời điểm phân tích.

Xem ví dụ về quy tắc thực thi và quy tắc kiểm thử.

Các quy tắc có thể thực thi và quy tắc kiểm thử có các thuộc tính bổ sung được xác định ngầm, ngoài các thuộc tính được thêm cho tất cả quy tắc. Bạn không thể thay đổi giá trị mặc định của các thuộc tính được thêm ngầm định, mặc dù bạn có thể giải quyết vấn đề này bằng cách gói quy tắc riêng tư trong Starlark macro để thay đổi mặc định:

def example_test(size = "small", **kwargs):
  _example_test(size = size, **kwargs)

_example_test = rule(
 ...
)

Vị trí tệp Runfile

Khi một mục tiêu thực thi được chạy bằng bazel run (hoặc test), gốc của thư mục runfiles nằm cạnh tệp thực thi. Các đường dẫn liên quan như sau:

# Given launcher_path and runfile_file:
runfiles_root = launcher_path.path + ".runfiles"
workspace_name = ctx.workspace_name
runfile_path = runfile_file.short_path
execution_root_relative_path = "%s/%s/%s" % (
    runfiles_root, workspace_name, runfile_path)

Đường dẫn đến một File trong thư mục runfiles tương ứng với File.short_path.

Tệp nhị phân do bazel thực thi trực tiếp ở bên cạnh gốc của thư mục runfiles. Tuy nhiên, các tệp nhị phân được gọi từ các tệp chạy không thể đưa ra giả định tương tự. Để giảm thiểu điều này, mỗi tệp nhị phân phải cung cấp một cách để chấp nhận gốc runfile của nó làm tham số bằng cách sử dụng môi trường hoặc đối số hoặc cờ dòng lệnh. Điều này cho phép các tệp nhị phân truyền tệp gốc runfile chuẩn đến tệp nhị phân mà nó gọi. Nếu bạn không đặt chính sách này, thì một tệp nhị phân có thể đoán rằng đó là tệp nhị phân đầu tiên được gọi và tìm một thư mục runfiles liền kề.

Chủ đề nâng cao

Đang yêu cầu tệp đầu ra

Một mục tiêu có thể có nhiều tệp đầu ra. Khi chạy lệnh bazel build, một số kết quả đầu ra của các mục tiêu được cung cấp cho lệnh đó sẽ được coi là yêu cầu. Bazel chỉ tạo những tệp được yêu cầu này và những tệp mà chúng trực tiếp hoặc gián tiếp phụ thuộc vào. (Xét trên biểu đồ hành động, Bazel chỉ thực thi các hành động có thể truy cập dưới dạng phần phụ thuộc bắc cầu của các tệp được yêu cầu.)

Ngoài đầu ra mặc định, mọi đầu ra được khai báo trước đều có thể được yêu cầu rõ ràng trên dòng lệnh. Các quy tắc có thể chỉ định đầu ra được khai báo trước bằng cách sử dụng thuộc tính đầu ra. Trong trường hợp đó, người dùng sẽ chọn rõ ràng các nhãn cho kết quả khi tạo thực thể cho quy tắc. Để lấy đối tượng File cho các thuộc tính đầu ra, hãy sử dụng thuộc tính tương ứng của ctx.outputs. Các quy tắc cũng có thể xác định ngầm định các kết quả được khai báo trước dựa trên tên mục tiêu, nhưng tính năng này sẽ không được dùng nữa.

Ngoài các kết quả đầu ra mặc định, còn có các nhóm đầu ra. Đây là các tập hợp các tệp đầu ra có thể được yêu cầu cùng nhau. Bạn có thể yêu cầu các dữ liệu này bằng --output_groups. Ví dụ: nếu mục tiêu //pkg:mytarget thuộc loại quy tắc có nhóm đầu ra debug_files, thì bạn có thể tạo các tệp này bằng cách chạy bazel build //pkg:mytarget --output_groups=debug_files. Vì dữ liệu đầu ra không được khai báo trước không có nhãn, nên bạn chỉ có thể yêu cầu chúng bằng cách xuất hiện trong dữ liệu đầu ra mặc định hoặc nhóm đầu ra.

Bạn có thể chỉ định nhóm đầu ra bằng trình cung cấp OutputGroupInfo. Xin lưu ý rằng không giống như nhiều trình cung cấp tích hợp, OutputGroupInfo có thể lấy các tham số có tên tuỳ ý để xác định các nhóm đầu ra có tên đó:

def _example_library_impl(ctx):
    ...
    debug_file = ctx.actions.declare_file(name + ".pdb")
    ...
    return [
        DefaultInfo(files = depset([output_file]), ...),
        OutputGroupInfo(
            debug_files = depset([debug_file]),
            all_files = depset([output_file, debug_file]),
        ),
        ...
    ]

Ngoài ra, không giống như hầu hết các trình cung cấp, OutputGroupInfo có thể được trả về bởi cả khung hình và mục tiêu của quy tắc áp dụng khía cạnh đó, miễn là các quy tắc này không xác định cùng nhóm đầu ra. Trong trường hợp đó, các nhà cung cấp thu được sẽ được hợp nhất.

Xin lưu ý rằng OutputGroupInfo thường không được dùng để truyền tải các loại tệp cụ thể từ một mục tiêu đến hành động của đối tượng sử dụng. Thay vào đó, hãy xác định trình cung cấp dành riêng cho quy tắc cho trường hợp đó.

Cấu hình

Hãy tưởng tượng rằng bạn muốn tạo một tệp nhị phân C++ cho một cấu trúc khác. Quá trình xây dựng có thể phức tạp và bao gồm nhiều bước. Một số tệp nhị phân trung gian, chẳng hạn như trình biên dịch và trình tạo mã, phải chạy trên nền tảng thực thi (có thể là máy chủ lưu trữ hoặc trình thực thi từ xa). Một số tệp nhị phân (như đầu ra cuối cùng) phải được tạo cho cấu trúc mục tiêu.

Vì lý do này, Bazel có khái niệm "cấu hình" và chuyển đổi. Các mục tiêu trên cùng (các mục tiêu được yêu cầu trên dòng lệnh) được tích hợp sẵn cấu hình "mục tiêu", trong khi các công cụ chạy trên nền tảng thực thi được tích hợp cấu hình "thực thi". Các quy tắc có thể tạo nhiều thao tác dựa trên cấu hình, chẳng hạn như thay đổi cấu trúc cpu được truyền đến trình biên dịch. Trong một số trường hợp, bạn có thể cần cùng một thư viện cho nhiều cấu hình. Nếu điều này xảy ra, mô hình này sẽ được phân tích và có thể được tạo nhiều lần.

Theo mặc định, Bazel tạo các phần phụ thuộc của mục tiêu trong cùng một cấu hình như mục tiêu, nói cách khác là không cần chuyển đổi. Khi phần phụ thuộc là một công cụ cần thiết để giúp xây dựng mục tiêu, thuộc tính tương ứng sẽ chỉ định quá trình chuyển đổi sang cấu hình thực thi. Điều này giúp công cụ và tất cả các phần phụ thuộc của công cụ xây dựng cho nền tảng thực thi.

Đối với mỗi thuộc tính phần phụ thuộc, bạn có thể sử dụng cfg để quyết định xem các phần phụ thuộc sẽ được tạo trong cùng một cấu hình hay chuyển đổi sang cấu hình thực thi. Nếu thuộc tính phần phụ thuộc có cờ executable = True, bạn phải đặt cfg một cách rõ ràng. Điều này nhằm tránh trường hợp vô tình tạo một công cụ có cấu hình sai. Xem ví dụ

Nhìn chung, các nguồn, thư viện phụ thuộc và tệp thực thi cần thiết trong thời gian chạy có thể sử dụng cùng một cấu hình.

Các công cụ được thực thi trong bản dựng (chẳng hạn như trình biên dịch hoặc trình tạo mã) phải được xây dựng cho cấu hình thực thi. Trong trường hợp này, hãy chỉ định cfg = "exec" trong thuộc tính.

Nếu không, bạn phải tạo các tệp thực thi được dùng trong thời gian chạy (chẳng hạn như một phần của quá trình kiểm thử) cho cấu hình mục tiêu. Trong trường hợp này, hãy chỉ định cfg = "target" trong thuộc tính.

cfg = "target" thực sự không làm gì cả: nó đơn thuần là một giá trị tiện lợi để giúp nhà thiết kế quy tắc thể hiện rõ ý định của họ. Khi executable = False, nghĩa là cfg là không bắt buộc, hãy chỉ đặt giá trị này khi thuộc tính này thực sự giúp dễ đọc.

Bạn cũng có thể sử dụng cfg = my_transition để sử dụng các lượt chuyển đổi do người dùng xác định, cho phép người tạo quy tắc rất linh hoạt trong việc thay đổi cấu hình, cùng với hạn chế là làm cho biểu đồ bản dựng lớn hơn và khó hiểu hơn.

Lưu ý: Trước đây, Bazel không có khái niệm về nền tảng thực thi mà mọi hành động xây dựng đều được xem là sẽ chạy trên máy chủ lưu trữ. Bazel các phiên bản trước 6.0 đã tạo một cấu hình "máy chủ" riêng biệt để thể hiện điều này. Nếu bạn thấy thông tin tham chiếu đến "máy chủ lưu trữ" trong mã hoặc tài liệu cũ, thì đó là nghĩa của đoạn mã. Bạn nên sử dụng Bazel 6.0 trở lên để tránh mức hao tổn quá mức mang tính khái niệm.

Mảnh cấu hình

Các quy tắc có thể truy cập vào các mảnh cấu hình như cpp và java. Tuy nhiên, bạn phải khai báo tất cả các mảnh bắt buộc để tránh lỗi truy cập:

def _impl(ctx):
    # Using ctx.fragments.cpp leads to an error since it was not declared.
    x = ctx.fragments.java
    ...

my_rule = rule(
    implementation = _impl,
    fragments = ["java"],      # Required fragments of the target configuration
    ...
)

Đường liên kết tượng trưng Runfiles

Thông thường, đường dẫn tương đối của một tệp trong cây runfiles giống với đường dẫn tương đối của tệp đó trong cây nguồn hoặc cây đầu ra được tạo. Nếu các giá trị này cần khác nhau vì một lý do nào đó, bạn có thể chỉ định đối số root_symlinks hoặc symlinks. root_symlinks là một đường dẫn ánh xạ từ điển đến các tệp, trong đó các đường dẫn tương ứng với thư mục gốc của thư mục runfiles. Từ điển symlinks giống nhau, nhưng đường dẫn sẽ được ngầm ẩn bằng tên của không gian làm việc chính (không phải tên của kho lưu trữ chứa mục tiêu hiện tại).

    ...
    runfiles = ctx.runfiles(
        root_symlinks = {"some/path/here.foo": ctx.file.some_data_file2}
        symlinks = {"some/path/here.bar": ctx.file.some_data_file3}
    )
    # Creates something like:
    # sometarget.runfiles/
    #     some/
    #         path/
    #             here.foo -> some_data_file2
    #     <workspace_name>/
    #         some/
    #             path/
    #                 here.bar -> some_data_file3

Nếu bạn sử dụng symlinks hoặc root_symlinks, hãy cẩn thận để không ánh xạ 2 tệp khác nhau với cùng một đường dẫn trong cây runfile. Điều này sẽ khiến bản dựng không hoạt động kèm theo lỗi mô tả xung đột. Để khắc phục, bạn cần sửa đổi các đối số ctx.runfiles để loại bỏ xung đột. Quá trình kiểm tra này sẽ được thực hiện cho mọi mục tiêu đang sử dụng quy tắc của bạn, cũng như các mục tiêu thuộc mọi loại phụ thuộc vào các mục tiêu đó. Điều này đặc biệt rủi ro nếu công cụ của bạn có thể sẽ được một công cụ khác sử dụng theo cách bắc cầu; tên đường liên kết tượng trưng phải là duy nhất trên các tệp chạy của công cụ và tất cả các phần phụ thuộc của công cụ đó.

Mức độ sử dụng mã

Khi chạy lệnh coverage, bản dựng có thể cần thêm khả năng đo lường mức độ sử dụng cho một số mục tiêu nhất định. Bản dựng này cũng thu thập danh sách các tệp nguồn được đo lường. Tập hợp con các mục tiêu được xem xét chịu sự kiểm soát của cờ --instrumentation_filter. Các mục tiêu thử nghiệm sẽ bị loại trừ, trừ phi bạn chỉ định --instrument_test_targets.

Nếu quá trình triển khai quy tắc thêm khả năng đo lường mức độ sử dụng vào thời gian xây dựng, thì bạn cần tính đến điều đó trong hàm triển khai. ctx.coverage_instrumented sẽ trả về True ở chế độ phạm vi nếu cần đo lường các nguồn của mục tiêu:

# Are this rule's sources instrumented?
if ctx.coverage_instrumented():
  # Do something to turn on coverage for this compile action

Logic luôn cần được bật ở chế độ mức độ phù hợp (cho dù nguồn của mục tiêu cụ thể có được đo lường hay không) có thể được điều chỉnh trên ctx.configuration.coverage_enabled.

Nếu quy tắc trực tiếp bao gồm các nguồn từ các phần phụ thuộc trước khi biên dịch (chẳng hạn như tệp tiêu đề), thì quy tắc đó cũng có thể cần phải bật tính năng đo lường thời gian biên dịch nếu cần đo lường nguồn của phần phụ thuộc:

# Are this rule's sources or any of the sources for its direct dependencies
# in deps instrumented?
if (ctx.configuration.coverage_enabled and
    (ctx.coverage_instrumented() or
     any([ctx.coverage_instrumented(dep) for dep in ctx.attr.deps]))):
    # Do something to turn on coverage for this compile action

Các quy tắc cũng phải cung cấp thông tin về các thuộc tính liên quan đến mức độ phù hợp của trình cung cấp InstrumentedFilesInfo, được tạo bằng coverage_common.instrumented_files_info. Tham số dependency_attributes của instrumented_files_info phải liệt kê tất cả các thuộc tính phần phụ thuộc thời gian chạy, bao gồm cả các phần phụ thuộc mã như deps và các phần phụ thuộc dữ liệu như data. Tham số source_attributes phải liệt kê các thuộc tính tệp nguồn của quy tắc nếu bạn có thể thêm khả năng đo lường mức độ phù hợp:

def _example_library_impl(ctx):
    ...
    return [
        ...
        coverage_common.instrumented_files_info(
            ctx,
            dependency_attributes = ["deps", "data"],
            # Omitted if coverage is not supported for this rule:
            source_attributes = ["srcs", "hdrs"],
        )
        ...
    ]

Nếu không trả về InstrumentedFilesInfo, hệ thống sẽ tạo một thuộc tính mặc định với mỗi thuộc tính phần phụ thuộc không phải công cụ và không đặt cfg thành "exec" trong giản đồ thuộc tính trong dependency_attributes. (Đây không phải là hành vi lý tưởng vì đặt các thuộc tính như srcs trong dependency_attributes thay vì source_attributes, nhưng sẽ không cần phải có cấu hình mức độ phù hợp rõ ràng cho tất cả các quy tắc trong chuỗi phần phụ thuộc.)

Hành động xác thực

Đôi khi, bạn cần xác thực nội dung nào đó về bản dựng và thông tin cần thiết để thực hiện việc xác thực đó chỉ có trong các cấu phần phần mềm (tệp nguồn hoặc tệp đã tạo). Vì thông tin này nằm trong cấu phần phần mềm, nên các quy tắc không thể thực hiện việc xác thực này tại thời điểm phân tích vì các quy tắc không thể đọc tệp. Thay vào đó, các hành động phải thực hiện việc xác thực này tại thời điểm thực thi. Khi xác thực không thành công, hành động sẽ không thành công và do đó, bản dựng cũng vậy.

Ví dụ về quy trình xác thực có thể chạy là phân tích tĩnh, tìm lỗi mã nguồn, kiểm tra phần phụ thuộc và tính nhất quán cũng như kiểm tra kiểu.

Thao tác xác thực cũng có thể giúp cải thiện hiệu suất của bản dựng bằng cách di chuyển các phần của hành động không cần thiết cho việc tạo cấu phần phần mềm thành các hành động riêng biệt. Ví dụ: nếu có thể tách một thao tác biên dịch và tìm lỗi mã nguồn thành một thao tác biên dịch và một thao tác tìm lỗi mã nguồn, thì thao tác tìm lỗi mã nguồn này có thể được chạy dưới dạng một thao tác xác thực và chạy song song với các thao tác khác.

Các "thao tác xác thực" này thường không tạo ra bất kỳ dữ liệu nào được dùng ở nơi khác trong bản dựng, vì chúng chỉ cần xác nhận mọi thứ về dữ liệu đầu vào của mình. Tuy nhiên, điều này gây ra một vấn đề: Nếu hành động xác thực không tạo ra bất kỳ nội dung nào được sử dụng ở nơi khác trong bản dựng, thì quy tắc sẽ chạy hành động đó bằng cách nào? Trước đây, phương pháp là yêu cầu hành động xác thực đưa ra một tệp trống và thêm một cách giả tạo đầu ra đó vào dữ liệu đầu vào của một số hành động quan trọng khác trong bản dựng:

Cách này hiệu quả vì Bazel sẽ luôn chạy thao tác xác thực khi chạy thao tác biên dịch, nhưng điều này có một số hạn chế đáng kể:

Hành động xác thực nằm trong đường dẫn quan trọng của bản dựng. Vì Bazel cho rằng cần phải có dữ liệu đầu ra trống để chạy thao tác biên dịch, nên thao tác này sẽ chạy thao tác xác thực trước, mặc dù thao tác biên dịch đó sẽ bỏ qua đầu vào. Điều này làm giảm tính song song và làm chậm bản dựng.
Nếu các thao tác khác trong bản dựng có thể chạy thay vì thao tác biên dịch, thì bạn cũng cần thêm kết quả trống của thao tác xác thực vào các thao tác đó (chẳng hạn như dữ liệu đầu ra trong tệp nguồn của java_library). Đây cũng là một vấn đề nếu sau đó các thao tác mới có thể chạy thay vì thao tác biên dịch được thêm vào và kết quả xác thực trống vô tình bị tắt.

Giải pháp cho những vấn đề này là sử dụng Nhóm kết quả xác thực.

Nhóm kết quả xác thực

Nhóm đầu ra của hoạt động xác thực là một nhóm đầu ra được thiết kế để lưu giữ các kết quả không được sử dụng của các hành động xác thực. Nhờ đó, bạn không cần thêm những hành động này một cách giả tạo vào dữ liệu đầu vào của các hành động khác.

Nhóm này đặc biệt ở chỗ đầu ra của nhóm luôn được yêu cầu, bất kể giá trị của cờ --output_groups và bất kể mục tiêu phụ thuộc vào cách nào (ví dụ: trên dòng lệnh, dưới dạng phần phụ thuộc hoặc thông qua kết quả đầu ra ngầm định của mục tiêu). Lưu ý rằng chức năng lưu vào bộ nhớ đệm và mức độ gia tăng thông thường vẫn được áp dụng: nếu dữ liệu đầu vào cho thao tác xác thực không thay đổi và thao tác xác thực đã thành công trước đó, thì thao tác xác thực sẽ không chạy.

Việc sử dụng nhóm đầu ra này vẫn yêu cầu các hành động xác thực xuất ra một số tệp, ngay cả một tệp trống. Bạn có thể phải gói một số công cụ thường không tạo đầu ra để tạo tệp.

Các hành động xác thực của mục tiêu không được chạy trong 3 trường hợp sau:

Khi mục tiêu được dựa vào làm công cụ
Khi mục tiêu được phụ thuộc vào dưới dạng phần phụ thuộc ngầm ẩn (ví dụ: một thuộc tính bắt đầu bằng "_")
Khi mục tiêu được xây dựng trong cấu hình exec.

Giả định rằng các mục tiêu này có các bản dựng và bài kiểm thử riêng biệt để phát hiện mọi lỗi xác thực.

Sử dụng nhóm kết quả xác thực

Nhóm đầu ra của quy trình xác thực có tên là _validation và được sử dụng như mọi nhóm đầu ra khác:

def _rule_with_validation_impl(ctx):

  ctx.actions.write(ctx.outputs.main, "main output\n")
  ctx.actions.write(ctx.outputs.implicit, "implicit output\n")

  validation_output = ctx.actions.declare_file(ctx.attr.name + ".validation")
  ctx.actions.run(
    outputs = [validation_output],
    executable = ctx.executable._validation_tool,
    arguments = [validation_output.path],
  )

  return [
    DefaultInfo(files = depset([ctx.outputs.main])),
    OutputGroupInfo(_validation = depset([validation_output])),
  ]


rule_with_validation = rule(
  implementation = _rule_with_validation_impl,
  outputs = {
    "main": "%{name}.main",
    "implicit": "%{name}.implicit",
  },
  attrs = {
    "_validation_tool": attr.label(
        default = Label("//validation_actions:validation_tool"),
        executable = True,
        cfg = "exec"
    ),
  }
)

Xin lưu ý rằng tệp đầu ra xác thực không được thêm vào DefaultInfo hoặc dữ liệu đầu vào cho bất kỳ hành động nào khác. Thao tác xác thực cho một mục tiêu thuộc loại quy tắc này sẽ vẫn chạy nếu mục tiêu phụ thuộc vào nhãn, hoặc bất kỳ kết quả ngầm ẩn nào của mục tiêu phụ thuộc trực tiếp hoặc gián tiếp.

Thông thường, điều quan trọng là đầu ra của các hành động xác thực chỉ chuyển vào nhóm đầu ra xác thực và không được thêm vào dữ liệu đầu vào của các hành động khác, vì điều này có thể làm hỏng khả năng tăng tính song song. Tuy nhiên, hãy lưu ý rằng Bazel không có quy trình kiểm tra đặc biệt nào để thực thi việc này. Do đó, bạn nên kiểm thử để đảm bảo rằng đầu ra của hành động xác thực không được thêm vào đầu vào của bất kỳ hành động nào trong quy trình kiểm thử cho các quy tắc Starlark. Ví dụ:

load("@bazel_skylib//lib:unittest.bzl", "analysistest")

def _validation_outputs_test_impl(ctx):
  env = analysistest.begin(ctx)

  actions = analysistest.target_actions(env)
  target = analysistest.target_under_test(env)
  validation_outputs = target.output_groups._validation.to_list()
  for action in actions:
    for validation_output in validation_outputs:
      if validation_output in action.inputs.to_list():
        analysistest.fail(env,
            "%s is a validation action output, but is an input to action %s" % (
                validation_output, action))

  return analysistest.end(env)

validation_outputs_test = analysistest.make(_validation_outputs_test_impl)

Cờ hành động xác thực

Việc chạy các hành động xác thực được kiểm soát bằng cờ dòng lệnh --run_validations (mặc định là đúng).

Những tính năng đã ngừng hoạt động

Kết quả đầu ra được khai báo trước không dùng nữa

Có 2 cách sử dụng kết quả được khai báo trước không dùng nữa:

Tham số outputs của rule chỉ định mối liên kết giữa tên thuộc tính đầu ra và mẫu chuỗi để tạo nhãn đầu ra được khai báo trước. Ưu tiên sử dụng kết quả không được khai báo trước và thêm kết quả vào DefaultInfo.files một cách rõ ràng. Hãy sử dụng nhãn của mục tiêu quy tắc làm dữ liệu đầu vào cho các quy tắc sử dụng dữ liệu đầu ra thay vì nhãn của đầu ra được khai báo trước.
Đối với các quy tắc thực thi, ctx.outputs.executable đề cập đến một đầu ra có thể thực thi được khai báo trước có cùng tên với mục tiêu của quy tắc. Ưu tiên khai báo kết quả một cách rõ ràng, chẳng hạn như với ctx.actions.declare_file(ctx.label.name) và đảm bảo rằng lệnh tạo ra tệp thực thi sẽ đặt các quyền để cho phép thực thi. Truyền rõ ràng đầu ra có thể thực thi đến tham số executable của DefaultInfo.

Các tính năng cần tránh khi chạy tệp Runfile

ctx.runfiles và loại runfiles có một tập hợp các tính năng phức tạp, nhiều tính năng trong số đó được giữ lại vì lý do cũ. Các đề xuất sau đây sẽ giúp giảm độ phức tạp:

Tránh sử dụng chế độ collect_data và collect_default của ctx.runfiles. Các chế độ này ngầm thu thập các tệp chạy trên một số cạnh phần phụ thuộc được mã hoá cứng theo những cách khó hiểu. Thay vào đó, hãy thêm các tệp bằng cách sử dụng tham số files hoặc transitive_files của ctx.runfiles hoặc bằng cách hợp nhất các tệp chạy từ các phần phụ thuộc với runfiles = runfiles.merge(dep[DefaultInfo].default_runfiles).
Tránh sử dụng data_runfiles và default_runfiles của hàm khởi tạo DefaultInfo. Thay vào đó, hãy chỉ định DefaultInfo(runfiles = ...). Sự khác biệt giữa các tệp chạy "mặc định" và "dữ liệu" vẫn được duy trì vì các lý do cũ. Ví dụ: một số quy tắc đặt kết quả mặc định trong data_runfiles, nhưng không đặt kết quả default_runfiles. Thay vì sử dụng data_runfiles, các quy tắc nên cả hai này bao gồm dữ liệu đầu ra mặc định và hợp nhất vào default_runfiles từ các thuộc tính cung cấp tệp chạy (thường là data).
Khi truy xuất runfiles từ DefaultInfo (thường chỉ để hợp nhất các tệp chạy giữa quy tắc hiện tại và phần phụ thuộc), hãy sử dụng DefaultInfo.default_runfiles, không phải DefaultInfo.data_runfiles.

Di chuyển từ các nhà cung cấp cũ

Trước đây, trình cung cấp Bazel là các trường đơn giản trên đối tượng Target. Các đối tượng này được truy cập bằng toán tử dấu chấm và được tạo bằng cách đặt trường trong struct do hàm triển khai của quy tắc trả về thay vì danh sách đối tượng của trình cung cấp:

return struct(example_info = struct(headers = depset(...)))

Các nhà cung cấp như vậy có thể được truy xuất từ trường tương ứng của đối tượng Target:

transitive_headers = [hdr.example_info.headers for hdr in ctx.attr.hdrs]

Kiểu này không được dùng nữa và không nên dùng trong mã mới; hãy xem phần sau để biết thông tin có thể giúp bạn di chuyển. Cơ chế của trình cung cấp mới sẽ tránh được xung đột tên. API này cũng hỗ trợ ẩn dữ liệu, bằng cách yêu cầu bất kỳ mã nào truy cập vào một thực thể nhà cung cấp để truy xuất thực thể đó bằng biểu tượng nhà cung cấp.

Hiện tại, chúng tôi vẫn hỗ trợ các nhà cung cấp cũ. Một quy tắc có thể trả về cả nhà cung cấp cũ và hiện đại như sau:

def _old_rule_impl(ctx):
  ...
  legacy_data = struct(x = "foo", ...)
  modern_data = MyInfo(y = "bar", ...)
  # When any legacy providers are returned, the top-level returned value is a
  # struct.
  return struct(
      # One key = value entry for each legacy provider.
      legacy_info = legacy_data,
      ...
      # Additional modern providers:
      providers = [modern_data, ...])

Nếu dep là đối tượng Target thu được cho một thực thể của quy tắc này, thì các trình cung cấp và nội dung của các trình cung cấp đó có thể được truy xuất dưới dạng dep.legacy_info.x và dep[MyInfo].y.

Ngoài providers, cấu trúc được trả về cũng có thể lấy một số trường khác có ý nghĩa đặc biệt (và do đó không tạo ra một nhà cung cấp cũ tương ứng):

Các trường files, runfiles, data_runfiles, default_runfiles và executable tương ứng với các trường cùng tên của DefaultInfo. Không được phép chỉ định trường nào trong số này khi cũng trả về trình cung cấp DefaultInfo.
Trường output_groups nhận một giá trị cấu trúc và tương ứng với một OutputGroupInfo.

Trong phần khai báo provides của quy tắc và trong phần khai báo providers của thuộc tính phần phụ thuộc, trình cung cấp cũ được truyền vào dưới dạng chuỗi, còn trình cung cấp hiện đại được truyền bằng biểu tượng Info. Hãy nhớ thay đổi từ chuỗi sang ký hiệu khi di chuyển. Đối với các tập hợp quy tắc lớn hoặc phức tạp và khó có thể cập nhật tất cả các quy tắc một cách triệt để, bạn có thể dễ dàng cập nhật hơn nếu làm theo trình tự các bước sau:

Sửa đổi các quy tắc tạo ra trình cung cấp cũ để tạo cả trình cung cấp cũ và hiện đại, bằng cách sử dụng cú pháp trước đó. Đối với các quy tắc khai báo rằng họ trả về trình cung cấp cũ, hãy cập nhật nội dung khai báo đó để bao gồm cả trình cung cấp cũ và hiện đại.
Sửa đổi các quy tắc sử dụng trình cung cấp cũ để sử dụng trình cung cấp hiện đại thay thế. Nếu bất kỳ nội dung khai báo thuộc tính nào yêu cầu trình cung cấp cũ, bạn cũng cần cập nhật các nội dung đó để yêu cầu trình cung cấp hiện đại. Nếu muốn, bạn có thể xen kẽ công việc này với bước 1 bằng cách yêu cầu người dùng chấp nhận hoặc yêu cầu một trong hai nhà cung cấp: Kiểm thử sự hiện diện của nhà cung cấp cũ bằng hasattr(target, 'foo') hoặc nhà cung cấp mới bằng FooInfo in target.
Xoá toàn bộ nhà cung cấp cũ khỏi tất cả các quy tắc.